Удаление из линейного списка

Program CityList;
 
Uses
  Crt;
  
type
 
  // Запись элемента списка
  PCity = ^TCity;
  TCity = record
    City: String;   // Данные - город
    Next: PCity;    // Указатель на следующий элемент списка
  end; 
 
var
  Head: PCity;   // Голова (первый элемент) списка
   
// Процедура добавления элемента в конец списка  
procedure AddElementToList(aCity: String);
var
  P, T: PCity;
begin
  // Обрабатываем случай, когда список пустой
  if Head = nil then begin
    New(Head);               // Вставляемый элемент будет головой. Выделяем память под него
    Head^.City := aCity;     // Записываем данные
    Head^.Next := nil;
  end
  else begin
    // Ищем последний элемент в списке
    P := Head;
    while P^.Next <> nil do P := P^.Next;
    
    // Выделяем помять под новый элемент и помещаем его в конец списка
    New(T); 
    T^.City := aCity;
    T^.Next := nil;
    P^.Next := T;
  end;
end;  
 
// Процедура вывод списка на экран
procedure VisualList;
var
  P: PCity;
begin
  P := Head;  
  while P <> nil do begin // Обходим каждый элемент списка начиная с головы
    WriteLn(P^.City);     // Выводим на экран каждый элемент
    P := P^.Next;
  end;
end;
 
// Процедура очистки списка
procedure ClearList;
var
  P, T: PCity;
begin
  P := Head;  
  while P <> nil do begin // Обходим каждый элемент списка начиная с головы
    T := P^.Next;
    Dispose(P);           // Освобождаем память, занимаемую элементом
    P := T;
  end;
  Head := Nil;
end;
  
// Загрузка из файла списка  
procedure LoadList(aFileName: String); 
var
  F: TextFile;  
  City: String;
begin
  AssignFile(F, aFileName);    
  Reset(F);                      // Открываем файл с данными для чтения
  
  while not EOF(F) do begin      // Считываем каждую строку файла
    ReadLn(F, City);               
    AddElementToList(City);      // Добавляем элемент (считанный из файла город) в список
  end;
   
  CloseFile(F);                  // Закрываем файл
end;   
 
// Удаление элементов списка, которые не начинаются на "А"
procedure DeleteElementNotA; 
var
  P, T, S: PCity;
begin
  P := Head;  
  while P <> nil do begin // Обходим каждый элемент списка начиная с головы
    
    if P^.City[1] <> 'А' then begin         // Если город начинается на А
      if T <> nil then T^.Next := P^.Next   // Связываем предыдущий элемент с последующим (относительно удаляемого элемента) 
      else Head := P^.Next;                 // Обрабатываем случай, когда удаляется голова списка
      S := P^.Next;            
      Dispose(P);                           // Освобождаем память удаляемого элемента
      P := S;
    end
    else begin
      T := P;                               // Запоминиаем предыдущий элемент
      P := T^.Next;                         // Переходим к следующему элементу списка   
    end;    
  end;
end;   
  
begin
  ClrScr;                                   // Очиска экрана
  
  LoadList('data.txt');                     // Загружаем в список все города из файла
   
  WriteLn('Элементы списка до обработки: ');  
  VisualList;                               // Выводим список на экран
  
  WriteLn;
  WriteLn('Элементы списка после обработки: '); 
  DeleteElementNotA;                        // Удаляем из списка города, что не начинаются на А
  VisualList;                               // Выводим список на экран
  
  ClearList;                                // Очищаем список и освобождаем память
  
  ReadLn;
end.