Поменять местами первый и второй абзацы текстового файла

program ExchangeParagraphs;
 
{$mode delphi}
{$APPTYPE CONSOLE}
 
uses
  SysUtils,
  Classes;
 
type
  TMyStringList = class(TStringList)
  public
    procedure Reverse(AFirst, ALast: integer);
    procedure LeftRotate(AIndex, ASize, AShift: integer);
  end;
 
  procedure TMyStringList.Reverse(AFirst, ALast: integer);
  begin
    if (AFirst > pred(Count)) or (AFirst < 0) then
      exit;
    if (ALast > pred(Count)) or (ALast < 0) then
      exit;
    while (AFirst < ALast) do
    begin
      Exchange(AFirst, ALast);
      Inc(AFirst);
      Dec(ALast);
    end;
  end;
 
  procedure TMyStringList.LeftRotate(AIndex, ASize, AShift: integer);
  begin
    if (AIndex < 0) or (AIndex >= Count) then
      exit;
    if (ASize <= 0) or (AIndex + ASize > Count) then
      exit;
    if (AShift > ASize) then
      AShift := AShift mod ASize;
    if ASize = 0 then
      exit;
    Reverse(AIndex, AIndex + AShift - 1);
    Reverse(AIndex + AShift, AIndex + ASize - 1);
    Reverse(AIndex, AIndex + ASize - 1);
  end;
 
const
  cInFileName  = 'infile.txt';
  cOutFileName = 'outfile.txt';
var
  slBook: TMyStringList;
  IndexFirstParagraph, IndexSecondParagraph, IndexThirdParagraph: integer;
  i: integer;
begin
  {Файл с ткстом считывается без изменений в переменную slBook}
  slBook := TMyStringList.Create;
  slBook.Sorted := False;
  slBook.Duplicates := dupAccept;
  {Чтение текста из файла}
  try
    slBook.LoadFromFile(cInFileName);
  except
    on Exception do
      WriteLn('File open error');
  end;
  {Обработка текста - поменять местами первый и второй абзацы текстового файла}
  {Ищем номер строки с первым абзацем}
  IndexFirstParagraph := -1;
  IndexSecondParagraph := -1;
  i := 0;
  for i := 0 to slBook.Count - 1 do
    if (length(slBook.Strings[i]) > 0) and (slBook.Strings[i][1] = ' ') then
    begin
      IndexFirstParagraph := i;
      break;
    end;
  {Ищем номер строки со вторым абзацем}
  for i := IndexFirstParagraph + 1 to slBook.Count - 1 do
    if (length(slBook.Strings[i]) > 0) and (slBook.Strings[i][1] = ' ') then
    begin
      IndexSecondParagraph := i;
      break;
    end;
  {Ищем номер строки с третьим абзацем - конец второго абзаца}
  IndexThirdParagraph := IndexSecondParagraph + 1;
  while (IndexThirdParagraph < slBook.Count) do
  begin
    if (length(slBook.Strings[IndexThirdParagraph]) > 0) and
      (slBook.Strings[IndexThirdParagraph][1] = ' ') then
      break;
    Inc(IndexThirdParagraph);
  end;
  if (IndexFirstParagraph <> -1) and (IndexSecondParagraph <> -1) then
    slBook.LeftRotate(IndexFirstParagraph, IndexThirdParagraph - IndexFirstParagraph,
      IndexSecondParagraph - IndexFirstParagraph);
  {Вывод результатов}
  try
    slBook.SaveToFile(cOutFileName);
  except
    on Exception do
      WriteLn('File write error');
  end;
  {Очистка памяти}
  slBook.Free;
end.