Как начертить график, имея последовательность чисел?

module TruestTypeFont where
 
import Data.List (sort)
import Data.List.Split (chunksOf)
 
beziercurve ps = map (bezierpoint ps) [0,0.001..1] where
    bezierpoint [(r,c)] _ = (round r, round c)
    bezierpoint ps t = bezierpoint ps' t where
        ps' = zipWith (\(r1,c1) (r2,c2) -> (r1+(r2-r1)*t, c1+(c2-c1)*t)) ps $ tail ps
 
polygon ps = concat.map beziercurve.zipWith (\x y->x++take 1 y) ps $ tail ps++[head ps]
 
surround ps = sort $ surround' (r0-1,c0+1) 3 [] where
    (r0,c0) = minimum ps
    surround' p d a = if p == (r0-1,c0) then a else
        let p' = (\(a,b) (c,d) -> (a+c,b+d)) p $ [(0,1),(-1,0),(0,-1),(1,0)]!!(mod d 4)
        in case elem p' ps of
        True -> surround' p  (d+1 `mod` 4) (if mod d 2 == 0 then (p':a) else a)
        _    -> surround' p' (d-1 `mod` 4) a
 
fill ((r1,c1):(r2,c2):ps) = map (\c -> (r1,c)) [c1..c2] ++ fill ps
fill _ = []
 
formtext glifs rows cols text = unlines.chunksOf cols $ ft text 0 where
    lfill = map (fill.surround.polygon) glifs
    pcount p = sum.map (fromEnum.elem p)
    ft tt@(t:ts) i = if i==(rows*cols) then [] else
        if pcount (div i cols, mod i cols) lfill `mod` 2 == 0
        then (' ':ft tt (i+1)) else (t:ft ts (i+1))
 
main = do
    let eye = [[(9,8),(7,9),(4,13),(7,17)],[(9,18),(11,17),(14,13),(11,9)]]
        gl = [[[(12,1),(2,2),(-3,22),(2,42)],[(12,43),(22,42),(27,22),(22,2)]],
                 eye, map (map (\(r,c)->(r,c+18))) eye,
                 [[(15,7),(21,22)],[(15,37),(25,22)]]]
    putStr $ formtext gl 25 45 $ cycle ['a'..'z']

    let gl1 = map (map (map (\(r,c)->(r*5,c*5)))) gl
    putStr $ formtext gl1 (25*5) (45*5) $ cycle "Any_maybe_long_text:)"

{-# LANGUAGE MultiWayIf #-}
module NelderMead where
-- Метод Нелдера — Мида, также известный как метод деформируемого многогранника
 
import Data.List
 
type Coord = (Double,Double)
type Triangle = (Coord,Coord,Coord)
 
center2:: Coord -> Coord -> Coord
center2 (x1,y1) (x2,y2) = ((x1+x2)/2,(y1+y2)/2)
 
triangleCenter:: Triangle -> Coord
triangleCenter ((x1,y1),(x2,y2),(x3,y3)) = ((x1+x2+x3)/3,(y1+y2+y3)/3)
 
reflection:: Coord -> Coord -> Coord
reflection (x1,y1) (x2,y2) = ( 2*x2-x1, 2*y2-y1 )
 
disp:: Double -> Double -> Double -> Double
disp f1 f2 f3 = max (max f1 f2) f3 - min (min f1 f2) f3
 
-- Двухмерная минимизация ф-ии методом Нелдера — Мида с трассировкой строящихся треугольников
traceNelderMead:: (Double -> Double -> Double) -- ф-ия у которой ищется локальный минимум  
                  -> Double  -- разброс значений в треугольнике (критерий останова)
                  -> Triangle -- исходный треугольник 
                  -> [Triangle] -- трассировка поиска минимума. Последний треугольник - результат
traceNelderMead f lim cc@(c1,c2,c3) = cc: go (fu c1) c1 (fu c2) c2 (fu c3) c3
    where   fu = uncurry f
            go f1 t1 f2 t2 f3 t3
                | lim > disp f1 f2 f3 = []
                | otherwise = 
                    let [(fl,l),(fg,g),(fh,h)]=sort [(f1,t1),(f2,t2),(f3,t3)]
                        c = center2 l g
                        r = reflection h c
                        fr = fu r  in
                    if  | fr < fl ->
                             let e = reflection c r
                                 fe = fu e  in
                             if fe < fr 
                                then (l,g,e): go fl l fg g fe e  
                                else (l,g,r): go fl l fg g fr r
                        | fr < fg -> (l,g,r): go fl l fg g fr r
                        | fr < fh ->          sh fl l fg g fr r c
                        | otherwise ->        sh fl l fg g fh h c 
            sh fl l fg g fh h c =
                let s = center2 h c
                    fs = fu s in
                if fs < fh 
                    then (l,g,s): go fl l fg g fs s
                    else let g' = center2 l g
                             h' = center2 l h
                         in (l,g',h'): go fl l (fu g') g' (fu h') h'
                
-- функция Розенброка в качестве тестовой
rosenbrock:: Double -> Double -> Double
rosenbrock x y = (1-x)^2+100*(y-x^2)^2
 
-- Вспомогательные ф-ии для создания данных на JS
showCJ (x,y) = '[': show x ++ "," ++ show y ++ "]"
 
showTJ (c1,c2,c3) = showCJ c1 ++ "," ++ showCJ c2 ++ "," ++ showCJ c3 ++ "," ++ showCJ c1 
 
triangleMinMax ((x1,y1),(x2,y2),(x3,y3)) = (min (min x1 x2) x3, max (max x1 x2) x3, 
                                            min (min y1 y2) y3, max (max y1 y2) y3)
 
mkTriangleJ (x:xs) = go xs (showTJ x) (triangleMinMax x)
   where go []     s mm = (s,mm)
         go (t:ts) s (xl,xh,yl,yh) = let (xl',xh',yl',yh')=triangleMinMax t in
                                     go ts (s++",[null,null],\n"++ showTJ t) 
                                           (min xl xl', max xh xh', min yl yl', max yh yh')
 
main = writeFile "test.html" $ htmlHead ++ 
        let t = traceNelderMead rosenbrock  0.0001 ( (2, -1), (2.5, 1), (2, -0.5) ) 
                                                    -- ( (-0.5, 0.3), (-0.7, 0.5), (-0.8, 0.2) ) 
            steps = length t
            c = triangleCenter $ last t 
            fc = uncurry rosenbrock c
            (s,(xl,xh,yl,yh)) = mkTriangleJ t  
        in  s ++ htmlAfterTable ++ show c ++ "=" ++ show fc ++ "  , steps=" ++ show steps ++ htmlX ++ 
            show (floor xl) ++ ", maxValue: " ++ show (ceiling xh) ++ htmlY ++
            show (floor yl)  ++ ", maxValue: " ++ show (ceiling yh) ++ htmlEnd
 
htmlHead ="<html><head><script type='text/javascript' src='https://www.google.com/jsapi'></script> \n\
 \ <script type='text/javascript'> \n\
 \     google.load('visualization', '1', {packages:['corechart']}); \n\
 \     google.setOnLoadCallback(function(){ \n\
 \       var data = google.visualization.arrayToDataTable([ ['X', 'Y'], \n"
 
htmlAfterTable ="]);\n\n\
 \        var options = { \n\
 \             title: 'Minimum: f"
 
htmlX = "',\n\
 \             hAxis: { title: 'X', minValue: "
 
htmlY="}, \n\
 \             vAxis: { title: 'Y', minValue: "
 
htmlEnd ="},\n          legend: 'none', lineWidth: 1, colors:['red'], pointSize : 0  \n\
 \        }; \
 \     var chart = new google.visualization.ScatterChart(document.getElementById('chart_div'));  \n\
 \        chart.draw(data, options);  \n\
 \    });  \n\
 \   </script></head><body><div id='chart_div' style='width: 900px; height: 500px;'></div></body></html>  \n"

module GooglePlotEx1 where
 
main = googlePlot "SimpleSinPlot.html" $ map (\x -> (x,sin(x))) [0.1,0.2 .. 10]
 
googlePlot:: String -> [(Double,Double)] -> IO () 
googlePlot filename dat = writeFile filename $ htmlHead ++ (showData dat) ++ htmlEnd 
    where showData [] = []
          showData (x:xs) = (shw x) ++ go xs
          go [] = []
          go (x:xs) = ",\n" ++ (shw x) ++ go xs
          shw (x,y) = '[':show x ++ "," ++ show y ++ "]"
 
htmlHead ="<html><head><script type='text/javascript' src='https://www.google.com/jsapi'></script> \n\
 \ <script type='text/javascript'> \n\
 \     google.load('visualization', '1', {packages:['corechart']}); \n\
 \     google.setOnLoadCallback(function(){ \n\
 \       var data = google.visualization.arrayToDataTable([ ['X', 'Y'], \n"
 
htmlEnd ="]);\n\n\
 \        var options = { \n\
 \             title: 'Simple plot of sin(x)',\n\
 \             hAxis: { title: 'X'}, \n\
 \             vAxis: { title: 'Y'},\n\
 \             legend: 'none', lineWidth: 1, colors:['blue'], pointSize : 0  \n\
 \        }; \
 \     var chart = new google.visualization.ScatterChart(document.getElementById('chart_div'));  \n\
 \        chart.draw(data, options);  \n\
 \    });  \n\
 \   </script></head><body><div id='chart_div' style='width: 900px; height: 500px;'></div></body></html>  \n"