Как лучше (пере)оформить этот код ?

module Main (main) where
import HangmanOld
 
main :: IO ()
main = do
    runGame

{-# LANGUAGE TupleSections #-}
module HangmanOld where
import Control.Monad.Trans.State.Lazy
import System.Random
import Control.Monad.Trans.Class (MonadTrans(..))
import Data.Char (toLower)
import Consts
import Util
import Data.Maybe (fromMaybe, listToMaybe, isJust)
 
data GameState = GS {lives :: Int, word :: [(Char, Bool)], guesses :: String} -- тип данных "состояние игры"
 
instance Show GameState where
    show (GS l word _) = map (\(ch, b) -> if b then ch else '_') word ++ "\n"
                            ++ "Жизней: (" ++ take maxLives (replicate l '#' ++ repeat ' ') ++ ")\n" --toString()
 
initGameState :: String -> GameState
initGameState word = GS maxLives (map (, False) word) "" --по загаданному слову лепим исходное состояние⌈
 
runGame :: IO ()
runGame = do
    strings <- words <$> readFile fileName                                   -- считываем файл
    word <- (strings !!) . fst . randomR (0, length strings-1) <$> newStdGen -- парсим его на слова, выбирая среди них рандомное
    evalStateT hangMan (initGameState word)                                  -- начинаем игру на выбранном слове
 
hangMan :: StateT GameState IO () -- сама игра
hangMan = do
    lift . print =<< get --печатаем состояние игры
    test <- testEndGame <$> get --смотрим не гейм овер ли у нас
    maybe (untilM id tryChar *> hangMan) (lift . putStrLn) test --если геймовер то печатаем, а если нет, то идём считывать букву
 
 
testEndGame :: GameState -> Maybe String  --тестируем состояние игры на предмет геймовера
testEndGame (GS lives word _)   | lives <= 0   = Just loseMsg -- всосали, если жизней - 0
                                | all snd word = Just winMsg  -- выиграли, если все буквы открыты
                                | otherwise    = Nothing      -- если нет, то продолжаем играть
 
tryChar :: StateT GameState IO Bool -- пробуем считать букву с строки stdin
tryChar = do
    maybeChar <- listToMaybe <$> lift getLine -- считываем строку, с которой мы будем брать первую букву
    maybe (return ()) acceptChar maybeChar --смотрим на то, что считали
    return $ isJust maybeChar -- возвращаем булеан наличия буквы
 
acceptChar :: Char -> StateT GameState IO () -- меняем состояние по букве
acceptChar ch = do
    (msg, gs') <- applyChar ch <$> get -- смотрим на изменённое состояние
    put gs' -- обновляем состояние
    lift $ putStrLn msg -- сообщаем об изменениях
 
 
applyChar :: Char -> GameState -> (String, GameState) --обновление состояния игры по букве
applyChar chr gs@(GS lives word guesses) | elemGuesses  = (sameCharMsg,     gs)                                  --уже загадывали такую букву
                                         | correctGuess = (correctGuessMsg, gs{word = word', guesses = guesses'})--отгадали правильно
                                         | otherwise    = (wrongGuessMsg,   gs{lives = pred lives, guesses = guesses'}) where--назвали неверную букву
    ch = toLower chr  --регистр не учитываем
    elemGuesses = ch `elem` guesses --была ли эта буква у нас раньше?
    correctGuess = ch `elem` map (toLower . fst) word --еть ли данная буква в слове?
    word' = map (\(c, b) -> (c, b || toLower c == ch)) word -- обновили отгаданные буквы
    guesses' = ch : guesses  --добавляем букву к списку использованных

module Util where
 
untilM :: Monad m => (a -> Bool) -> m a -> m a --выполняем эффект вычисления до тех пор, пока предикат не выдаст на его значении True
untilM f ma = do
    a <- ma
    if f a then return a else untilM f ma

module Consts where
 
maxLives :: Int
maxLives = 5
 
fileName, loseMsg, winMsg, sameCharMsg, wrongGuessMsg, correctGuessMsg :: String
fileName = "words.txt"
 
loseMsg = "Вы проиграли"
winMsg = "Вы выиграли"
 
sameCharMsg = "Буква уже была загадана"
wrongGuessMsg = "Правильно"
correctGuessMsg = "Неправильно"

dependencies:
- arrows #нужны для аналогичной проги на стрелках
- transformers
- random
- base >= 4.7 && < 5