Объявление статических массивов по константе

program ArraySpeed;
// тестирование на скорость сортировки различных массивов
//  методом прямого выбора
//{$define dfnPrintArray}
 
uses SysUtils;
const ArrLen=100000; 
//const ArrLen=10; 
const ElementMaxValue=System.MaxLongint;
//const ElementMaxValue=System.MaxInt;
type StaticArray=array [1..ArrLen] of longint;
var test_array:StaticArray;
 
var arr1:StaticArray;
var arr2:^StaticArray;
var arr3:^longint;
var arr4:array of longint;
 
procedure FillTestArray();
var
    i:longint;
begin
    // заполняем случайными числами
    System.Randomize();
    for i:=System.Low(test_array) to System.High(test_array)
    do begin
        test_array[i]:=System.Random(ElementMaxValue);
    end;
end;
 
procedure SortStaticArray();
var
    start_tm, stop_tm : System.TDateTime;
    start_ms, stop_ms : comp;
    dur : double;
    el:longint;
    i,j,k:longint;
begin
    // копируем тестовый массив в рабочий массив
    arr1:=test_array;
    System.WriteLn('Статический массив фиксированной длины ',ArrLen);
{$ifdef dfnPrintArray}
    System.WriteLn('Перед началом сортировки:');
    for el in arr1
    do begin
        System.Write(el,' ');
    end;
    System.WriteLn();
{$endif}
    start_tm := SysUtils.Now();
 
    for i:=1 to ArrLen-1
    do begin
        k:=i;
        el:=arr1[i];
        for j:=i+1 to ArrLen
        do begin
            if arr1[j] < el
            then begin
                k:=j;
                el:=arr1[k];
            end;
        end;
        arr1[k]:=arr1[i];
        arr1[i]:=el;
    end;
 
    stop_tm := SysUtils.Now();
    start_ms := TimeStampToMSecs( DateTimeToTimeStamp( start_tm ) );
    stop_ms := TimeStampToMSecs( DateTimeToTimeStamp( stop_tm ) );
    dur := double( stop_ms - start_ms ) * 1.0e-3;
    System.WriteLn('Продолжительность расчёта: ', dur:10:3, ' секунд.' );
    System.WriteLn();
{$ifdef dfnPrintArray}
    System.WriteLn('После сортировки:');
    for el in arr1
    do begin
        System.Write(el,' ');
    end;
    System.WriteLn();
{$endif}
    System.WriteLn();
end;
 
procedure SortDynamicArray1();
var
    start_tm, stop_tm : System.TDateTime;
    start_ms, stop_ms : comp;
    dur : double;
    el:longint;
    i,j,k:longint;
begin
    System.New(arr2);
    try
        // копируем тестовый массив в рабочий массив
        arr2^:=test_array;
        System.WriteLn('Динамический массив фиксированной длины (^arrtype) ',ArrLen);
    {$ifdef dfnPrintArray}
        System.WriteLn('Перед началом сортировки:');
        for el in arr2^
        do begin
            System.Write(el,' ');
        end;
        System.WriteLn();
    {$endif}
        start_tm := SysUtils.Now();
 
        for i:=1 to ArrLen-1
        do begin
            k:=i;
            el:=arr2^[i];
            for j:=i+1 to ArrLen
            do begin
                if arr2^[j] < el
                then begin
                    k:=j;
                    el:=arr2^[k];
                end;
            end;
            arr2^[k]:=arr2^[i];
            arr2^[i]:=el;
        end;
 
        stop_tm := SysUtils.Now();
        start_ms := TimeStampToMSecs( DateTimeToTimeStamp( start_tm ) );
        stop_ms := TimeStampToMSecs( DateTimeToTimeStamp( stop_tm ) );
        dur := double( stop_ms - start_ms ) * 1.0e-3;
        System.WriteLn('Продолжительность расчёта: ', dur:10:3, ' секунд.' );
        System.WriteLn();
    {$ifdef dfnPrintArray}
        System.WriteLn('После сортировки:');
        for el in arr2^
        do begin
            System.Write(el,' ');
        end;
        System.WriteLn();
    {$endif}
    finally
        System.Dispose(arr2);
        arr2:=nil;
    end;
    System.WriteLn();
end;
 
procedure SortDynamicArray2();
var
    start_tm, stop_tm : System.TDateTime;
    start_ms, stop_ms : comp;
    dur : double;
    el:longint;
    i,j,k:longint;
begin
    System.GetMem(arr3, ArrLen*sizeof(longint));
    try
        // копируем тестовый массив в рабочий массив
        for i:=System.Low(test_array) to System.High(test_array)
        do begin
            arr3[i-1]:=test_array[i];
        end;
 
        System.WriteLn('Динамический массив произвольной длины (GetMem) ',ArrLen);
    {$ifdef dfnPrintArray}
        System.WriteLn('Перед началом сортировки:');
        for i:=0 to ArrLen-1
        do begin
            System.Write(arr3[i],' ');
        end;
        System.WriteLn();
    {$endif}
        start_tm := SysUtils.Now();
 
        for i:=0 to ArrLen-2
        do begin
            k:=i;
            el:=arr3[i];
            for j:=i to ArrLen-1
            do begin
                if arr3[j] < el
                then begin
                    k:=j;
                    el:=arr3[k];
                end;
            end;
            arr3[k]:=arr3[i];
            arr3[i]:=el;
        end;
 
        stop_tm := SysUtils.Now();
        start_ms := TimeStampToMSecs( DateTimeToTimeStamp( start_tm ) );
        stop_ms := TimeStampToMSecs( DateTimeToTimeStamp( stop_tm ) );
        dur := double( stop_ms - start_ms ) * 1.0e-3;
        System.WriteLn('Продолжительность расчёта: ', dur:10:3, ' секунд.' );
        System.WriteLn();
    {$ifdef dfnPrintArray}
        System.WriteLn('После сортировки:');
        for i:=0 to ArrLen-1
        do begin
            System.Write(arr3[i],' ');
        end;
        System.WriteLn();
    {$endif}
    finally
        System.FreeMem(arr3);
        arr3:=nil;
    end;
    System.WriteLn();
end;
 
procedure SortDynamicArray3();
var
    start_tm, stop_tm : System.TDateTime;
    start_ms, stop_ms : comp;
    dur : double;
    el:longint;
    i,j,k:longint;
begin
    System.SetLength(arr4, ArrLen);
    // копируем тестовый массив в рабочий массив
    for i:=System.Low(test_array) to System.High(test_array)
    do begin
        arr4[i-1]:=test_array[i];
    end;
 
    System.WriteLn('Динамический массив произвольной длины (array of) ',ArrLen);
{$ifdef dfnPrintArray}
    System.WriteLn('Перед началом сортировки:');
    for i:=0 to ArrLen-1
    do begin
        System.Write(arr4[i],' ');
    end;
    System.WriteLn();
{$endif}
    start_tm := SysUtils.Now();
 
    for i:=0 to ArrLen-2
    do begin
        k:=i;
        el:=arr4[i];
        for j:=i to ArrLen-1
        do begin
            if arr4[j] < el
            then begin
                k:=j;
                el:=arr4[k];
            end;
        end;
        arr4[k]:=arr4[i];
        arr4[i]:=el;
    end;
 
    stop_tm := SysUtils.Now();
    start_ms := TimeStampToMSecs( DateTimeToTimeStamp( start_tm ) );
    stop_ms := TimeStampToMSecs( DateTimeToTimeStamp( stop_tm ) );
    dur := double( stop_ms - start_ms ) * 1.0e-3;
    System.WriteLn('Продолжительность расчёта: ', dur:10:3, ' секунд.' );
    System.WriteLn();
{$ifdef dfnPrintArray}
    System.WriteLn('После сортировки:');
    for i:=0 to ArrLen-1
    do begin
        System.Write(arr4[i],' ');
    end;
    System.WriteLn();
{$endif}
    System.WriteLn();
end;
 
 
begin
        // заполняем массив тестовыми данными
    FillTestArray();
 
    SortStaticArray();
    SortDynamicArray1();
    SortDynamicArray2();
    SortDynamicArray3();
 
end.