Помогите, пожалуйста, сделать вложенный цикл, но не через LOOP...

(defun task (k s r)
  (let ((r 0))
     (iter (for i from 1 to k)
           (iter (for y from 1 to s) 
               (summing  (/ (- r 4) (+ y y 1)) into r))) r)) 
 
==> TASK
 
(task 5 6 2)
 
==> -4445476837477900/14530697473149

(defun sum-loop (k s r)
  (loop for a from 1 to k sum
        (loop for b from 1 to s sum
              (/ (- r 4) (+ b b 1)))))
 
> (sum-loop 5 6 2)
-86048/9009

(defun sum-recursion (k s r &optional (z 0))
  (if (zerop k) z
      (sum-recursion (1- k) s r (+ z (sum k s r)))))
 
(defun sum (k s r &optional (z 0))
  (if (zerop s) z
      (sum k (1- s) r (+ z (/ (- r 4) (+ s s 1))))))
 
> (sum-recursion 5 6 2)
-86048/9009

> (* -86048/45045 5)
-86048/9009

(defun sum-loop (k s r)
  (* k (loop for b from 1 to s
             sum (/ (- r 4) (+ b b 1)))))
 
> (sum-loop 5 6 2)
-86048/9009

(defun sum-recursion (k s r) (* k (sum s r)))
 
(defun sum (s r &optional (z 0))
  (if (zerop s) z
      (sum (1- s) r (+ z (/ (- r 4) (+ s s 1))))))
 
> (sum-recursion 5 6 2)
-86048/9009

(defun sum-loop (k s r)
  (loop repeat k sum
        (loop for b from 1 to s
              sum (/ (- r 4) (+ b b 1)))))
 
> (sum-loop 5 6 2)
-86048/9009

(defun sum-loop (k s r &aux (z 0))
  (* k (dotimes (b s z)
         (setf z (+ z (/ (- r 4) (+ b b 3)))))))
 
> (sum-loop 5 6 2)
-86048/9009

(defun f (k s r)
  (prog ((y 1)
         (i 1)
         (sum 0))
   check-counters
     (if (> i k)
         (go result)
         (go sum))
   sum
     (incf sum (/ (- r 4)
                  (+ (* 2 y) 1)))
     (go next-counter)
   next-counter
     (if (< y s)
         (incf y)
         (progn
           (incf i)
           (setf y 1)))
     (go check-counters)
   result
     (return sum)))

(defun sum-[r-4]/[2y+1] (k s r)
  (* k (reduce #'+ (loop for a from 1 to s collect a)
               :key #'(lambda (e) (/ (- r 4) (+ e e 1))))))
 
> (sum-[r-4]/[2y+1] 5 6 2)
-86048/9009