Передача данных c МК51 по UART и вывод в терминал

;  вычисления по формуле 235 - 400*Т1 / Т2
;   где Т1 - значение таймера0 TH0:TL0
;       Т2 - значение таймера1 TH1:TL1
;
 
org 00h
 
; Умножение на 400
; Х= 400*Х= (16*Х + 8*Х + Х)*16
; Сумма в регистрах r7:r6:r5:r4
; Счетные регистры r3:r2:r1
;
 
;заносим в сумму Х .
; берем из таймера0
    mov r7,#00
    mov r6,#00
    mov r5,#10h
    mov r4,#20h
;заносим в счетные регистры Х.
    mov     r3,#00
    mov     a,r5
    mov     r2,a
    mov     a,r4
    mov     r1,a
; умножаем на 8 тремя сдвигами влево
    mov     r0,#03  ; три сдвига
m1:
    clr     c       ; сбрасываем С (он попадет в младший бит)
    mov     a,r1    ; младший байт в аккумулятор
    rlc     a       ; сдвиг влево через перенос
    mov     r1,a    ; обратно в регистр
    mov     a,r2    ; средний регистр в аккумулятор
    rlc     a       ; сдвиг влево через перенос
    mov     r2,a    ; обратно в регистр
    mov     a,r3    ; старший регистр в аккумулятор
    rlc     a       ; сдвиг влево через перенос
    mov     r3,a    ; обратно в регистр
    djnz    r0,m1   ; вычесть из r1 единицу и перейти, если r0 не равен 0
; складываем с суммой
    mov     a,r1    ; регистр в аккумулятор
    add     a,r4    ; складываем с регистром суммы
    mov     r4,a    ; обратно в регистр суммы
    mov     a,r2    ; регистр в аккумулятор
    addc    a,r5    ; складываем с регистром суммы с учетом переноса
    mov     r5,a    ; обратно в регистр суммы
    mov     a,r3    ; регистр в аккумулятор
    addc    a,r6    ; складываем с регистром суммы с учетом переноса
    mov     r6,a    ; обратно в регистр суммы
    clr     a       ; старший байт счетных регистров = 0
    addc    a,r7    ; складываем с регистром суммы с учетом переноса
    mov     r7,a    ; обратно в регистр суммы
; умножаем счетные регистры еще раз на 2. В итоге получится X*16
    clr     c
    mov     a,r1
    rlc     a
    mov     r1,a
    mov     a,r2
    rlc     a
    mov     r2,a
    mov     a,r3
    rlc     a
    mov     r3,a
; складываем с суммой
    mov     a,r1
    add     a,r4
    mov     r4,a
    mov     a,r2
    addc    a,r5
    mov     r5,a
    mov     a,r3
    addc    a,r6
    mov     r6,a
    clr     a
    addc    a,r7
    mov     r7,a
; умножаем сумму на 16 четырьмя сдвигами влево
    mov     r0,#04  ; четыре сдвига
m2:
    clr     c
    mov     a,r4
    rlc     a
    mov     r4,a
    mov     a,r5
    rlc     a
    mov     r5,a
    mov     a,r6
    rlc     a
    mov     r6,a
    mov     a,r7
    rlc     a
    mov     r7,a
    djnz    r0,m2
;
; Деление    сумма/Т2
; (r7:r6:r5:r4)/(r3:r2) = r5:r4
;
 
; делитель берем из таймера1
    mov     r3,#05h  ; старший байт
    mov     r2,#10h  ; младший байт
; проверяем на переполнение частного (если старшие два байта делимого >= делителю)
    clr     c       ; сбрасываем С, чтобы не повлиял на команду subb
    mov     a,r6    ; регистр в аккумулятор
    subb    a,r2    ; вычитаем
    mov     a,r7    ; регистр в аккумулятор
    subb    a,r3    ; вычитаем (важен С)
 
    jnc    div_error        ; если есть перенос(число больше), то уходим на ошибку
 
    mov     b,#16   ; 16 циклов
; сдвиг влево r7:r6:r5:r4
div16_0:
    clr     c
    mov     a,r4
    rlc     a
    mov     r4,a
    mov     a,r5
    rlc     a
    mov     r5,a
    mov     a,r6
    rlc     a
    mov     r6,a
    mov     a,r7
    rlc     a
    mov     r7,a
 
    jc      div16_3 ; если есть перенос, то вычесть делитель и прибавить 1 в частное r5:r4
; вычитаем делитель r3:r2
    mov     a,r6
    subb    a,r2
    mov     r6,a
    mov     a,r7
    subb    a,r3
    mov     r7,a
 
    jnc     div16_1 ; переноса нет, +1 к частному
; восстанавливаем остаток
    mov     a,r6
    add     a,r2
    mov     r6,a
    mov     a,r7
    addc    a,r3
    mov     r7,a
 
    sjmp    div16_2
; вычитаем остаток
div16_3:
    clr     c
    mov     a,r6
    subb    a,r2
    mov     r6,a
    mov     a,r7
    subb    a,r3
    mov     r7,a
; +1 к частному
div16_1:
    inc     r4
; следующий цикл
div16_2:
    djnz    b,div16_0
;
; 235 - r5:r4
;
 
; в r7:r6 заносим 235
    mov     r7,#00
    mov     r6,#235
; вычитаем
    clr     c
    mov     a,r6
    subb    a,r4
    mov     r4,a
    mov     a,r7
    subb    a,r5
    mov     r5,a
; В регистрах r5:r4 находится разница - результат вычислений.