Как преобразовать таблицу, повторить строку с нарастающим счетчиком от 1 до указаного числа - MS Access

http://www.sql.ru/forum/actualutils.aspx?action=gotomsg&tid=535505&msg=5414410

Private Sub test01()
'Выполнять можно сколько угодно раз ... :)
'Расчитано на любое кол-во квартир
Dim rs As DAO.Recordset
Dim rsDST As DAO.Recordset
Dim lRecID As Long
Dim i As Integer, iQty As Integer
Dim strCriteria As String
 
'Адреса
    Set rs = CurrentDb.OpenRecordset("Таблица_Адресов", dbOpenSnapshot)
'Квартиры
    Set rsDST = CurrentDb.OpenRecordset("Таблица_Квартир", dbOpenDynaset)
    
'Перебор всех записей в наборе Адреса
    With rs
        Do Until .EOF = True 'Цикл до конца набора
            lRecID = !Adress_ID 'ID текущего Адреса
            iQty = !kol_kv 'кол-во квартир
            For i = 1 To iQty
                strCriteria = "Adress_SID=" & lRecID & " AND kvNo=" & i
                With rsDST
                    If .EOF = False And .BOF = False Then .MoveFirst
                    .FindFirst strCriteria
                    If .NoMatch Then 'Если искомое не найдено - добавляем!
                        .AddNew
                            !Adress_SID = lRecID
                            !kvNo = i
                        .Update
                    End If
                End With
            Next i
            .MoveNext
        Loop
    End With
 
On Error Resume Next
    rs.Close
    Set rs = Nothing
    rsDST.Close
    Set rsDST = Nothing
 
End Sub