Работа с таблицами разделённой базы через экземпляры классов. Как?

Private Sub cmdGo_Click()
    Dim ctl As Control
    Dim objFrm As AccessObject
    Dim prp As Property
    Dim strFormName As String
    Dim strMeName As String
    Dim strSource As String
    
    Const coSourceFrom As String = "IN 'd:\.Programms\Office Access\accdb_ Предприятие\tables\Предприятие_таблицы.accdb';"
    Const coSourceTo As String = "IN 'd:\.Programms\Office Access\accdb_ Предприятие\tables\tables_in\Предприятие_таблицы.accdb';"
    
    On Error GoTo ErrorHandler
    
    strMeName = Me.Name
    ' отключаем обновление экрана
    Application.Echo False, "Идёт получение свойств. Это может занять значительное время. Подождите..."
    ' перечитываем все формы, сохранённые в базе
    For Each objFrm In CurrentProject.AllForms
        strFormName = objFrm.Name
        Select Case strFormName
            ' список форм, исключённых из обработки
            Case Is = strMeName, "Заставка", "frmAndmDeveloper", "frmAndmReLincTables" _
                                , "frmAndmSincCenter", "frmAndmSincro"
            Case Else
                ' открываем форму
                DoCmd.OpenForm strFormName, acDesign
                
                ' выбираем свойство "источник записей"
                Set prp = Forms(strFormName).Properties("RecordSource")
                ' изсеняем источник данных
                If Not IsNull(prp.Value) Then
                    strSource = prp.Value
                    prp.Value = Replace(strSource, coSourceFrom, coSourceTo)
                End If
                
                ' перечитываем элементы формы
                For Each ctl In Forms(strFormName).Controls
                    ' выбираем свойство "тип элемента"
                    Set prp = ctl.Properties("ControlType")
                    ' если это ComboBox
                    If prp.Value = 111 Then
                        ' выбираем свойство "источник строк"
                        Set prp = ctl.Properties("RowSource")
                        ' изсеняем источник данных
                        If Not IsNull(prp.Value) Then
                            strSource = prp.Value
                            prp.Value = Replace(strSource, coSourceFrom, coSourceTo)
                        End If
                    End If
                Next ctl
                
                ' закрываем форму с сохранением изменений
                DoCmd.Close acForm, strFormName, acSaveYes
        End Select
    Next objFrm
    
    ' включаем обновление экрана
    Application.Echo True, "Получение свойств завершено."
    MsgBox "Обработка окончена"
    Exit Sub
    
ErrorHandler:
    MsgBox "Error " & err.Number & " in " & err.Source & vbCr _
            & err.Description
    err.Clear
    Resume Next
End Sub