Предыдущая запись как значение по умолчанию

Private Sub Form_Current()
'Событие текущая запись
'При переходе на новую запись - Делаем копию предидущей с запросом по DLookUp()
'Опираемся на то, что у новой записи - поле счётчика = Null
'--------------------------------------------------------------------------
Dim lPrevRecordID As Long, v As Variant
On Error GoTo Form_Current_Err
    If IsNull(Me!Код) = True Then 'проверяем поле счётчика ....
    
    'Запрос поддтверждения - при ответе НЕТ - остановка
        If MsgBox("Вы на новой записи  - Скопировать данные предидущей?", _
            vbYesNo + vbQuestion + vbDefaultButton1, _
            "Новая запись") = vbNo Then Exit Sub
    'Собственно копирование
    v = DLookup("Max(Код)", "Табель") ' Ищем посл. запись
    
    If IsNull(v) Then Exit Sub
    lPrevRecordID = CLng(v)
    Me!cbФИО = DLookup("ФИО", "Табель", "Код = " & lPrevRecordID)
    Me!txtДолжность = DLookup("Должность", "Табель", "Код = " & lPrevRecordID)
    Me!txtТабельный_номер = DLookup("[Табельный номер]", "Персонал", "Код = " & lPrevRecordID)
    
    End If
Form_Current_Bye:
    Exit Sub
 
Form_Current_Err:
    MsgBox "Ошибка " & Err.Number & vbCrLf & Err.Description & vbCrLf & "в процедуре: Form_Current", vbCritical, "Error in module Form_Табель"
    Resume Form_Current_Bye
End Sub

Private Sub Form_Current()
On Error GoTo Form_Current_Err
    If Me.NewRecord Then
        With Me.RecordsetClone
            If Not (.EOF And .BOF) Then
                .MoveLast
                    If Not IsNull(.Fields("[ФИО]")) Then'вообще-то это решается на уровне таблицы - отсутствие у записи важного атрибута
                        Me.cbФИО = .Fields("[ФИО]")
                        Me.txtДолжность = .Fields("[Должность]")
                        Me.txtТабельный_номер = .Fields("[Табельный номер]")
                    End If
            End If
        End With
    End If
Form_Current_Bye:
    Exit Sub
Form_Current_Err:
    MsgBox "Ошибка " & Err.Number & vbCrLf & Err.Description & vbCrLf & "в процедуре: Form_Current", vbCritical, "Error in module Form_Табель"
    Resume Form_Current_Bye
End Sub

     if len(me.user) = 0 then
     Dim wsnet
     Set wsnet = CreateObject("wscript.network")
     me.user = wsnet.UserName
     end if