Преобразовать дату из текстовой строки в DATETIME

@VirtualMan · Регистрация: 21.07.2016

Студворк — интернет-сервис помощи студентам

В экселе сейчас текстовые поля вместо дат:
1 марта в 19:24
вчера в 09:45
сегодня в 09:45
и т.д.

Как преобразовать в формат YYYY-MM-DD HH:MM:SS, чтобы потом можно было импорт CSV в SQL сделать?

Заранее благодарю!

@pashulka · 01.01.2017, 16:15

Можно программно удалить " в", а затем, заменить "вчера" на Date-1, "сегодня" на Date, а "завтра" на Date+1. После чего, использовать функцию CDate + соответствующий формат ячеек (если нужна именно дата) или Format (ежели нужен текст)

P.S. Если существует вероятность наличия текста, типа "100 дней до приказа", то перед вызовом функции CDate имеет смысл добавить проверку (см. функцию IsDate)

@AlexM · 01.01.2017, 17:01

Можно использовать формулу

Code
1
=ЕСЛИ(ЕОШ(-ЛЕВБ(A1));СЕГОДНЯ()-ПРОСМОТР(2;ПОИСК({"вчера";"сегодня"};A1);{1;0});ЛЕВБ(ПОДСТАВИТЬ(A1;"я ";"й ");6))+ПРАВБ(A1;5)

Результат потом копировать и вставить специальной вставкой "значения", чтобы убрать функцию СЕГОДНЯ(). Иначе на следующий день функция СЕГОДНЯ() вернет другое значение

@VirtualMan · 01.01.2017, 17:30 **[ТС]**

Сообщение от AlexM

Можно использовать формулу

Большое спасибо, то что нужно.
Но один момент как итоговый год с текущего 2017 поменять на 2016 или 2015?

@AlexM · 01.01.2017, 18:41

Для сегодня и вчера, я полагаю, год не надо менять.

Code
1
=ЕСЛИ(ЕОШ(-ЛЕВБ(A1));СЕГОДНЯ()-ПРОСМОТР(2;ПОИСК({"вчера";"сегодня"};A1);{1;0});ЛЕВБ(ПОДСТАВИТЬ(A1;"я ";"й ");6)&E$1)+ПРАВБ(A1;5)

Год задается в ячейке Е1 или в формуле заменить ссылку на число 2016 или 2015

@VirtualMan · 01.01.2017, 20:02 **[ТС]**

Обнаружил проблему если месяц июль.
Насколько понимаю здесь как то связано с окончанием и формула вместо июля получает июлй

@AlexM · 01.01.2017, 22:33

Либо формат даты должен быть с числом из двух знаков, например 01, 09, 22 или усложнять формулу

Code
1
=ЕСЛИ(ЕОШ(-ЛЕВБ(A1));СЕГОДНЯ()-ПРОСМОТР(2;ПОИСК({"вчера";"сегодня"};A1);{1;0});ЛЕВБ(ПОДСТАВИТЬ(ЕСЛИ(ЕОШ(-ЛЕВБ(A1;3));0;"")&A1;"я ";"й ");6)&E$1)+ПРАВБ(A1;5)

@VirtualMan · 02.01.2017, 23:39 **[ТС]**

Спасибо.
Бьюсь пару часов не могу решить другую задачу.
Все победил кроме условия с $, не могу понять что не так делаю.

Code
1
=ЕСЛИ(ИЛИ(A1="не указана";A1="договорная");СЖПРОБЕЛЫ(A1);СЖПРОБЕЛЫ(ЕСЛИ(ПОИСК("руб";A1)>0;ПСТР(A1;1;ПОИСК("руб";A1)+2);ЕСЛИ(ПОИСК("$";A1)>0;ПСТР(A1;1;ПОИСК("$";A1))))))

@AlexM · 03.01.2017, 00:13

Code
1
=ЕСЛИ(ЕОШ(-ЛЕВБ(A1));A1;ЛЕВБ(A1;ПРОСМОТР(99;ПОИСК({"руб";"$"};A1)+{2;0})))

@AlexM · 03.01.2017, 10:04

Ваша формула без ошибок

Code
1
=ЕСЛИ(ИЛИ(A1="не указана";A1="договорная");СЖПРОБЕЛЫ(A1);СЖПРОБЕЛЫ(ЕСЛИ(ЕЧИСЛО(ПОИСК("руб";A1));ПСТР(A1;1;ПОИСК("руб";A1)+2);ЕСЛИ(ЕЧИСЛО(ПОИСК("$";A1));ПСТР(A1;1;ПОИСК("$";A1))))))

Ваша формула упрощенная

Code
1
=СЖПРОБЕЛЫ(ЕСЛИ(ЕЧИСЛО(ПОИСК("руб";A1));ПСТР(A1;1;ПОИСК("руб";A1)+2);ЕСЛИ(ЕЧИСЛО(ПОИСК("$";A1));ПСТР(A1;1;ПОИСК("$";A1));A1)))

В файле три формулы

@AlexM · 03.01.2017, 10:13

Еще короткая формула

Code
1
=ЛЕВБ(A1;ПРОСМОТР(99;ПОИСК({"|";"руб";"$"};A1&"|")+{0;2;0}))

В файле 4 формулы

@AlexM · 03.01.2017, 11:07

Интересная новогодняя задача :)

Code
1
=ЛЕВБ(A1;ГПР(99;ПОИСК({"|";"руб";"$"};A1&"|")+{0;2;0};1))

Добавлено через 46 минут

Code
1
=ЛЕВБ(A1;ГПР(99;ПОИСК({"|";"руб";"$"};A1&"|")+2;1))

@VirtualMan · 03.01.2017, 11:32 **[ТС]**

Еще большое спасибо, в том числе за оптимизацию, узнал много нового в экселе для себя)
Вопрос закрыт

@AlexM · 03.01.2017, 11:34

Еще короче

Code
1
=ЛЕВБ(A1;ГПР(99;ПОИСК({0;"руб";"$"};A1&0)+2;1))

Новые блоги и статьи Все статьи Все блоги /
Как дизайн сайта влияет на конверсию: 7 решений, которые реально повышают заявки Neotwalker 08.03.2026 Многие до сих пор воспринимают дизайн сайта как “красивую оболочку”. На практике всё иначе: дизайн напрямую влияет на то, оставит человек заявку или уйдёт через несколько секунд. Даже если у вас. . .	Модульная разработка через nuget packages DevAlt 07.03.2026 Сложившийся в . Net-среде способ разработки чаще всего предполагает монорепозиторий в котором находятся все исходники. При создании нового решения, мы просто добавляем нужные проекты и имеем. . .	Модульный подход на примере F# DevAlt 06.03.2026 В блоге дяди Боба наткнулся на такое определение: В этой книге («Подход, основанный на вариантах использования») Ивар утверждает, что архитектура программного обеспечения — это структуры,. . .	Управление камерой с помощью скрипта OrbitControls.js на Three.js: Вращение, зум и панорамирование 8Observer8 05.03.2026 Содержание блога Финальная демка в браузере работает на Desktop и мобильных браузерах. Итоговый код: orbit-controls-threejs-js. zip. Сканируйте QR-код на мобильном. Вращайте камеру одним пальцем,. . .
SDL3 для Web (WebAssembly): Синхронизация спрайтов SDL3 и тел Box2D 8Observer8 04.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-sync-physics-sprites-sdl3-c. zip На первой гифке отладочные линии отключены, а на второй включены:. . .	SDL3 для Web (WebAssembly): Идентификация объектов на Box2D v3 - использование userData и событий коллизий 8Observer8 02.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-collision-events-sdl3-c. zip Сканируйте QR-код на мобильном и вы увидите, что появится джойстик для управления главным героем. . . .	Реалии Hrethgir 01.03.2026 Нет, я не закончил до сих пор симулятор. Эта задача сложнее. Не получилось уйти в плавсостав, но оно и к лучшему, возможно. Точнее получалось - но сварщиком в палубную команду, а это значит, в моём. . .	Ритм жизни kumehtar 27.02.2026 Иногда приходится жить в ритме, где дел становится всё больше, а вовлечения в происходящее — всё меньше. Плотный график не даёт вниманию закрепиться ни на одном событии. Утро начинается с быстрых,. . .

@VirtualMan 2 / 2 / 1 Регистрация: 21.07.2016 Сообщений: 46

	Преобразовать дату из текстовой строки в DATETIME 01.01.2017, 15:01. Показов 3516. Ответов 13 Метки нет (Все метки) В экселе сейчас текстовые поля вместо дат: 1 марта в 19:24 вчера в 09:45 сегодня в 09:45 и т.д. Как преобразовать в формат YYYY-MM-DD HH:MM:SS, чтобы потом можно было импорт CSV в SQL сделать? Заранее благодарю! 0

@pashulka 4139 / 2243 / 940 Регистрация: 01.12.2010 Сообщений: 4,624
	01.01.2017, 16:15
	Можно программно удалить " в", а затем, заменить "вчера" на Date-1, "сегодня" на Date, а "завтра" на Date+1. После чего, использовать функцию CDate + соответствующий формат ячеек (если нужна именно дата) или Format (ежели нужен текст) P.S. Если существует вероятность наличия текста, типа "100 дней до приказа", то перед вызовом функции CDate имеет смысл добавить проверку (см. функцию IsDate) 0

@VirtualMan 2 / 2 / 1 Регистрация: 21.07.2016 Сообщений: 46
	03.01.2017, 11:32 [ТС]
	Еще большое спасибо, в том числе за оптимизацию, узнал много нового в экселе для себя) Вопрос закрыт 0

Преобразовать дату из текстовой строки в DATETIME

Решение