Объясните понятие ООП

(defclass point ()
  ((label :initarg :label :reader point-label)
   (x :type number :initarg :x :reader point-x)
   (y :type number :initarg :y :reader point-y)))
 
(defmethod print-object ((p point) stream)
  (format stream "~a(~a, ~a)" (point-label p) (point-x p) (point-y p)))
 
(defgeneric distance (a b))
 
(defun pythagoras (x1 y1 x2 y2)
  (sqrt (+ (expt (- x1 x2) 2)
           (expt (- y1 y2) 2))))
 
(defun not-applicable (method-name &rest objects)
  (let ((class-names
         (loop :for object :in objects
               :collect (class-name (class-of object)))))
    (format nil "~s is not applicable to ~s." method-name class-names)))
 
(defmethod distance ((a point) (b point))
  (pythagoras (point-x a) (point-y a)
              (point-x b) (point-y b)))
 
(defmethod distance ((a point) (b number))
  (not-applicable 'distance a b))
 
(defmethod distance ((a number) (b point))
  (not-applicable 'distance a b))
 
(defmethod distance ((a complex) (b complex))
  (pythagoras (realpart a) (imagpart a)
              (realpart b) (imagpart b)))
 
(defmethod distance ((a number) (b complex))
  (pythagoras a 0 (realpart b) (imagpart b)))
 
(defmethod distance ((a number) (b complex))
  (pythagoras (realpart a) (imagpart a) b 0))
 
(defmethod distance ((a number) (b number))
  (abs (- a b)))
 
; ----------------------------------------------------------------
 
(let ((a (make-instance 'point :label "A" :x 1.2 :y -3))
      (b (make-instance 'point :label "B" :x 2 :y 3))
      (x (complex 1.2 -3))
      (y (complex 2 3))
      (i 1.2)
      (j 3/4))
  (let ((objects `((a ,a) (b ,b) (x ,x) (y ,y) (i ,i) (j ,j))))
    (loop :for (name object) :in objects :do
      (format t "~a = ~a~%" name object))
    (loop :for ((a-name a) . rest-objects) :on objects :do
      (format t "~%")
      (loop :for (b-name b) :in rest-objects :do
        (format t "distance between ~a and ~a is ~a~%"
                  a-name b-name (distance a b))))))