Обработка файлов)

program Project1;
 
(*Подсчитывает количество слов в строке aStr, которые начинаются и заканчиваются
на одну и ту же букву, независимо от регистра.*)
function CountWord(const aStr : String) : Word;
const
  (*Множество разделителей.*)
  Delims = [' ', '.', ',', ':', ';', '!', '?', '-'];
var
  (*Индексы символов строки.*)
  i : Integer;
  (*Очередное слово, выделенное из строки.*)
  StrWord : String;
  (*Количество заданных слов в строке.*)
  Res : Word;
begin
  Res := 0;
  StrWord := '';
  (*Перебор всех символов строки.*)
  for i := 1 to Length(aStr) do begin
    (*Если символ не является разделителем - добавляем его к слову.*)
    if not (aStr[i] in Delims) then StrWord := StrWord + aStr[i];
    (*Отслеживаем конец слова.*)
    if ( (aStr[i] in Delims) or (i = Length(aStr)) ) and (StrWord <> '') then begin
      (*Если первая и последняя буквы слова совпадают (независимо от регистра),
      то подсчитываем это слово.*)
      if UpCase(StrWord[1]) = UpCase( StrWord[ Length(StrWord) ] ) then Inc(Res);
      StrWord := '';
    end;
  end;
 
  CountWord := Res;
end;
 
const
  FileName = 'data.txt';
var
  F : Text;
  StrTmp : String;
  CntWord : Word;
begin
  (*Связываем файловую переменную с именем файла.*)
  Assign(F, FileName);
 
  (*Записываем тестовые данные в файл.*)
  Rewrite(F);
  Writeln(F, 'a abcdef A abcdef Aa abcdef Abcdefa abcdef');
  Writeln(F, 'a abcdef A abcdef Aa abcdef Abcdefa abcdef');
  Write(F, 'a abcdef A abcdef Aa abcdef Abcdefa abcdef');
 
  Writeln('Содержимое входного файла:');
  Writeln('----------');
  Reset(F);
  while not Eof(F) do begin
    Readln(F, StrTmp);
    Writeln(StrTmp);
  end;
  Writeln('----------');
 
  (*Производим подсчёт.*)
  Reset(F);
  CntWord := 0;
  while not Eof(F) do begin
    Readln(F, StrTmp);
    CntWord := CntWord + CountWord(StrTmp);
  end;
 
  (*Закрываем файл.*)
  Close(F);
 
  (*Показываем результат подсчёта.*)
  Writeln('Количество слов с одинаковой буквой (независимо от регистра) в начале и в конце = ', CntWord);
 
  Readln;
end.