Реализовать программу, которая "сжимает" текстовый файл, считывая его и заменяя все повторяющиеся символы

program Project1;
 
const
  {Имена входного и выходного файлов.}
  FnIn = 'file_in.txt';
  FnOut = 'file_out.txt';
var
  FIn, FOut : Text;
  S, Sw, SRes : String;
  Ch : Char;
  i, Len, LenW : Integer;
begin
  {Связываем файловые переменные с именами файлов.}
  Assign(FIn, FnIn);
  Assign(FOut, FnOut);
 
  repeat
    Writeln('Входной файл: ', FnIn);
    Writeln('Выходной файл: ', FnOut);
    Writeln('Выполнить обработку - д, Д, y, Y. Любой другой символ - выход.');
    Readln(S);
    if (S = '') or not (S[1] in ['д', 'Д', 'y', 'Y']) then
      Break;
 
    {Открываем файлы.}
    Reset(FIn);
    Rewrite(FOut);
 
    {Обработка файла.}
    SRes := ''; {Строка для записи в выходной файл.}
    Ch := #0; {Предыдущий символ.}
    LenW := 0; {Счётчик символов в последовательности одинаковых символов.}
    while not Eof(FIn) do
    begin
      Readln(FIn, S); {Читаем очередную строку из входного файла.}
      {Обработка строки.}
      Len := Length(S);
      for i := 1 to Len do
      begin
        Inc(LenW); {Подсчёт текущего символа.}
        {Если обнаружен конец последовательности одинаковых символов.
        (LenW > 1) and (S[i] <> Ch) = True - последовательность закончилась
        на предыдущем символе.
        (i = Len) and Eof(FIn) = True - последовательнось закончилась на текущем
        символе в связи с тем, что достигнут конец файла.}
        if (LenW > 1) and (S[i] <> Ch) or (i = Len) and Eof(FIn) then
        begin
          if (LenW > 1) and (S[i] <> Ch) then {Если последовательность закончилась на предыдущем символе.}
          begin
            Str(LenW - 1, Sw);
            SRes := SRes + Sw + '(' + Ch + ')';
            LenW := 1; {Сбрасываем счётчик и учитываем текущий символ в подсчёте.}
          end
          else  {Если последовательность закончилась на текущем символе.}
          begin
            Str(LenW, Sw);
            SRes := SRes + Sw + '(' + S[i] + ')';
            LenW := 0; {Сброс счётчика.}
          end;
        end;
        Ch := S[i]; {Запоминаем символ.}
      end;
      if (Length(SRes) >= 50) or ((SRes <> '') and Eof(FIn)) then {Запись в выходной файл.}
      begin
        Write(FOut, SRes);
        SRes := '';
      end;
    end;
 
    {Закрываем файлы.}
    Close(FIn);
    Close(FOut);
    Writeln('Обработка завершена.');
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.