Написать программу которая выведет на экран все буквы латинствого алфавита с кодом ASCII и частотой появления

program Project1;
 
const
  D = ['A'..'Z', 'a'..'z']; {Множество английских букв.}
  Fn = 'file_in.txt';
var
  F : Text;
  S : String;
  Ch : Char;
  i, Cnt, CntMax : Longint;
  {Это тоже самое что и: Arr : array[#0..#255] of Longint;}
  Arr : array[Char] of Longint;
begin
  {Связываем файловую переменную с именем файла.}
  Assign(F, Fn);
  repeat
    {Попытка открыть входной файл для чтения.}
    Writeln('Входной файл: ', Fn);
    {$I-}
    Reset(F);
    {$I+}
    if IOResult <> 0 then
    begin
      Writeln('Не удалось открыть входной файл! Возможно, он не создан или занят другим приложением.');
      Writeln('Повторить - Enter, выход - любой символ + Enter.');
      Readln(S);
      Continue;
    end;
 
    {Обнуляем элементы массива статистики.}
    for Ch := #0 to #255 do
      Arr[Ch] := 0;
    {Читаем построчно данные из входного файла и выполняем обработку.}
    Cnt := 0; {Общее количество английских букв, найденных в файле.}
    CntMax := 0; {Наибольшее количество присутствий среди английских букв.}
    while not Eof(F) do
    begin
      {Чтение из файла очередной строки.}
      Readln(F, S);
      {Обработка данных строки.}
      for i := 1 to Length(S) do
      begin
        Inc(Arr[S[i]]); {Сбор статистики.}
        {Определение общего количества английских букв и наибольшего числа
        присутствий среди английских букв.}
        if S[i] in D then
        begin
          Inc(Cnt);
          if Arr[S[i]] > CntMax then
            CntMax := Arr[S[i]];
        end;
      end;
    end;
    Close(F); {Закрываем входной файл.}
 
    {Показываем статистику по английским буквам.}
    Writeln('Всего английских букв в файле: ', Cnt);
    Writeln('Статистика использования английских букв:');
    i := 0;
    for Ch := #0 to #255 do
      if Ch in D then
      begin
        {После каждого 3-го элемента переходим на следующую строку.
        Иначе (если предыдущий элемент не является 3-им), записываем
        разделитель.
        0, 1, 2
        3, 4, 5
        6, 7, 8
        ...}
        if i > 0 then
          if i mod 3 = 0 then
            Writeln
          else
            Write(','#9);
        Write('"', Ch, '" - #', Ord(Ch):3, ' - ', Arr[Ch], ' - ', Arr[Ch]/Cnt:0:3);
        Inc(i);
      end;
    Writeln;
 
    {Показываем сведения о наиболее частых английских буквах.}
    if CntMax = 0 then
      Writeln('В тексте нет ни одной английской буквы.')
    else
    begin
      Writeln('Наибольшее количество присутствий: ', CntMax);
      Writeln('Перечень английских букв с наибольшим количеством присутствий:');
      i := 0;
      for Ch := #0 to #255 do
        if (Ch in D) and (Arr[Ch] = CntMax) then
        begin
          if i > 0 then
            Write(', ');
          Write(Ch);
          Inc(i);
        end;
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

const
  CLatin = ['A'..'Z','a'..'z'];
var
  c: array ['A'..'z'] of integer;
  i, m: integer;
  s: string;
  ch: char;
begin
  WriteLn('Введите текст. Завершение ввода - пустая строка.');
  repeat
    ReadLn(s);
    for i:=1 to Length(s) do
      if s[i] in CLatin then begin
        Inc(c[s[i]]); if c[s[i]]>m then m:=c[s[i]];
      end;
  until s='';
  if m=0 then WriteLn('Текст не содержит латинских символов')
  else begin
    WriteLn('Статистика (символ, код, частота):');
    for ch:='A' to 'Z' do if c[ch] <> 0 then WriteLn(ch,ord(ch):4,c[ch]:6);
    for ch:='a' to 'z' do if c[ch] <> 0 then WriteLn(ch,ord(ch):4,c[ch]:6);
    WriteLn('Чаще всего встречаются:');
    for ch:='A' to 'z' do if c[ch] = m then WriteLn(ch,ord(ch):4,c[ch]:6);
  end;
end.