Перестановка элементов в динамическом списке

type
  TData = Integer;
  TPElem = ^TElem;//указатель на элемент
  TElem = record
    Data : TData;
    PNext : TPElem;//Указатель на следующий элемент.
  end;
  TDList = record
    PFirst, PLast : TPElem; //1ый и последний элемент списка
  end; 
procedure Init(var aL : TDList);//создание "головы"и"хвоста"
begin
  aL.PFirst := nil;
  aL.PLast := nil;
end;  
 
procedure Print(const aL : TDList);//вывод на экран
var
  P : TPElem;
begin
  P := aL.PFirst; {Указатель на первый элемент списка.}
  if P <> nil then
  repeat
    if P <> aL.PFirst then//после первого элемента ставим запятую
      Write(', ');
    Write(P^.Data); //Распечатываем данные текущего элемента
    P := P^.PNext; //Получаем указатель на следующий элемент
  until P = nil
  else
    Write('Список пуст.');
  Writeln;
end;
procedure AddDesc(var aL : TDList; const aData : TData);//добавление элементов
var
  PNew, PCur, PPrev : TPElem;
begin
  New(PNew); 
  PNew^.Data := aData; 
  PCur := aL.PFirst;// текущий элемент
  PPrev := nil;
  while (PCur <> nil)do 
  begin
    PPrev := PCur;
    PCur := PCur^.PNext;
  end;
  PNew^.PNext := PCur;//вставка
  if PPrev <> nil then {Добавление между PPrev и PCur, либо - в конец списка.}
    PPrev^.PNext := PNew
  else {Добавление в начало списка.}
    aL.PFirst := PNew;
  if PNew^.PNext = nil then 
    aL.PLast := PNew;
end;
procedure Swap(Var al:TDlist);//обмен минимального с последним положительным
var PNew,PCur,PPrev,PPrevPol,PMin,PPol:TPElem;
begin
  PCur:=al.PFirst;//указатель
  PMin:=al.PFirst;//минимальный элемент
  PPol:=al.PFirst;//положительный
  while(PCur<>nil)do//поиск минимума 
  begin
    if (PMin^.Data<PCur^.Data) then//поиск минимума
    begin
      PMin^.Data:=PCur^.Data;//копирование информационного поля
      PMin^.PNext:=PCur^.PNext;//ссылка на следующий 
      PPrev:=PCur;//ссылка на текущий
    end; 
    PCur:=PCur^.PNext;
  end;
  PCur:=al.PFirst;
  while(PCur<>nil)do
  begin
    if(PCur^.Data>0)then//поиск последнего положительного
    begin
      PPol^.Data:=PCur^.Data;//копирование инф. части
      PPol^.PNext:=PCur^.PNext;//ссылка на следующий
      PPrevPol:=Pcur;//ссылка на текущий
    end;
    PCur:=PCur^.PNext;
  end;
  PCur:=al.PFirst;
  while(PCur<>Nil)do//обмен это часть не получается
  begin
    if(PCur=PPrev)then
    begin
      PPol^.PNext:=PCur^.PNext;
      dispose(PCur);
    end;
    if(PCur=PPrevPol)then
    begin
      PMin^.PNext:=PCur^.PNext;
      dispose(PCur);
    end;
    PCur:=PCur^.PNext;
  end;
end;
 
//основная программа
var
  L1 : TDList;
  i,m : Integer;
Begin
  Init(L1);
  write('введите кол-во элементов 1-ого списка: ');
  readln(m);
  {Создаём исходные списки.}
  randomize;
  for i := 1 to m do
    AddDesc(L1,random(100)-50);
  writeln('исходный список:');  
  Print(L1);
  Swap(L1);
  {ответ}
  writeln('после обмена :');
  Print(L1);
End.

{Обмен данных между первым наименьшим и последним положительным элементами.}
procedure Swap(const al : TDList);
var
  PCur, PMin, PPol:TPElem;
  Data : TData;
begin
  {Ищем указатели на первый наименьший и на последний положительный элементы.}
  PCur := al.PFirst;
  PMin := PCur;
  PPol := nil;
  while PCur <> nil do
  begin
    if PCur^.Data < PMin^.Data then
      PMin := PCur;
    if PCur^.Data > 0 then
      PPol := PCur;
    PCur := PCur^.PNext;
  end;
  {Обмен данных между элементами.}
  if (PMin <> PPol) and (PPol <> nil) then
  begin
    Data := PMin^.Data;
    PMin^.Data := PPol^.Data;
    PPol^.Data := Data;
  end;
end;

{Добавление элемента в конец списка.}
procedure Add(var aL : TDList; const aData : TData);
var
  P : TPElem;
begin
  New(P); {Выделяем паямять для элемента.}
  P^.Data := aData; {Записываем данные.}
  {Так как добавляемый элемент будет последним в списке, то указатель
  на следующий элемент делаем равным NIL.}
  P^.PNext := nil;
  {Если список пуст, то новый элемент станет первым элементом списка.}
  if aL.PFirst = nil then
    aL.PFirst := P
  {Если список непустой, то новый элемент прикрепляем к последнему элементу списка.}
  else
    aL.PLast^.PNext := P;
  {Новый элемент становится последним элементом списка.}
  aL.PLast := P;
end;

type
  //Тип основных данных.
  TData = record
    A, B, C : Integer;
    D, E : String[20];
  end;
  TPData = ^TData; //Указатель на основные данные.
  TPElem = ^TElem; //Указатель на элемент.
  TElem = record
    PData : TPData; //Указатель на основные данные.
    PNext : TPElem; //Указатель на следующий элемент списка.
  end;
  TDList = record
    PFirst, PLast : TPElem; //Указатели на первый и последний элементы списка.
  end;

  PData := PElem1^.PData;
  PElem1^.PData := PElem2^.PData;
  PElem2^.PData := PData;