Напечатать в алфавитном порядке все гласные буквы, которые входят в каждое слово

@Dzhen · Регистрация: 25.06.2014

Студворк — интернет-сервис помощи студентам

Дан текст на русском языке . Напечатать в алфавитном порядке все гласные буквы , которые входят в каждое слово.
Помогите, пожалуйста. Задача на множества. Паскаль

@Mawrat · 25.06.2014, 19:15

Сообщение от Dzhen

Напечатать в алфавитном порядке все гласные буквы , которые входят в каждое слово.

Решение.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
program Project1;
 
{Задача:
Напечатать в алфавитном порядке все гласные буквы, которые входят в каждое слово.}
 
{Перевод букв строки в верхний регистр. Для кодовой страницы CP866 (DOS).}
function UpCase866(const aStr : String) : String;
var
  S : String;
  i : Integer;
begin
  S := aStr;
  for i := 1 to Length(S) do
    if S[i] in ['а'..'п'] then
      S[i] := Chr(Ord(S[i]) - 32)
    else if s[i] in ['р'..'я'] then
      S[i] := Chr(Ord(S[i]) - 80)
    else if S[i] = 'ё' then
      S[i]:='Ё'
    else
      S[i] := UpCase(S[i]);
  UpCase866 := S;
end;
 
const
  {Множество разделителей слов.}
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  {Множество гласных букв.}
  Da = [
    {Русские гласные буквы.}
    'А', 'Я', 'О', 'Ё', 'Ы', 'И', 'Э', 'Е', 'У', 'Ю',
    {Английские гласные буквы.}
    'A', 'E', 'I', 'O', 'U', 'Y' ];
var
  S : String;
  Dw, Dra : set of Char;
  Ch : Char;
  i, Len : Integer;
  F : Boolean;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    {Решение.}
    S := UpCase866(S); {Приводим буквы строки к верхнему регистру.}
    Len := Length(S); {Длина строки.}
    Dw := []; {Множество букв, которые входят в текущее слово.}
    Dra := []; {Множество гласных букв, которые входят в каждое слово.}
    F := True; {True - найдено первое слово, иначе - False.}
    for i := 1 to Len do
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Dw := Dw + [S[i]]; {Добавляем букву во множество букв текущего слова.}
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          if F then {Если текущее слово является первым словом в тексте.}
          begin
            Dra := Dw * Da; {Все гласные буквы текущего слова.}
            F := False;
          end
          else {Если текущее слово не первое в тексте (второе, третье и т. д.)}
            Dra := Dw * Da * Dra; {Гласные буквы текущего слова, которые входят в каждое из предыдущих слов.}
          if Dra = [] then {Если искомое множество уже пусто, то прерываем обработку.}
            Break;
          Dw := []; {Обнуление множества букв текущего слова.}
        end;
      end;
 
    {Ответ.}
    if Dra = [] then
      Writeln('Нет ни одной гласной буквы, которая бы входила в каждое слово.')
    else
    begin
      Writeln('Множество гласных букв, которые входят в каждое слово:');
      for Ch := #0 to #255 do
        if Ch in Dra then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

@Dzhen · 26.06.2014, 00:01 **[ТС]**

как-то сложно получается..

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Program pr;
Const
G='аеёиоуыэюя';
type Alf='а'..'я';
var glasn,k,w:set of Alf;
s:string[100];
I:byte;
begin
writeln('введите текст ');
readln(s);
glasn :=['а','е','ё','и','о','у','ы','э','ю','я'];
i:= length(s);
while i <> 0 do
begin
 if s[i] in glasn
         then k:=k+[s[i]];
 i:=i-1;
 w:=glasn-k;
end;
for i:=1 to length(G) do
if G[i] in k then writeln(G[i]);
readln;
end.

можно эту программу исправить..

@Mawrat · 26.06.2014, 00:31

Сообщение от Dzhen

можно эту программу исправить..

Можно. Только опять получится то, что я написал.

---
Ну можно, например, в моём коде убрать английские гласные буквы. Кроме этого, если во множестве гласных букв оставить только строчные буквы, то можно убрать функцию UpCase866().
Тогда получится следующее:

Напечатать в алфавитном порядке все строчные русские гласные буквы, которые входят в каждое слово.

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
program Project1;
 
{Задача:
Напечатать в алфавитном порядке все строчные русские гласные буквы, которые входят в каждое слово.}
 
const
  {Множество разделителей слов.}
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  {Множество русских гласных букв (только строчные буквы).}
  Da = ['а', 'я', 'о', 'ё', 'ы', 'и', 'э', 'е', 'у', 'ю'];
var
  S : String;
  Dw, Dra : set of Char;
  Ch : Char;
  i, Len : Integer;
  F : Boolean;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    {Решение.}
    Len := Length(S); {Длина строки.}
    Dw := []; {Множество букв, которые входят в текущее слово.}
    Dra := []; {Множество гласных букв, которые входят в каждое слово.}
    F := True; {True - найдено первое слово, иначе - False.}
    for i := 1 to Len do
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Dw := Dw + [S[i]]; {Добавляем букву во множество букв текущего слова.}
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          if F then {Если текущее слово является первым словом в тексте.}
          begin
            Dra := Dw * Da; {Все гласные буквы текущего слова.}
            F := False;
          end
          else {Если текущее слово не первое в тексте (второе, третье и т. д.)}
            Dra := Dw * Da * Dra; {Гласные буквы текущего слова, которые входят в каждое из предыдущих слов.}
          if Dra = [] then {Если искомое множество уже пусто, то прерываем обработку.}
            Break;
          Dw := []; {Обнуление множества букв текущего слова.}
        end;
      end;
 
    {Ответ.}
    if Dra = [] then
      Writeln('Нет ни одной гласной буквы, которая бы входила в каждое слово.')
    else
    begin
      Writeln('Множество гласных букв, которые входят в каждое слово:');
      for Ch := #0 to #255 do
        if Ch in Dra then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

@Dzhen · 26.06.2014, 11:32 **[ТС]**

у меня не работает

@Mawrat · 26.06.2014, 11:59

В чём это выражается? Программа не запускается или ещё что-то не то происходит?
Я проверял. Сейчас вот ещё раз запустил, программа выдала следующее:

Задайте текст:
аяо аяоё аяоёы аяоёыи аяоёыиэ.
Множество гласных букв, которые входят в каждое слово:
а о я
Повторить - Enter. Выход - любой символ + Enter.

Т. е., программа верный ответ дала.

@Dzhen · 26.06.2014, 12:18 **[ТС]**

Mawrat, у меня не выводит эти буквы. вот так:

Pascal
1
2
3
4
5
Задайте текст:
аяо аяоё аяоёы аяоёыи аяоёыиэ.
Множество гласных букв, которые входят в каждое слово:
 
Повторить - Enter. Выход - любой символ + Enter.

@Mawrat · 26.06.2014, 12:26

Похоже на то, что исходный код программы вводится в редакторе в одной кодировке - например, в CP1251 (Windows), а выполняется программа уже в окружении с другой кодировкой - CP866 (DOS). Или наоборот.
В связи с этим вопрос - в какой среде вводится исходный текст программы и в какой среде выполняется? В Borland/Turbo Pascal? Или ещё где-то?

@Dzhen · 26.06.2014, 12:31 **[ТС]**

Windows, Turbo Pascal

@Mawrat · 26.06.2014, 12:45

Dzhen, запусти сейчас вот эту программу:

Pascal
1
2
3
4
5
6
program Test;
 
begin
  Writeln('Symbol for code #$C1: ', #$C1);
  Readln;
end.

Если будет выведен такой текст:

Symbol for code #$C1: ┴

значит, программа выполняется в окружении с кодировкой CP866 (DOS).
Если будет выведен такой текст:

Symbol for code #$C1: Б

значит, программа выполняется в окружении с кодировкой CP1251 (Windows).

Dzhen, как выполнишь эту проверку - напиши, что получилось.

Добавлено через 1 минуту
По результатам я тебе вышлю файл с исходником в нужной кодировке.

Добавлено через 4 минуты
Если исходный код пишется в Borland/Turbo Pascal, то вопрос такой - русские буквы там получается вводить? Они правильно показываются или в виде кракозябр?

Добавлено через 3 минуты

Сообщение от Mawrat

По результатам я тебе вышлю файл с исходником в нужной кодировке.

Это может и не решить проблему. Т. к., на экране могут быть кракозябры вместо русских букв. В общем, наша задача сейчас разобраться с кодировками. Для начала надо выполнить ту проверочную программу, о которой я выше написал. Дальше будем разбираться.

@Dzhen · 26.06.2014, 12:54 **[ТС]**

вот что
Symbol for code #$C1: 193

@Mawrat · 26.06.2014, 12:55

Или можно в качестве промежуточного варианта написать программу по изменённой формулировке - для английских гласных букв:

Дан текст на английском языке . Напечатать в алфавитном порядке все гласные буквы , которые входят в каждое слово.

На английском языке программа в любом случае отработает правильно, потому что английские буквы в обеих кодировках CP1251 и CP866 имеют одни и те же коды.
В этом случае программа будет выглядеть так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
program Project1;
 
{Задача:
Напечатать в алфавитном порядке все строчные английские гласные буквы, которые входят в каждое слово.}
 
const
  {Множество разделителей слов.}
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  {Множество английских гласных букв (только строчные буквы).}
  Da = ['a', 'e', 'i', 'o', 'u', 'y'];
var
  S : String;
  Dw, Dra : set of Char;
  Ch : Char;
  i, Len : Integer;
  F : Boolean;
begin
  repeat
    Writeln('Input text:');
    Readln(S);
 
    {Решение.}
    Len := Length(S); {Длина строки.}
    Dw := []; {Множество букв, которые входят в текущее слово.}
    Dra := []; {Множество гласных букв, которые входят в каждое слово.}
    F := True; {True - найдено первое слово, иначе - False.}
    for i := 1 to Len do
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Dw := Dw + [S[i]]; {Добавляем букву во множество букв текущего слова.}
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          if F then {Если текущее слово является первым словом в тексте.}
          begin
            Dra := Dw * Da; {Все гласные буквы текущего слова.}
            F := False;
          end
          else {Если текущее слово не первое в тексте (второе, третье и т. д.)}
            Dra := Dw * Da * Dra; {Гласные буквы текущего слова, которые входят в каждое из предыдущих слов.}
          if Dra = [] then {Если искомое множество уже пусто, то прерываем обработку.}
            Break;
          Dw := []; {Обнуление множества букв текущего слова.}
        end;
      end;
 
    {Ответ.}
    if Dra = [] then {Нет ни одной гласной буквы, которая бы входила в каждое слово.}
      Writeln('No one vowel, which would included in every word.')
    else {Множество гласных букв, которые входят в каждое слово.}
    begin
      Writeln('Set of vowels that are included in each word:');
      for Ch := #0 to #255 do
        if Ch in Dra then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Writeln('Repeat - Enter. Exit - any key + Enter.');
    Readln(S);
  until S <> '';
end.

Добавлено через 1 минуту

Сообщение от Dzhen

вот что
Symbol for code #$C1: 193

Это не то, что надо. Это ты в программе вот так написал:

Pascal
1
Writeln('Symbol for code #$C1: ', $C1);

А надо со знаком "#" - вот так:

Pascal
1
Writeln('Symbol for code #$C1: ', #$C1);

Ещё раз запусти.

@Dzhen · 26.06.2014, 13:02 **[ТС]**

Mawrat, для английских работает.

Сообщение от Mawrat

Writeln('Symbol for code #$C1: ', #$C1);

я так и писала.. все равно то же самое выводит

@Mawrat · 26.06.2014, 13:11

Сообщение от Dzhen

я так и писала.. все равно то же самое выводит

Чудеса... Ну тогда вот так предлагаю попробовать:

Pascal
1
2
3
4
5
6
7
8
9
program Test;
 
var
  S : String; 
begin
  S := #$C1;
  Writeln('Symbol for code #$C1: ', S);
  Readln;
end.

Добавлено через 1 минуту
Dzhen, а решение с английскими гласными буквами - подходит такой вариант? Или обязательно надо именно русские буквы использовать? Алгоритм один и тот же.

@Dzhen · 26.06.2014, 13:11 **[ТС]**

ошибка
надо русские обязательно..

@Mawrat · 26.06.2014, 13:32

А Pascal какой? Обыкновенный? Или какой-нибудь скул-пак? Какая Windows - XP, Windows 7 или 8?

Сообщение от Dzhen

ошибка

Какая ошибка? Что о ней пишет среда разработки?

Сообщение от Dzhen

надо русские обязательно..

Если преподаватель адекватный, то ему можно объяснить, что на компе проблема с кодировками и с обработкой русских букв. Потому, что если человек в теме, то он знает, что если с кодировками проблема, то новичок её вряд ли решит самостоятельно.

Добавлено через 12 минут
Ещё программу можно запустить с другого компа, где нет проблемы с кодировками - где-то в ВУЗе или у друзей.

@Dzhen · 26.06.2014, 14:07 **[ТС]**

Windows - XP,

Сообщение от Mawrat

ошибка

Нельзя преобразовать тип integer к string
Хорошо, попробую на другом компе

@Mawrat · 26.06.2014, 15:32

Сообщение от Dzhen

Нельзя преобразовать тип integer к string

Такое произойдёт, если написать без знака #:

Pascal
1
S := $C1;

Нужно писать именно со знаком #:

Pascal
1
S := #$C1;

Если это не сработает, то со средой разработки творится какая-то чертовщина. Что-то там не то. В конце концов можно попробовать вот такой код:

Pascal
1
2
3
4
5
6
7
8
9
program Test;
 
var
  S : String;
begin
  S := Chr($C1);
  Writeln('Symbol for code #$C1: ', S);
  Readln;
end.

Добавлено через 46 минут

Сообщение от Dzhen

Windows, Turbo Pascal

Судя по симптомам, у тебя не Turbo Pascal, а PascalABC или PascalABC.NET. Там сроки и символы устроены совсем не так, как в Borland/Turbo Pascal.

Добавлено через 13 минут
Dzhen, в общем, у тебя PascalABC.NET, скорее всего. Вот вариант, который в PascalABC.NET будет работать правильно:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
program Project1;
 
{Задача:
Напечатать в алфавитном порядке все строчные русские гласные буквы, которые входят в каждое слово.}
 
const
  {Множество разделителей слов.}
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  {Множество русских гласных букв (только строчные буквы).}
  Da = ['а', 'я', 'о', 'ё', 'ы', 'и', 'э', 'е', 'у', 'ю'];
var
  S : String;
  Dw, Dra : set of Char;
  Ch : Char;
  i, Len : Integer;
  F : Boolean;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    {Решение.}
    Len := Length(S); {Длина строки.}
    Dw := []; {Множество букв, которые входят в текущее слово.}
    Dra := []; {Множество гласных букв, которые входят в каждое слово.}
    F := True; {True - найдено первое слово, иначе - False.}
    for i := 1 to Len do
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Dw := Dw + [S[i]]; {Добавляем букву во множество букв текущего слова.}
        if (i = Len) or (S[i + 1] in D) then {Отслеживаем конец слова.}
        begin
          if F then {Если текущее слово является первым словом в тексте.}
          begin
            Dra := Dw * Da; {Все гласные буквы текущего слова.}
            F := False;
          end
          else {Если текущее слово не первое в тексте (второе, третье и т. д.)}
            Dra := Dw * Da * Dra; {Гласные буквы текущего слова, которые входят в каждое из предыдущих слов.}
          if Dra = [] then {Если искомое множество уже пусто, то прерываем обработку.}
            Break;
          Dw := []; {Обнуление множества букв текущего слова.}
        end;
      end;
 
    {Ответ.}
    if Dra = [] then
      Writeln('Нет ни одной гласной буквы, которая бы входила в каждое слово.')
    else
    begin
      Writeln('Множество гласных букв, которые входят в каждое слово:');
      for Ch := 'а' to 'ё' do
        if Ch in Dra then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

Добавлено через 5 минут
По PascalABC на форуме есть специальные подразделы:
Pascal ABC
PascalABC.NET

@Dzhen · 26.06.2014, 20:34 **[ТС]**

Mawrat, спасибо большое

Новые блоги и статьи Все статьи Все блоги /
Отображение реквизитов в документе по условию и контроль их заполнения Maks 04.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "ПланированиеСпецтехники", разработанного в конфигурации КА2. Данный документ берёт данные из другого нетипового документа. . .	Фото всей Земли с борта корабля Orion миссии Artemis II kumehtar 04.04.2026 Это первое подобное фото сделанное человеком за 50 лет. Снимок называют новым вариантом легендарной фотографии «The Blue Marble» 1972 года, сделанной с борта корабля «Аполлон-17». Новое фото. . .	Вывод диалогового окна перед закрытием, если документ не проведён Maks 04.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "СписаниеМатериалов", разработанного в конфигурации КА2. Задача: реализовать программный контроль на предмет проведения документа. . .	Программный контроль заполнения реквизита табличной части документа Maks 02.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "СписаниеМатериалов", разработанного в конфигурации КА2. Задача: реализовать контроль заполнения реквизита "ПричинаСписания". . .
wmic не является внутренней или внешней командой Maks 02.04.2026 Решение: DISM / Online / Add-Capability / CapabilityName:WMIC~~~~ Отсюда: https:/ / winitpro. ru/ index. php/ 2025/ 02/ 14/ komanda-wmic-ne-naydena/	Программная установка даты и запрет ее изменения Maks 02.04.2026 Алгоритм из решения ниже реализован на примере нетипового документа "СписаниеМатериалов", разработанного в конфигурации КА2. Задача: при создании документов установить период списания автоматически. . .	Вывод данных в справочнике через динамический список Maks 01.04.2026 Реализация из решения ниже выполнена на примере нетипового справочника "Спецтехника" разработанного в конфигурации КА2. Задача: вывести данные из ТЧ нетипового документа. . .	Программное заполнения текстового поля в реквизите формы документа Maks 01.04.2026 Алгоритм из решения ниже реализован на нетиповом документе "ВыдачаОборудованияНаСпецтехнику" разработанного в конфигурации КА2, в дополнении к предыдущему решению. На форме документа создается. . .

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26

	Напечатать в алфавитном порядке все гласные буквы, которые входят в каждое слово 25.06.2014, 14:54. Показов 6377. Ответов 18 Метки нет (Все метки) Дан текст на русском языке . Напечатать в алфавитном порядке все гласные буквы , которые входят в каждое слово. Помогите, пожалуйста. Задача на множества. Паскаль 0

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26
	26.06.2014, 11:32 [ТС]
	у меня не работает 0

@Mawrat 13116 / 5897 / 1708 Регистрация: 19.09.2009 Сообщений: 8,809
	26.06.2014, 11:59
	В чём это выражается? Программа не запускается или ещё что-то не то происходит? Я проверял. Сейчас вот ещё раз запустил, программа выдала следующее: Задайте текст: аяо аяоё аяоёы аяоёыи аяоёыиэ. Множество гласных букв, которые входят в каждое слово: а о я Повторить - Enter. Выход - любой символ + Enter. Т. е., программа верный ответ дала. 0

@Mawrat 13116 / 5897 / 1708 Регистрация: 19.09.2009 Сообщений: 8,809
	26.06.2014, 12:26
	Похоже на то, что исходный код программы вводится в редакторе в одной кодировке - например, в CP1251 (Windows), а выполняется программа уже в окружении с другой кодировкой - CP866 (DOS). Или наоборот. В связи с этим вопрос - в какой среде вводится исходный текст программы и в какой среде выполняется? В Borland/Turbo Pascal? Или ещё где-то? 0

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26
	26.06.2014, 12:31 [ТС]
	Windows, Turbo Pascal 0

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26
	26.06.2014, 12:54 [ТС]
	вот что Symbol for code #$C1: 193 0

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26
	26.06.2014, 13:11 [ТС]
	ошибка надо русские обязательно.. 0

@Dzhen 0 / 0 / 0 Регистрация: 25.06.2014 Сообщений: 26
	26.06.2014, 20:34 [ТС]
	Mawrat, спасибо большое 0