Напечатать в алфавитном порядке все гласные буквы, которые не входят более чем в одно слово

program Project1;
 
{Перевод букв строки в верхний регистр. Для кодовой страницы CP866 (OEM, DOS).}
function UpCaseRu(S : String) : String;
var
  i : Integer;
begin
  for i := 1 to Length(S) do
    if S[i] in ['а'..'п'] then
      S[i] := Chr(Ord(S[i]) - 32)
    else if s[i] in ['р'..'я'] then
      S[i] := Chr(Ord(S[i]) - 80)
    else if S[i] = 'ё' then
      S[i]:='Ё'
    else
      S[i] := UpCase(S[i]);
  UpCaseRu := S;
end;
 
const
  {Множество разделителей слов.}
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  {Множество русских гласных букв.}
  Da = ['А', 'Е', 'Ё', 'И', 'О', 'У', 'Ы', 'Э', 'Ю', 'Я'];
var
  S : String;
  Dw, Ds, Dr, De : set of Char;
  Ch : Char;
  i, Len : Integer;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    S := UpCaseRu(S); {Приводим буквы строки к верхнему регистру.}
 
    Len := Length(S);
    Dw := []; {Множество гласных букв в текущем слове.}
    Ds := []; {Множество гласных букв, обнаруженных в предыдущих словах.}
    Dr := []; {Множество гласных букв, которые присутствуют БОЛЕЕ, чем в одном слове.}
    for i := 1 to Len do {Перебор всех символов строки.}
      {Если символ не является разделителем, значит он принадлежит слову.}
      if not (S[i] in D) then
      begin
        if S[i] in Da then
          Dw := Dw + [S[i]]; {Добавляем символ во множество гласных букв слова.}
        if (i = Len) or (S[i + 1] in D) then {Если обнаружен конец слова.}
        begin
          {Dw * Ds - это множество гласных букв, которые входят в текущее
          слово и которые входят в какие-то слова, обработанные ранее.
          Т. е., Dw * Ds - это, часть множества гласных букв, которые входят
          БОЛЕЕ, чем в одно слово. Так, обрабатывая слово за словом, мы соберём
          сведения обо всех таких буквах в тексте.}
          Dr := Dr + Dw * Ds;
          Ds := Ds + Dw;
          Dw := [];
        end;
      end;
 
    {Итак, теперь мы имеем следующее:
    - Во множестве Dr содержатся те буквы, которые входят БОЛЕЕ, чем
      в одно слово.
    - Тогда множество букв, которые не входят более, чем в одно слово,
      будет равно: Da - Dr.}
 
    De := Da - Dr; {Множество гласных букв, которые не входят более, чем в одно слово.}
 
    {Распечатка гласных букв, которые не входят более, чем в одно слово.}
    if De = [] then
      Writeln('Нет ни одной гласной буквы, которая бы не входила более, чем в одно слово.')
    else
    begin
      Writeln('Перечень гласных букв, которые не входят более, чем в одно слово:');
      for Ch := 'А' to #255 do {Для кодовых страниц CP866 (DOS) и CP1251 (Windows).}
        if Ch in De then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.