Если слово начинается с нечётной позиции, то записать символы этого слова в обратном порядке

program Project1;
 
const
  {Множество разделителей слов.}
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S : String;
  Ch : Char;
  i, j, LenW : Integer;
begin
  repeat
    Writeln('Задайте текст:');
    Readln(S);
 
    LenW := 0; {Длина текущего слова.}
    for i := Length(S) downto 1 do {Перебор символов строки справа-налево.}
      if not (S[i] in D) then {Если символ принадлежит слову.}
      begin
        Inc(LenW); {Учитываем очередной символ в длине слова.}
        if (i = 1) or (S[i - 1] in D) then {Отслеживаем начало слова.}
        begin
          if i mod 2 <> 0 then {Если слово расположено на нечётной позиции, то переворачиваем его.}
            for j := 1 to LenW div 2 do {Симметрично переставляем буквы слова.}
            begin
              Ch := S[i + j - 1];
              S[i + j - 1] := S[i + LenW - j];
              S[i + LenW - j] := Ch;
            end;
          LenW := 0; {Сброс длины текущего слова.}
        end;
      end;
    
    Writeln('Текст после обработки:');
    Writeln(S);
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.