Найти всех жителей с фамилией Петров, у которых нет телефона

type
    TAdres = record
        rajon : String;
        ulica : String;
        dom, kvart : Byte;
    end;
    TPerson = record
        fam : String[25];
        imia : String[20];
        otch : String[25];
        data : String[10];
        adres : TAdres;
        tel : Boolean;
        num : String[20];
    end;
 
procedure ReadAdres(var x : TAdres);
begin
    with x do
    begin
        Write(#9, 'район: '); ReadLn(rajon);
        Write(#9, 'улица: '); ReadLn(ulica);
        Write(#9, 'номер дома: '); ReadLn(dom);
        Write(#9, 'номер квартиры: '); ReadLn(kvart);
    end;
end;
 
procedure ReadPerson(var x : TPerson);
var
    c : Byte;
begin
    with x do
    begin
        Write(#9, 'фамилия: '); ReadLn(fam);
        Write(#9, 'имя: '); ReadLn(imia);
        Write(#9, 'отчество: '); ReadLn(otch);
        Write(#9, 'дата рождения: '); ReadLn(data);
        ReadAdres(adres);
        Write(#9, 'Имеется ли телефон? (0 - нет, 1 - да) '); ReadLn(c);
        tel := (c = 1);
        if tel
        then
        begin
            Write(#9, 'номер телефона: '); ReadLn(num);
        end;
    end;
end;
 
procedure PrintPerson(const x : TPerson);
begin
    with x do
    begin
        WriteLn(fam, ' ', imia, ' ', otch, ':');
        WriteLn(#9, data);
        with adres do
            WriteLn(#9, rajon, ' ', ulica, ' ', dom, '/', kvart);
    end;
    WriteLn('--------------------------------');
end;
 
function CheckPerson(const x : TPerson) : Boolean;
begin
    CheckPerson := ((x.fam = 'Петров') And Not(x.tel));
end;
 
var
    x : Array[1..100] Of TPerson;
    i, n : Byte;
begin
    Write('n='); ReadLn(n);
    for i := 1 to n do
    begin
        WriteLn('добавление ', i, '-того человека:');
        ReadPerson(x[i]);
    end;
    for i := 1 to n do
        if CheckPerson(x[i])
        then
            PrintPerson(x[i]);
end.