Создать процедуру перемножения двух неквадратных матриц

program MMult; 
 
type
  TMatrixElement = Single; 
  TArray = Array[0..1] of Single; 
  PArray = ^TArray; 
  TMatrix = Record 
    rows, cols: Integer; 
    data: PArray; 
  End; 
{$R-} 
procedure AllocMatrix(var M: TMatrix);
begin
  GetMem(M.data, M.rows * M.cols * sizeof(TMatrixElement)); 
end;
 
procedure DeleteMatrix(var M: TMatrix);
begin
  FreeMem(M.data, M.rows * M.cols * sizeof(TMatrixElement)); 
end;
 
procedure WriteElem(M: TMatrix; r, c: Integer; v: TMatrixElement);
begin
  M.data^[r * M.cols + c] := v; 
end;
 
function ReadElem(M: TMatrix; r, c: Integer): TMatrixElement;
begin
  ReadElem := M.data^[r * M.cols + c]; 
end;
 
procedure InputMatrix(M: TMatrix; Name: String);
var
  r, c: Integer; 
  v: TMatrixElement; 
begin
  WriteLn('Please specify elements of matrix ', Name, ':'); 
  for r := 0 to M.rows - 1 do 
  begin
    for c := 0 to M.cols - 1 do 
    begin
      Write(Name, '[', r, ',', c, ']= '); ReadLn(v); 
      WriteElem(M, r, c, v); 
    end; 
  end; 
end;
 
procedure OutputMatrix(M: TMatrix; Name: String);
var
  r, c: Integer; 
begin
  WriteLn('The value of matrix ', Name, ' (', M.rows, '*', M.cols, ') is:'); 
  for r := 0 to M.rows - 1 do 
  begin
    Write('('); 
    for c := 0 to M.cols - 1 do 
    begin
      Write(ReadElem(M, r, c):3:3); 
      if c <> (M.cols - 1) Then Write(','); 
    end; 
    WriteLn(')'); 
  end; 
end;
 
procedure MultMatrix(A, B, M: TMatrix);
var
  r, c, t: Integer; 
  S: TMatrixELement; 
begin
  for r := 0 to A.rows - 1 do 
  begin
    for c := 0 to B.cols - 1 do 
    begin
      S := 0; 
      for t := 0 to A.cols - 1 do 
      begin
        S := S + ReadElem(A, r, t) * ReadElem(B, t, c); 
      end; 
      WriteElem(M, r, c, S); 
    end; 
  end; 
end;
 
var
  A, B, C: TMatrix; 
 
begin
  WriteLn('Program will calculate A*B'); 
  Write('Enter number of rows of A: '); ReadLn(A.rows); 
  Write('Enter number of columns of A: '); ReadLn(A.cols); 
  Write('Enter number of rows of B: '); ReadLn(B.rows); 
  Write('Enter number of columns of B: '); ReadLn(B.cols); 
  if (A.cols <> B.rows) or (A.cols * A.rows <= 0) or (B.cols * B.rows <= 0) or (A.cols < 0) or (B.cols < 0) Then begin
    WriteLn('You have specified invalid matrix size'); 
  end Else begin
    C.rows := A.rows; 
    C.cols := B.cols; 
    AllocMatrix(A); 
    AllocMatrix(B); 
    AllocMatrix(C); 
    InputMatrix(A, 'A'); 
    InputMatrix(B, 'B'); 
    MultMatrix(A, B, C); 
    OutputMatrix(C, 'C'); 
  end; 
  WriteLn('Press [Enter] to exit...'); 
  ReadLn; 
end.