Напечатать пары чисел близнецов (процедуры)

{проседура для определения простоты числа от Sergio Leone}
{взята как есть, хотя на чётные и на <=2 по контексту можно не проверять}
{на входе x: longint, здесь параметр передаётся по значению,}
{возвращаемое значение функции}
{b = TRUE - число простое, b = False - не простое, передаётся по ссылке}
procedure isPrime(x: longint; var b: boolean);
var i, gr : integer; {очередной делитель и последний возможный делитель}
begin
     b := false; {пока считаем, что число не простое}
     if x < 2 then exit; {если <2, то точно не простое, выходим (b = false)}
     if not odd(x) and (x <> 2) {проверяем на чётность, исключая 2}
          then exit; {если чётное и <> 2, выходим (b = false)}
     i := 3; {делители начинаем искать с 3}
     gr := trunc(sqrt(x));
     {делитель не может превосходить sqrt(x), так как sqrt(x) * sqrt(x) = x}
     while i <= gr  do {проверяем только нечётные}
     {при этом цикл не выполнится ни разу для x < 9,}
     {и это хорошо: на числа < 2, чётные и <> 2 сработали предыдущие if,}
     {то есть, отсеяны x<2, 4, 6, 8, а остались только простые 2, 3, 5, 7}
     begin
          if x mod i = 0 then Exit; {если делится нацело, выходим (isPrime = false)}
          inc(i,2); {следующий делитель: i:=i+2}
     end;
     b := true; {если не нашлось ни одного делителя, то число простое}
end;
 
var s1, s2, ng: boolean; {флаги простоты чисел и флаг отсутствия близнецов}
    n, n2: integer; {само число и конец интервала}
begin
  repeat {ввод с проверкой}
    write('n = ');
    readln(n);
    if n <= 2 then writeln('n must be > 2, reenter.')
  until n > 2;
  writeln('Gemini in [', n, '..', n * 2, ']:');
  n2 := n * 2 - 2; {последнее число для поиска}
  if not odd(n) then inc(n); {так как n>2, то если чётное, прибавляем единицу}
  ng := true; {близнецов пока нет}
  while n <= n2 {ищем}
    do begin
      isPrime(n, s1); {проверяем число}
      inc(n, 2); {следующее на 2 больше}
      isPrime(n, s2); {проверяем число}
      if s1 and s2 {если оба простые, то}
        then begin
          writeln(n - 2, ', ', n); {печатаем}
          ng := false {близнецы есть}
        end
    end; {конец поиска}
  if ng then writeln('Gemini not found.'); {если близнецов нет, выодим сообщение}
  readln
end.

{проседура для определения простоты числа от Sergio Leone, слегка упрщённая}
procedure isPrime(x: longint; var b: boolean);
var i, gr : integer;
begin
  b := false;
  i := 3;
  gr := trunc(sqrt(x));
  while i <= gr
    do begin
      if x mod i = 0 then Exit;
      inc(i, 2)
    end;
  b := true
end;
 
var s1, s2, ng: boolean;
    n, n2: integer;
begin
  repeat
    write('n = ');
    readln(n);
    if n <= 2 then writeln('n must be > 2, reenter.')
  until n > 2;
  writeln('Gemini in [', n, '..', n * 2, ']:');
  n2 := n * 2 - 2;
  if not odd(n) then inc(n);
  ng := true;
  isPrime(n, s1);
  while n <= n2
    do begin
      inc(n, 2);
      isPrime(n, s2);
      if s1 and s2
        then begin
          writeln(n - 2, ', ', n);
          ng := false
        end;
      s1 := s2
    end;
  if ng then writeln('Gemini not found.');
  readln
end.