Массив целых чисел, двунаправленный список

type
  tElem = string[20];
  
const
  maxCount = 100;
  
var
  A : array [1..maxCount] of tElem;
  aCount : Integer;
  
procedure InputArray;
var
  i : Integer;
begin
  Write('Число элементов массива (до ', maxCount, ') = '); ReadLn(aCount);
  for i := 1 to aCount do
    begin
      Write('A[', i, '] = '); ReadLn(A[i]);
    end;
end;
  
procedure OutArray(msg : String);
var
  i : Integer;
begin
  Write(msg, ':'); for i := 1 to aCount do Write(#32, A[i]); WriteLn;
end;
 
type
  tList = ^rList;
  rList = record
    E : tElem;
    N, P : tList;
  end;
  
function Array2List : tList;
var
  Cur : tList;
  i : Integer;
begin
  New(Cur); Cur^.E := A[aCount]; Cur^.N := nil;
  for i := aCount - 1 downto 1 do
    begin
      New(Cur^.P); Cur^.P^.N := Cur; Cur := Cur^.P; Cur^.E := A[i];
    end;
  Cur^.P := nil;
  Array2List := Cur;
end;
 
procedure OutList(msg : String; Cur : tList);
begin
  Write(msg, ':'); while Cur <> nil do begin Write(#32, Cur^.E); Cur := Cur^.N; end; WriteLn;
end;
 
procedure SwapE(var List1, List2 : tList);
var
  E : tElem;
begin
  E := List1^.E; List1^.E := List2^.E; list2^.E := E;
end;
 
procedure SortList(var First : tList);
var
  Cur : tList;
  Swaps : Boolean;
begin
  repeat
    Swaps := False;
    Cur := First^.N;
    while Cur <> nil do
      begin
        if Cur^.P^.E > Cur^.E then
          begin
            SwapE(Cur^.P, Cur);
            Swaps := True;
          end;
        Cur := Cur^.N;
      end;
  until Not Swaps;
end;
 
procedure OutDubl(msg : String; Cur : tList);
var
  Count : Integer;
  E : tElem;
begin
  Write(msg, ':');
  Count := 0;
  while Cur <> nil do
    begin
      if Count = 0 then
        begin
          E := Cur^.E;
          Write(#32, E);
          Count := 1;
          Cur := Cur^.N;
        end
      else if E = Cur^.E then
        begin
          Inc(Count);
          Cur := Cur^.N;
        end
      else // E <> Cur^.E
        begin
          Write(' (', Count, ')');
          Count := 0;
        end;
    end;
  WriteLn(' (', Count, ')');
end;
 
var
  List : tList;
 
begin
  InputArray;
  OutArray('Введён массив A');
  List := Array2List;
  OutList('Сформирован список List', List);
  SortList(List);
  OutList('Список List отсортирован по возрастанию', List);
  OutDubl('Список дублей', List);
end.