Программа сложной модульной структуры

unit ua;
interface
 
{ Заполняет массив случайными значениями из интервала [b,c) }
procedure mRand(var a: array of Real; b, c: Real);
 
{ Выводит содержимое массива }
procedure mWrite(const a: array of Real; W, D: Integer);
 
{ Подсчитывает сумму элементов массива со смещениями от b до c }
function mSum(var a: array of Real; b, c: Integer): Real;
 
type
  { Прототип функции упорядочивания a<b }
  TLessFunc = function (a, b: Real): Boolean;
 
{ Сортирует массив }
procedure mSort(var a: array of Real; Less: TLessFunc);
 
implementation
 
procedure mRand(var a: array of Real; b, c: Real);
var i: Integer;
begin
  for i:=Low(a) to High(a) do a[i]:=b+Random*(c-b);
end;
 
procedure mWrite(const a: array of Real; W, D: Integer);
var i: Integer;
begin
  for i:=Low(a) to High(a) do
    if      W<0 then Write(' ',a[i])
    else if D<0 then Write(' ',a[i]:W)
    else             Write(' ',a[i]:W:D);
  WriteLn;
end;
 
procedure mSort(var a: array of Real; Less: TLessFunc);
var i, j: Integer; t: Real;
begin
  for j:=High(a) downto Low(a)+1 do
    for i:=Low(a)+1 to j do
      if Less(a[i],a[i-1]) then begin
        t:=a[i-1]; a[i-1]:=a[i]; a[i]:=t;
      end;
end;
 
function mSum(var a: array of Real; b, c: Integer): Real;
var r: Real;
begin
  Inc(b,Low(a)); Inc(c,Low(a)); r:=0;
  for b:=b to c do r:=r+a[b];
  mSum:=r;
end;
end.

unit um;
interface
 
{ Возвращает смещение минимального элемента массива от начала }
function OffsMin(const a: array of Real): Integer;
 
{ Возвращает смещение отрицательного элемента, иначе -1 }
function OffsNeg(const a: array of Real; o: Integer): Integer;
 
implementation
 
function OffsMin(const a: array of Real): Integer;
var i, j: Integer;
begin
  j:=Low(a);
  for i:=Low(a)+1 to High(a) do
    if a[j]>a[i] then j:=i;
  OffsMin:=j-Low(a);
end;
 
function OffsNeg(const a: array of Real; o: Integer): Integer;
begin
  o:=o+Low(a); OffsNeg:=-1; if o<Low(a) then Exit;
  while (o<=High(a)) and (a[o]>=0) do Inc(o);
  if o>High(a) then Exit;
  OffsNeg:=o-Low(a);
end;
end.

uses ua, um;
{$F+}
function less1(a, b: Real): Boolean;
begin less1:=(abs(a)<=1) and (abs(b)>1); end;
 
const n=10;
var
  a: array [0..n-1] of Real;
  i1, i2: Integer;
begin
  Randomize; mRand(a,-2,2);
  Write('A ='); mWrite(a,0,2);
  WriteLn('Номер минимального элемента: ',OffsMin(a)+1);
  i1:=OffsNeg(a,0); i2:=OffsNeg(a,i1+1);
  if i2<0 then WriteLn('Нет 2-х отрицательных элементов')
  else WriteLn('Сумма между 1 и 2-м отрицательным: ',mSum(a,i1+1,i2-1):0:2);
  mSort(a,less1);
  Write('A''='); mWrite(a,0,2);
end.