Организовать структуру данных Heap для хранения целых чисел

program task;
var
  heap : array[0..100007] of longint;
  heap_free : longint;
 
procedure add(x : longint);
begin
  heap[heap_free] := x;
  inc(heap_free);
end;
 
procedure remove;
begin
  dec(heap_free);
end;
 
procedure heap_insert(x : longint);
var 
  ii, parent, temp : longint;
begin
  add(x);
  ii := heap_free - 1;
  parent := (ii - 1) div 2;
  while((ii > 0) and (heap[parent] < heap[ii])) do begin
    temp := heap[ii];
    heap[ii] := heap[parent];
    heap[parent] := temp;
 
    ii := parent;
    parent := (ii - 1) div 2;
  end;
end;
 
procedure heapify(x : longint);
var 
  left_child, right_child, largest_child, temp: longint;
begin
  while(true) do begin
    left_child := 2 * x + 1;
    right_child := 2 * x + 2;
    largest_child := x;
    
    if((left_child < heap_free) and (heap[left_child] > heap[largest_child])) then largest_child := left_child;
    if((right_child < heap_free) and (heap[right_child] > heap[largest_child])) then largest_child := right_child;
    if(largest_child = x) then break;
 
    temp := heap[x];
    heap[x] := heap[largest_child];
    heap[largest_child] := temp;
    x := largest_child;
  end;
end;
 
function extract : longint;
var 
  res : longint;
begin
  res := heap[0];
  heap[0] := heap[heap_free- 1];
  remove;
  heapify(0);
  extract := res;
end; 
 
var 
  n, id, x, i : longint;
begin
  heap_free := 0;
  
  readln(n);
  for i := 1 to n do begin
    read(id);
    if(id = 0) then begin
      readln(x);
      heap_insert(x);
    end
    else if(id = 1) then writeln(extract);
  end;
end.