Найдите сумму трех наибольших <Положительных нечетных > элементов исходного массива Р(22)

const 
  n = 22;
 
type
  int = integer; //Здесь можешь поставить любой порядковый тип
  long = longint; //Тип для суммы
  uint = byte; //Тип для итераторов
  range = 0..n - 1; //Индексация массива
  arr = array[range] of int; //Тип массива
  
procedure quicksort(var mas:arr; first, last:int); //Быстрая сортировка
var i, l, x, buf:int;
begin
  if not(first < last) then
    exit;
  x:= mas[(first + last) div 2];
  i:= first;
  l:= last;
  while (i <= l) do
  begin
    while (mas[i] > x) do //Сортируем по убыванию; для сортировки по возрастанию поменяй > на <
      inc(i);
    while (mas[l] < x) do //Сортируем по убыванию; для сортировки по возрастанию поменяй < на >
      dec(l);
    if (i <= l) then
    begin
      buf:= mas[i];
      mas[i]:= mas[l];
      mas[l]:= buf;
      inc(i);
      dec(l);
    end;
  end;
  quicksort(mas, first, l);  
  quicksort(mas, i, last);
end;  
 
var 
  a:arr;
  i, counter:range;
  sum:long;
  
begin
  writeln('Введите все элементы массива (', n, '):');
  for i:= 0 to n - 1 do
    read(a[i]);
  quicksort(a, 0, n - 1);
  counter:= 0; //Счетчик найденных элементов
  sum:= 0;
  for i:= 0 to n - 1 do
    if ((counter < 3) and (a[i] > 0) and (a[i] mod 2 = 1)) then
    begin
      sum:= sum + a[i];
      counter:= counter + 1;
    end
    else if (counter = 3) then
      break;
  if (counter = 3) then
    writeln('Искомая сумма: ', sum)
  else
    writeln('Не нашлось трех положительных нечетных элементов в массиве(');
end.