Введение точности в численном интегрировании

@dadaetowi · Регистрация: 13.04.2015

Студворк — интернет-сервис помощи студентам

Приветствую, написал программу вычисления значения интеграла с помощью метода правых прямоугольников:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
var i,n,g:integer; a,e,b,h,x1,x,s:real;
function f(x:real):real;
begin f:=(x*x*x*x*x)/(0.125+(x*x*x));
end;
begin
 
write('[a;b]');
write('Начальный интервал ');
readln(a);
write('Конечный интервал');
readln(b);
write('Введите количество отрезков');
readln(n);
h:=abs(b-a)/n; s:=0; x1:=a;
 
for i:=1 to n do
begin
s:=s+f(x1+h*i)*h;
end;
 
writeln('integral= ',abs(s):12:10); readln;
end.

Но не знаю как ввести в эту программу точность, относительно этого задания, я не понял. Надеюсь на помощь

Теория

Согласно этому правилу, вычисление заданного интеграла проводят для разных интервалов разбиения отрезка [A, B]. Так, если начальное число интервалов разбиения есть n и соответствующее ему приближённое значение интеграла - I_n, то для числа интервалов 2n получим значение интеграла I_2n. Число интервалов можно увеличивать в 2, 3 и т. д. раз по сравнению с базовым значением n. При двукратном увеличении числа отрезков погрешность Δ приближённого значения интеграла для методов прямоугольников и трапеций оценивается как

Δ = |I_n-I_2n| / 3

Если Δ > E, то количество интервалов разбиения [A, B] опять увеличивают вдвое, т. е. значение I вычисляют для 4n. Такое удвоение повторяют до тех пор, пока не выполнится условие Δ < E. Необходимо помнить, что общая погрешность вычислений, равная сумме погрешностей усечения и округления, сначала с ростом интервалов разбиения уменьшается за счёт уменьшения ошибки усечения до некоторого "критического" значения n_кр, а затем увеличивается из-за увеличения ошибок округления.

@dadaetowi · 20.03.2017, 08:23 **[ТС]**

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
var i,n,g:integer; a,M,e,b,s0,s1,k,h,x1,x,s:real;
function f(x:real):real;
begin f:=(x*x*x*x*x)/(0.125+(x*x*x));
end;
begin
 
write('[a;b]');
write('  vvedite na4alniy interval  ');
readln(a);
write('vvedite kone4niy interval  ');
readln(b);
write('Vvedite koli4estvo otrezkov ');
readln(n);
write('Vvedite to4nost e');
readln(e);
h:=abs(b-a)/n; s:=0;
x1:=a;
s0:=0;
 
 
repeat
for i:=1 to n do
begin
s0:=s;
s:=s0+f(x1+h*i)*h;
end;
k:=2*n;
s1:=s0+f(x1+h*k)*h;
M:=abs(s-s1)/3;
until M<e   ;
 
writeln('integral= ',abs(s):12:10); readln;
end.

Попробовал решить так, но не могу связать увеличение n с циклом, буду благодарен если укажите на ошибку и как её можно решить.

ФедосеевПавел · 20.03.2017, 08:41

Там всё шаблонно, но само вычисление интеграла нужно вынести в функцию для первого вычисления I_n

Добавлено через 2 минуты

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
program AnyInt;
 
const
  {коэффициенты пропорциональности из правила Рунге для различных
   методов интегрирования
   Delta_2N=Q*Abs(I_2N - I_N)
  }
  Qsymp = 1 / 15;
  Qsqr  = 1 / 3;
const
  EpsConst = 0.00001;
 
  {интегрируемая функция}
  function F(x: real): real;
  begin
    F := sin(x);
    {  F:=exp(2*sin(x)) * sin(5+2*cos(x));}
  end;
 
  function IntSquareR(a, b: real; n: integer): real;
  var
    Res: real;
    h: real; {величина шага}
    x: real;
    i: integer;
  begin
    h := (b - a) / n;
    Res := 0;
    i := 1;
    while i <= n do
    begin
      x := a + i * h;
      Res := Res + F(x);
      Inc(i);
    end;
    Res := h * Res;
    IntSquareR := Res;
  end;
 
var
  a, b,          {границы интегрирования}
  Eps: real;     {погрешность численного интегрирования}
 
  n: integer;    {количество подинтервалов интегрирования}
  Icur,          {значение интеграла на текущем шаге итерации}
  Ipre: real;    {значение интеграла на предыдущем шаге итерации}
 
begin
  WriteLn('====================================');
  a := 0;
  b := Pi;
  Eps := EpsConst;
 
  WriteLn('Right Squaries');
  n := 2;
  Icur := IntSquareR(a, b, n);
  repeat
    Ipre := Icur;
    n := 2 * n;                {увеличиваем количество подинтервалов}
    Icur := IntSquareR(a, b, n);
    WriteLn('I=', Icur: 10: 8, ' при n=', n, ', e=', Abs(Icur - Ipre): 10: 8);
  until Qsqr * Abs(Icur - Ipre) < Eps;
  WriteLn('I=', Icur: 10: 8, ' при n=', n, ', e=', Abs(Icur - Ipre): 10: 8);
end.

Добавлено через 4 минуты
Иногда не хватает разрядности n - её тип можно заменить на более ёмкий (longint, dword, qword, uint64).

Новые блоги и статьи Все статьи Все блоги /
Отправка уведомления на почту при изменении наименования справочника Maks 24.03.2026 Программная отправка письма электронной почты на примере изменения наименования справочника "Склады" в конфигурации БП3. Перед реализацией необходимо выполнить настройку системной учетной записи. . .	модель ЗдравоСохранения 5. Меньше увольнений- больше дохода! anaschu 24.03.2026 Теперь система здравосохранения уменьшает количество увольнений. 9TO2GP2bpX4 a42b81fb172ffc12ca589c7898261ccb/ https:/ / rutube. ru/ video/ a42b81fb172ffc12ca589c7898261ccb/ Слева синяя линия -. . .	Midnight Chicago Blues kumehtar 24.03.2026 Такой Midnight Chicago Blues, знаешь?. . Когда вечерние улицы становятся ночными, а ты не можешь уснуть. Ты идёшь в любимый старый бар, и бармен наливает тебе виски. Ты смотришь на пролетающие. . .	Контроль уникальности заводского номера - вариант №2 Maks 24.03.2026 В отличие от предыдущего варианта добавлено прерывание циклов, также добавлены новые переменные для сохранения контекста ошибки перед прерыванием цикла: Процедура ПередЗаписью(Отказ, РежимЗаписи,. . .
SDL3 для Desktop (MinGW): Вывод текста со шрифтом TTF с помощью библиотеки SDL3_ttf на Си и C++ 8Observer8 24.03.2026 Содержание блога Финальные проекты на Си и на C++: finish-text-sdl3-c. zip finish-text-sdl3-cpp. zip	Жизнь в неопределённости kumehtar 23.03.2026 Жизнь — это постоянное существование в неопределённости. Например, даже если у тебя есть список дел, невозможно дойти до точки, где всё окончательно завершено и больше ничего не осталось. В принципе,. . .	Модель здравоСохранения: работники работают быстрее после её введения. anaschu 23.03.2026 geJalZw1fLo Корпорация до введения программа здравоохранения имела много невыполненных работниками заданий, после введения программы количество заданий выросло. Но на выплатах по больничным это. . .	Контроль уникальности заводского номера - вариант №1 Maks 23.03.2026 Алгоритм контроля уникальности заводского (или серийного) номера на примере документа выдачи шин для спецтехники с табличной частью в конфигурации КА2. Данные берутся из регистра сведений, по. . .