Выводит только первый элемент после сортировки и добавления в список

program pr3;
 type och=^s;
      s=record
      inf:integer;
      link:och;
 end;
 const n=8;
 var a:array[1..n] of integer;
     begl,endl,p:och;
     i,b,max,imax,j:integer;
 begin
 
  begl:=nil; endl:=nil;
  new(p);
  writeln('Vvedite chislo');
  readln(p^.inf);
  a[1]:=p^.inf;
  p^.link:=nil;
  begl:=p; endl:=p;
  
  for i:=2 to n do
   begin
    new(p);
    writeln('Vvedite chislo');
    readln(p^.inf);
    a[i]:=p^.inf;
    p^.link:=nil;
    endl^.link:=p;
    endl:=p;
   end;
   
  for i:=1 to n do
   if i mod 2 = 0 then
    begin
     max:=a[i];
     imax:=i;
     for j:=i+1 to n-1 do
      if a[j]>max then
       begin
        max:=a[j];
        imax:=j;
       end;
 
     a[imax]:=a[i];
     a[i]:=max;
    end;
    
  for i:=1 to n do
   begin
    new(p);
    p^.inf:=a[i];
    p^.link:=nil;
    endl^.link:=p;
    endl:=p;
   end;
 
  while p<>nil do
   begin
    write(p^.inf:3);
    p:=p^.link;
   end;
 
 end.

  p:=begl;

type
  pnode = ^node;
  node = record
    inf: integer;
    next: pnode;
  end;
 
const
  n = 5;
 
var
  list: pnode;
  tail: pnode;
  p, q, max: pnode;
  i: integer;
 
begin
  { Заполняем список }
  list := nil;
  for i := 1 to n do
  begin
    new(p);
    writeln('введите число:');
    readln(p^.inf);
    
    p^.next := nil;
    if list = nil then list := p
    else tail^.next := p;
    tail := p;
  end;
  
  { Выводим его }
  p := list;
  writeln('исходный список');
  while p <> nil do
  begin
    write(p^.inf:5);
    p := p^.next;
  end;
  writeln;
  
  { Упорядочиваем элементы списка с четными номерами (начиная с 1-цы) по убыванию }
  { методом последовательного поиска минимума (в нашем случае - максимума) }
  if (list = nil) or (list^.next = nil) then writeln('нечего сортировать') else
  begin
    q := list^.next; { это указатель на элемент, куда будет записан максимум на данной итерации }
    while (q <> nil) and (q^.next <> nil) do
    begin
      p := q; max := q; { и внутренний цикл, от элемента, на который указывает q, до конца списка }
      while (p <> nil) and (p^.next <> nil) do
      begin
        p := p^.next^.next; { перепрыгиваем через 1 элемент, потому что нужны только четные номера }
        if (p <> nil) and (p^.inf > max^.inf) then max := p;
      end;
      i := max^.inf; max^.inf := q^.inf; q^.inf := i; { меняем значения элементов q и max}
      q := q^.next^.next; { и уходим на следующую итерацию: продвигаем q на следующий четный номер }
    end;
  end;
  
  { Вот и все, печатаем результат }
  p := list;
  writeln('отсортированный список');
  while p <> nil do
  begin
    write(p^.inf:5);
    p := p^.next;
  end;
  writeln;
 
  { Все, что осталось - это удалить выделенную память. Это самостоятельно доделай }
end.

var t: ^PNode;
 
  { Заполняем список }
  t:=@list;
  for i := 1 to n do
  begin
    New(t^);
    Write('число: ');
    Read(t^^.inf);
    t:=@t^^.next;
  end;
  t^^.next:=nil;

  New(list); p:=list;
  Write('число: '); Read(p^.inf);
  for i:=2 to n do begin
    New(p^.next); p:=p^.next;
    Write('число: '); Read(p^.inf);
  end;
  p^.next:=nil;