Поиск позиций всех локальных минимумов матрицы

const mij = 5;
type matrix = array[1..mij, 1..mij] of integer;
     mtrstr = array[1..mij, 1..mij] of string[3];
 
//генерация матрицы
procedure gen(var x: matrix);
var i, j: integer;
begin
  for i := 1 to mij do
    for j := 1 to mij do x[i, j] := -99 + random(199)
end;
 
//печать матрицы, в зависимости от параметра is_matrix тип параметра x интерпретируется как matrix или mtrstr
procedure prn(var x; is_matrix: boolean);
var i, j: integer;
begin
  for i := 1 to mij do
    begin
      for j := 1 to mij do
        if is_matrix
          then write(matrix(x)[i, j]:4)
          else write(mtrstr(x)[i, j]:4);
      writeln
    end;
end;
 
//печать основной матрицы и матрицы локальных минимумов
procedure print(s: string; var x, y);
begin
  writeln(s);
  prn(x, true);
  writeln('Локальные минимумы:');
  prn(y, false);
  write('Нажмите <Enter>');
  readln
end;
 
//нахождение локальных минимумов матрицы
procedure locmin(var x: matrix; var y: mtrstr);
const p: array[boolean] of string[3] = ('---', 'min');
var i, j: integer;
    min: boolean;
begin
  for i := 1 to mij do
    for j := 1 to mij do
      begin
        min := true;
        if i > 1 then min := x[i, j] < x[i - 1, j];
        if min and (j > 1) then min := x[i, j] < x[i, j - 1];
        if min and (i < mij) then min := x[i, j] < x[i + 1, j];
        if min and (j < mij) then min := x[i, j] < x[i, j + 1];
        y[i, j] := p[min]
      end
end;
 
//зеркальное отражение матрицы, в зависимости от параметра is_vertical вертикально или горизонтально
procedure mirror(var x: matrix; is_vertical: boolean);
var i, j, t: integer;
begin
  for i := 1 to mij do
    for j := 1 to mij div 2 do
      if is_vertical
        then begin
          t := x[i, j];
          x[i, j] := x[i, mij - j + 1];
          x[i, mij - j + 1] := t
        end
        else begin
          t := x[j, i];
          x[j, i] := x[mij - j + 1, i];
          x[mij - j + 1, i] := t
        end
end;
 
//основная программа
var a: matrix;
    lm: mtrstr;
begin
  randomize; //инициализация ГПСЧ
  gen(a);
  locmin(a, lm);
  print('Исходная матрица:', a, lm);
  mirror(a, true);
  locmin(a, lm);
  print('Зеркальная перестановка относительно вертикали:', a, lm);
  mirror(a, false);
  locmin(a, lm);
  print('Зеркальная перестановка относительно горизонтали:', a, lm)
end.