Опишите функцию, подсчитывающую количество строк

 type
  PNode = ^TNode;
  TNode = record
    next: PNode;
    s: String;
  end;
 
  TMatchFunc = function (p: PNode): Boolean;
 
procedure lstRead(var h: PNode);
var
  p: ^PNode;
  ts: String;
begin
  p:=@h;
  WriteLn('Введите строки, окончание ввода - пустая строка:');
  repeat
    ReadLn(ts);
    if ts='' then Break;
    New(p^); p^^.s:=ts; p:=@p^^.next;
  until False;
  p^:=nil;
end;
 
procedure lstDispose(var h: PNode);
var p: PNode;
begin
  while h<>nil do begin
    p:=h; h:=h^.next; Dispose(p);
  end;
  h:=nil;
end;
 
procedure lstWrite(p: PNode);
begin
  WriteLn('Содержимое списка:');
  while p<>nil do with p^ do begin
    WriteLn(s); p:=next;
  end;
end;
 
function Count(p: PNode; cond: TMatchFunc): Integer;
var r: Integer;
begin
  r:=0;
  while p<>nil do begin
    if cond(p) then Inc(r);
    p:=p^.next;
  end;
  Count:=r;
end;
{$F+}
function MatchA(p: PNode): Boolean;
begin
  with p^ do MatchA:=(Length(s)>0) and (s[1]=s[Length(s)]);
end;
function MatchB(p: PNode): Boolean;
begin
  with p^ do MatchB:=(next<>nil) and (Copy(s,1,1)=Copy(next^.s,1,1));
end;
 
var
  h: PNode;
begin
  lstRead(h); lstWrite(h);
  WriteLn('начинаются и оканчиваются одним и тем же символом: ',Count(h,MatchA),', начинаются с того же символа, что и следующая строка: ',Count(h,MatchB));
  lstDispose(h);
end.