Простая проблема новичка

program lab6;
 
const kol = 25; {количество студентов}
 
Type students = record
   fio: array [1..16] of char;
   day: 1..31;
   month: 1..12;
   year: integer;
   first: array [1..4] of 2..5;  {оценки первого семестра}
   second: array [1..5] of 2..5; {оценки второго семестра}
end;
 
var
 s:students;
 every: array [1..kol] of students;
 a: array[1..kol] of real;
 i,j,c,d:integer;
 b:real;
 symbols:char;
 f,t:text;
 
begin
assign(t,'input6.txt');
rewrite(t);
 
assign(f,'B.dat');
reset(f);
 
for i := 1 to 4 do      {На заголовок отведено 4 строки}
 begin
 while not Eoln(f) do   {до конца строки}
  begin
  Read(f,symbols);
  Write(t,symbols);
  end;
 Readln(f);
 Writeln(t);
 end;
  
Readln(f);
for i:=1 to 24 do                {для каждого из 24 студентов}
 begin 
 for j:=1 to 20 do
  begin
  Read(f,every[i].fio[j]);       {считывается ФИО}
  Read(f,every[i].day);          {считывается день}
  Read(f,every[i].month);        {считывается месяц}
  Read(f,every[i].year);         {год рождения}
  for j:=1 to 4 do
   begin
   Read(f, every[i].first[j]);   {Оценки 1-го семестра}
   for j:=1 to 5 do
    begin
    Read(f,every[i].second[j]);  {Оценки 2-го семетра}
    Readln(f);
    end;
   end;
  end;
 end; 
 
for i:=1 to kol do
 begin
 for j:=1 to 4 do
  begin
  a[i]:=(every[i].first[j]+a[i])/4; {нахождение среднего балла первого семестра}
  end;
 end;
 
for i:=1 to kol-1 do            {сортировка по убыванию среднего балла}
 begin
 for j:=i+1 to kol do
  begin
  if (a[j] < a[j+1]) then
   begin
   b:=a[j];
   a[j]:=a[j+1];
   a[j+1]:=b;
   end;
  end;
 end;
 
for i := 1 to 25 do
   Write( a[i],' ');
   
Readln(f);
for i := 1 to 24 do
 begin  
 for j := 1 to 20 do
  begin
  Write(t, every[i].fio[j]);
  Write(t, every[i].day);
  Write(t, every[i].month);
  Write(t, every[i].year);
  Write(t, ' ');
  for j := 1 to 4 do
   begin
   Write(t, every[i].first[j]);
   Write(t, ' ');
   for j:= 1 to 5 do
    begin
    Write(t, every[i].second[j]);
    Writeln(t);
    end;
   end;
  end;
 end; 
 
close(f);
close(t);
end.

for j := 1 to 20 do
  begin
    //...
    for j := 1 to 4 do
      begin
        //...
        for j := 1 to 5 do
         begin
         //...
         end;
        //...
      end;
    //...
  end;

for i:=1 to kol-1 do            {сортировка по убыванию среднего балла}
 begin
 for j:=i+1 to kol do
  begin
  if (a[j] < a[j+1]) then
   begin
   b:=a[j];
   a[j]:=a[j+1];
   a[j+1]:=b;
   s:=every[j];
   every[j]:=every[j+1];
   every[j+1]:=s;
   end;
  end;
 end;

program lab6;
 
const
  kol = 2; {количество студентов}
  kfio= 16;  {длина fio}
  k1 = 4;   {количество оценок за 1 семестр}
  k2 = 5;   {количество оценок за 2 семестр}
Type
  students =
    record
      fio: array[1..kfio] of char;
      day: 1..31;
      month: 1..12;
      year: integer;
      first: array [1..k1] of 2..5;  {оценки первого семестра}
      second: array [1..k2] of 2..5; {оценки второго семестра}
    end;
 
var
  s: students;
  every: array [1..kol] of students;
  a: array[1..kol] of real;
  i, j: integer;
  c: char;
  b: real;
  str: string;
  f, t: text;
begin
  assign(t,'input6.txt');
  rewrite(t);
 
  assign(f,'B.dat');
  reset(f);
 
  for i := 1 to 4 do      {На заголовок отведено 4 строки}
    begin
      readln(f, str);
      writeln(t, str)
    end;
 
  for i := 1  to kol do                {для каждого из 24 студентов}
    with every[i] do
      begin
        for j := 1 to kfio do            {ФИО}
          begin
            read(f, c);
            fio[j] := c
          end;
        read(f, day);                  {день}
        read(f, month);                {месяц}
        read(f, year);                 {год рождения}
        for j := 1 to k1 do             {Оценки 1-го семестра}
          read(f, first[j]);
        for j := 1 to k2 do             {Оценки 2-го семетра}
          read(f, second[j]);
        readln(f)
      end;
 
  for i := 1 to kol do              {нахождение среднего балла первого семестра}
    for j := 1 to k1 do
        a[i] := a[i] + every[i].first[j] / k1;
 
  for i := 1 to kol - 1 do            {сортировка по невозрастанию среднего балла}
    for j := i + 1 to kol do
      if a[i] < a[j] then
        begin
          b := a[i];
          a[i] := a[j];
          a[j] := b;
          s := every[i];
          every[i] := every[j];
          every[j] := s
        end;
 
  for i := 1 to kol do
    with every[i] do
      begin
        for j := 1 to kfio do write(t, fio[j]);
        write(t, ' ', day);
        Write(t, ' ', month);
        Write(t, ' ', year);
        for j := 1 to k1 do write(t, ' ', first[j]);
        for j:= 1 to k2 do write(t, ' ', second[j]);
        Writeln(t)
      end;
 
  close(f);
  close(t)
end.

  for i := 1 to kol do
    with every[i] do
      begin
        for j := 1 to kfio do write(t, fio[j]);
        write(t, day:8);
        Write(t, month:7);
        Write(t, year:9);
        write(t, '   '); //пробел между годом и оценками
        for j := 1 to k1 do write(t, first[j]:2);
        write(t, '   '); //пробел между группами оценок
        for j:= 1 to k2 do write(t, second[j]:2);
        Writeln(t)
      end;