Найти сумму всех простых чисел, значения которых не превышает n

var n,i,j,k,a:integer;
    m:array[1..1000] of boolean;//пусть n максимальное=1000
    s:integer;
begin
readln(n);
//разбиваем числа от 2 до n на простые и составные, используя решето Эратосфена
m[1] := false;//число 1 не простое
for i:=2 to n do m[i] := true;//пока все считаем простыми
for i:=2 to round(sqrt(n)) do
for j:=2 to n div i do //перебираем все возможные произведения
m[i*j]:=false;//это составное, будем "выкалывать"
s:=0;
for i:=1 to n do
if m[i] then s:=s+i;
write(s)
end.

{$BITPACKING ON}
{$mode Delphi}
program Eratosfen;
 
const
  //верхняя граница рассматриваемых кандидатов в простые числа
  Nmax = 1000 * 1000 * 100;
type
  TVector = packed array [0..Nmax] of boolean;
var
  PrimeCandidate, Step, j, LastCandidate: QWord;
  Sieve:  TVector;
  n, Sum: QWord;
begin
  readln(n);
  //инициализация
  Sum := 0;
  if (n > 1) then
  begin
    if (n = 2) then
      Sum := 2
    else
    begin
      if (n = 3) then
        Sum := 5
      else
      begin
        Sum := 5;
        {заполнение решета Эратосфена - сразу "вычёркиваем" чётные числа}
        fillchar(Sieve, sizeof(Sieve), $AA);
        {особые случаи для 0, 1 и 2}
        Sieve[0] := False;
        Sieve[1] := False;
        Sieve[2] := True;
        {особый случай для 3}
        j := 9;
        while j <= n do
        begin
          Sieve[j] := False;
          Inc(j, 6);
        end;
        {заполнение для простых чисел, начиная от 5}
        PrimeCandidate := 5;
        Step := 2;
        LastCandidate := round(sqrt(n)) + 1;
        while (PrimeCandidate <= LastCandidate) do
        begin
          if Sieve[PrimeCandidate] then
          begin
            Inc(Sum, PrimeCandidate);
            j := sqr(PrimeCandidate);
            while (n >= j) do
            begin
              Sieve[j] := False;
              Inc(j, PrimeCandidate);
            end;
          end;
          PrimeCandidate := PrimeCandidate + Step;
          Step := Step xor $6;
        end;
        //суммирование простых чисел, котроые уже не участвуют в вычёркивании
        while (PrimeCandidate <= n) do
        begin
          if Sieve[PrimeCandidate] then
            Inc(Sum, PrimeCandidate);
          PrimeCandidate := PrimeCandidate + Step;
          Step := Step xor $6;
        end;
      end;
    end;
  end;
  writeln(Sum);
end.