Сформировать новое множество

@___funny · Регистрация: 16.12.2019

Студворк — интернет-сервис помощи студентам

Дано множество Х1, содержащее символы из диапазона [a..z]. Сформировать новое множество Y1 путем выделения из множества Х1 всех символов в алфавите позже f и раньше m, и множество Y2 путем выделения из множества Х1 символов, расположенных раньше g или позже j. На экнран вывести множество .

@ValentinNemo · 20.12.2019, 01:50

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
program Project1;
var
  x,y1,y2: set of char; {переменные для хранения множеств}
  i: integer;  {вспомогательная переменная для организации цикла }
 
begin
  x:= ['a'..'z'];
  y1:= ['g'..'l'];
  y2:= ['a'..'f', 'k'..'z'];
  writeln('Set x:');
  for i:= 0 to 255 do
    if chr(i) in x then
        write(chr(i),' ');
  writeln;
  writeln('Set y1:');
  for i:= 0 to 255 do
    if chr(i) in y1 then
        write(chr(i),' ');
   writeln;
  writeln('Set y2:');
  for i:= 0 to 255 do
    if chr(i) in y2 then
        write(chr(i),' ');
  Readln;
end.

@___funny · 23.12.2019, 18:58 **[ТС]**

На экнран вывести множество Y3=(Y1/Y2). Извините пожалуйста , не дописала

@ValentinNemo · 24.12.2019, 05:37

https://ru.wikipedia.org/wiki/... 0%B2%D0%BE
Знак деления означает разность между множествами? Если так, то

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
program Project1;
var
  x,y1,y2,y3: set of char; {переменные для хранения множеств}
  i: integer;  {вспомогательная переменная для организации цикла }
 
begin
  x:= ['a'..'z'];
  y1:= ['g'..'l'];
  y2:= ['a'..'f', 'k'..'z'];
  writeln('Set x:');
  for i:= 0 to 255 do
    if chr(i) in x then
        write(chr(i),' ');
  writeln;
  writeln('Set y1:');
  for i:= 0 to 255 do
    if chr(i) in y1 then
        write(chr(i),' ');
   writeln;
  writeln('Set y2:');
  for i:= 0 to 255 do
    if chr(i) in y2 then
        write(chr(i),' ');
  Y3:= Y1-Y2;
  writeln;
  writeln('Set y3:');
  for i:= 0 to 255 do
    if chr(i) in y3 then
        write(chr(i),' ');
  Readln;
end.

@Cyborg Drone · 29.12.2019, 03:56

Задание содержит разночтение: неясно, что содержит множество X1: некоторые символы из диапазона ['a'..'z'] или все символы из диапазона ['a'..'z']

ValentinNemo, Ваши программы по-любому не соответствует заданию, поскольку множества Y1 и Y2 у Вас не формируются из исходного множества, а декларируются.

И почему Вы в качестве счётчиков цикла не используете переменные типа char?

Если считать, что X1 = ['a'..'z'], то можно так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
type
  sc = set of char;
 
procedure prn(s: string; const x: sc);
var
  c: char;
  d: string[2];
begin
  d := '';
  writeln('Множество ', s, ':');
  write('[');
  for c := 'a' to 'z' do
    if c in x then
      begin
        write(d);
        if length(d) = 0 then d := ', ';
        write(c)
      end;
  writeln(']')
end;
 
var
  X1, Y1, Y2, Y3: sc;
 
begin
  X1 := ['a'..'z'];
  prn('X1', X1);
  Y1 := X1 * [succ('f')..pred('m')];
  prn('Y1', Y1);
  Y2 := X1 - ['g'..'j'];
  prn('Y2', Y2);
  Y3 := Y1 - Y2;
  prn('Y3', Y3);
  readln
end.

Если считать, что X1 $https://www.cyberforum.ru/cgi-bin/latex.cgi?\small \in$ ['a'..'z'], то X1 нужно будет ввести, например, так:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
type
  sc = set of char;
 
procedure prn(s: string; const x: sc);
var
  c: char;
  d: string[2];
begin
  d := '';
  writeln('Множество ', s, ':');
  write('[');
  for c := 'a' to 'z' do
    if c in x then
      begin
        write(d);
        if length(d) = 0 then d := ', ';
        write(c)
      end;
  writeln(']')
end;
 
var
  X1, Y1, Y2, Y3: sc;
  p: char;
 
begin
  X1 := [];
  writeln('Введите в одну строку символы из диапазона [''a''..''z'']:');
  while not SeekEoLn do
    begin
      read(p);
      if p in ['a'..'z'] then include(X1, p)
    end;
  readln;
  prn('X1', X1);
  Y1 := X1 * [succ('f')..pred('m')];
  prn('Y1', Y1);
  Y2 := X1 - ['g'..'j'];
  prn('Y2', Y2);
  Y3 := Y1 - Y2;
  prn('Y3', Y3);
  readln
end.

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Обработчик клика мыши в браузере ПК и касания экрана в браузере на мобильном устройстве 8Observer8 02.02.2026 Содержание блога Для начала пошагово создадим рабочий пример для подготовки к экспериментам в браузере ПК и в браузере мобильного устройства. Потом напишем обработчик клика мыши и обработчик. . .	Философия технологии iceja 01.02.2026 На мой взгляд у человека в технических проектах остается роль генерального директора. Все остальное нейронки делают уже лучше человека. Они не могут нести предпринимательские риски, не могут. . .	SDL3 для Web (WebAssembly): Вывод текста со шрифтом TTF с помощью SDL3_ttf 8Observer8 01.02.2026 Содержание блога В этой пошаговой инструкции создадим с нуля веб-приложение, которое выводит текст в окне браузера. Запустим на Android на локальном сервере. Загрузим Release на бесплатный. . .	SDL3 для Web (WebAssembly): Сборка C/C++ проекта из консоли 8Observer8 30.01.2026 Содержание блога Если вы откроете примеры для начинающих на официальном репозитории SDL3 в папке: examples, то вы увидите, что все примеры используют следующие четыре обязательные функции, а. . .
SDL3 для Web (WebAssembly): Установка Emscripten SDK (emsdk) и CMake для сборки C и C++ приложений в Wasm 8Observer8 30.01.2026 Содержание блога Для того чтобы скачать Emscripten SDK (emsdk) необходимо сначало скачать и уставить Git: Install for Windows. Следуйте стандартной процедуре установки Git через установщик. . . .	SDL3 для Android: Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 29.01.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами. Версия v3 была полностью переписана на Си, в. . .	Инструменты COM: Сохранение данный из VARIANT в файл и загрузка из файла в VARIANT bedvit 28.01.2026 Сохранение базовых типов COM и массивов (одномерных или двухмерных) любой вложенности (деревья) в файл, с возможностью выбора алгоритмов сжатия и шифрования. Часть библиотеки BedvitCOM Использованы. . .	SDL3 для Android: Загрузка PNG с альфа-каналом с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 28.01.2026 Содержание блога SDL3 имеет собственные средства для загрузки и отображения PNG-файлов с альфа-каналом и базовой работы с ними. В этой инструкции используется функция SDL_LoadPNG(), которая. . .

@___funny 0 / 0 / 0 Регистрация: 16.12.2019 Сообщений: 16

	Сформировать новое множество 19.12.2019, 20:27. Показов 2178. Ответов 4 Метки нет (Все метки) Дано множество Х1, содержащее символы из диапазона [a..z]. Сформировать новое множество Y1 путем выделения из множества Х1 всех символов в алфавите позже f и раньше m, и множество Y2 путем выделения из множества Х1 символов, расположенных раньше g или позже j. На экнран вывести множество . 0

@___funny 0 / 0 / 0 Регистрация: 16.12.2019 Сообщений: 16
	23.12.2019, 18:58 [ТС]
	На экнран вывести множество Y3=(Y1/Y2). Извините пожалуйста , не дописала 0

Сформировать новое множество

Решение