В одномерном массиве из случайных букв подсчитать количество гласных, и заменить их случайной цифрой

@Darova2020 · Регистрация: 21.04.2020

Студворк — интернет-сервис помощи студентам

Помогите решить хитрую задачу на Паскаль

: "Заполните одномерный массив случайными буквами латинского алфавита, подсчитать количество гласных букв стоящих на нечетных местах и заменить их цифрой, выбранной тоже случайным образом."

- а). С помощью строк.
- б). С помощью массивов.
- в). С помощью последовательных процедур или функций.
- г). С помощью вложенных процедур или функций.

Спасибо!!

@Cyborg Drone · 06.09.2020, 11:08

Я так понимаю, что вся хитрость этой задачи в том, что Вы чего-то там недоучили.

а)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
const
  m = 100;
var
  a: string;
  i, n, k: integer;
  c: char;
begin
  randomize;
  repeat
    write('Введите количество букв [1..', m, ']: ');
    readln(n)
  until n in [1..m];
  c := char(ord('0') + random(10));
  writeln('Исходный массив:');
  for i := 1 to n do
    begin
      a := a + char(ord('a') + random(26));
      write(a[i]);
      if odd(i) and (a[i] in ['a', 'e', 'i', 'o', 'u']) then
        begin
          a[i] := c;
          inc(k)
        end
    end;
  writeln;
  writeln('Количество гласных букв на нечётных местах: ', k);
  writeln('Преобразованный массив:');
  write(a);
  readln
end.

б)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
const
  m = 100;
var
  a: array[1..m] of char;
  i, n, k: integer;
  c: char;
begin
  randomize;
  repeat
    write('Введите количество букв [1..', m, ']: ');
    readln(n)
  until n in [1..m];
  c := char(ord('0') + random(10));
  writeln('Исходный массив:');
  for i := 1 to n do
    begin
      a[i] := char(ord('a') + random(26));
      write(a[i]);
      if odd(i) and (a[i] in ['a', 'e', 'i', 'o', 'u']) then
        begin
          a[i] := c;
          inc(k)
        end
    end;
  writeln;
  writeln('Количество гласных букв на нечётных местах: ', k);
  writeln('Преобразованный массив:');
  for i := 1 to n do write(a[i]);
  readln
end.

Процедуры и функции, тем более вложенные, здесь нужны как зайцу стоп-сигнал. Но - надо так надо.

в)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
const
  m = 100;
 
procedure readln_q(var x: integer);
begin
  repeat
    write('Введите количество букв [1..', m, ']: ');
    readln(x)
  until x in [1..m]
end;
 
procedure generate(var x: array of char; p: integer);
var
  i: integer;
begin
  for i := 0 to p - 1 do x[i] := char(ord('a') + random(26))
end;
 
procedure print(s: string; var x: array of char; p: integer);
var
  i: integer;
begin
  writeln(s);
  for i := 0 to p - 1 do write(x[i]);
  writeln
end;
 
procedure change(var x: array of char; p: integer; var q: integer; t: char);
var
  i: integer;
begin
  for i := 0 to p - 1 do
    if not odd(i) and (x[i] in ['a', 'e', 'i', 'o', 'u']) then
      begin
        x[i] := t;
        inc(q)
      end
end;
 
var
  a: array[1..m] of char;
  n, k: integer;
begin
  randomize;
  readln_q(n);
  generate(a, n);
  print('Исходный массив:', a, n);
  change(a, n, k, char(ord('0') + random(10)));
  writeln('Количество гласных букв на нечётных местах: ', k);
  print('Преобразованный массив:', a, n);
  readln
end.

г)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
const
  m = 100;
 
procedure readln_q(var x: integer);
begin
  repeat
    write('Введите колчество букв [1..', m, ']: ');
    readln(x)
  until x in [1..m]
end;
 
procedure generate(var x: array of char; p: integer);
var
  i: integer;
begin
  for i := 0 to p - 1 do x[i] := char(ord('a') + random(26))
end;
 
procedure print(s: string; var x: array of char; p: integer);
var
  i: integer;
begin
  writeln(s);
  for i := 0 to p - 1 do write(x[i]);
  writeln
end;
 
procedure change(var x: array of char; p: integer; var q: integer; t: char);
  procedure tr(f: integer; var g: integer; var v: char; w: char);
  begin
    if not odd(f) and (v in ['a', 'e', 'i', 'o', 'u']) then
      begin
        v := w;
        inc(g)
      end
  end;
var
  i: integer;
begin
  for i := 0 to p - 1 do tr(i, q, x[i], t);
end;
 
var
  a: array[1..m] of char;
  n, k: integer;
begin
  randomize;
  readln_q(n);
  generate(a, n);
  print('Исходный массив:', a, n);
  change(a, n, k, char(ord('0') + random(10)));
  writeln('Количество гласных букв на нечётных местах: ', k);
  print('Преобразованный массив:', a, n);
  readln
end.

Новые блоги и статьи Все статьи Все блоги /
Отправка уведомления на почту при изменении наименования справочника Maks 24.03.2026 Программная отправка письма электронной почты на примере изменения наименования типового справочника "Склады" в конфигурации БП3. Перед реализацией необходимо выполнить настройку системной учетной. . .	модель ЗдравоСохранения 5. Меньше увольнений- больше дохода! anaschu 24.03.2026 Теперь система здравосохранения уменьшает количество увольнений. 9TO2GP2bpX4 a42b81fb172ffc12ca589c7898261ccb/ https:/ / rutube. ru/ video/ a42b81fb172ffc12ca589c7898261ccb/ Слева синяя линия -. . .	Midnight Chicago Blues kumehtar 24.03.2026 Такой Midnight Chicago Blues, знаешь?. . Когда вечерние улицы становятся ночными, а ты не можешь уснуть. Ты идёшь в любимый старый бар, и бармен наливает тебе виски. Ты смотришь на пролетающие. . .	SDL3 для Desktop (MinGW): Вывод текста со шрифтом TTF с помощью библиотеки SDL3_ttf на Си и C++ 8Observer8 24.03.2026 Содержание блога Финальные проекты на Си и на C++: finish-text-sdl3-c. zip finish-text-sdl3-cpp. zip
Жизнь в неопределённости kumehtar 23.03.2026 Жизнь — это постоянное существование в неопределённости. Например, даже если у тебя есть список дел, невозможно дойти до точки, где всё окончательно завершено и больше ничего не осталось. В принципе,. . .	Модель здравоСохранения: работники работают быстрее после её введения. anaschu 23.03.2026 geJalZw1fLo Корпорация до введения программа здравоохранения имела много невыполненных работниками заданий, после введения программы количество заданий выросло. Но на выплатах по больничным это. . .	Контроль уникальности заводского номера Maks 23.03.2026 Алгоритм контроля уникальности заводского (или серийного) номера на примере нетипового документа выдачи шин для спецтехники с табличной частью, разработанного в конфигурации КА2. Данные берутся из. . .	Хочу заставить корпорации вкладываться в здоровье сотрудников: делаю мат модель здравосохранения anaschu 22.03.2026 e7EYtONaj8Y Z4Tv2zpXVVo https:/ / github. com/ shumilovas/ med2. git

@Darova2020 0 / 0 / 0 Регистрация: 21.04.2020 Сообщений: 4

	В одномерном массиве из случайных букв подсчитать количество гласных, и заменить их случайной цифрой 06.09.2020, 09:25. Показов 1569. Ответов 1 Метки нет (Все метки) Помогите решить хитрую задачу на Паскаль : "Заполните одномерный массив случайными буквами латинского алфавита, подсчитать количество гласных букв стоящих на нечетных местах и заменить их цифрой, выбранной тоже случайным образом." - а). С помощью строк. - б). С помощью массивов. - в). С помощью последовательных процедур или функций. - г). С помощью вложенных процедур или функций. Спасибо!! 0

В одномерном массиве из случайных букв подсчитать количество гласных, и заменить их случайной цифрой

Решение