Вычислить матрицу по формулам

const
  Rows = 100;
  Cols = 100;
 
type
  matrix = record
    r, c : Integer;
    arr  : array [1..Rows, 1..Cols] of Real;
  end;
 
function ReadMatrixSize(name : String) : matrix;
var
  m : matrix;
begin
  Write('Введите размеры матрицы ', name, ': ');
  ReadLn(m.r, m.c);
  ReadMatrixSize := m;
end;  
 
procedure GenMatrixA(var m : matrix);
var r, c : Integer;
begin
  for r := 1 to m.r do
    for c := 1 to m.c do
      m.arr[r, c] := 1.5 * r - 4;
end;
 
procedure GenMatrixB(var m : matrix);
var r, c : Integer;
begin
  for r := 1 to m.r do
    for c := 1 to m.c do
      m.arr[r, c] := 0.4 * c + exp(sin(c));
end;
 
procedure OutMatrix(msg : String; m : matrix);
var r, c : Integer;
begin
  WriteLn(msg);
  for r := 1 to m.r do
    begin
      for c := 1 to m.c do
        Write(m.arr[r,c]:10:3);
      WriteLn;
    end;
end;
 
function MulMatrix(a, b : matrix) : matrix;
var m : matrix; r, c, i : Integer;
begin
  m.r := a.r;
  m.c := b.c;
  for r := 1 to m.r do
    for c := 1 to m.c do
      begin
        m.arr[r,c] := 0;
        for i := 1 to a.c do
          m.arr[r,c] := m.arr[r,c] + a.arr[r,i] * b.arr[i,c];
      end;
  MulMatrix := m;
end;
 
var
  A, B, F : matrix;
 
begin
  A := ReadMatrixSize('A'); GenMatrixA(A); OutMatrix('создана матрица A', A);
  B := ReadMatrixSize('B'); GenMatrixB(B); OutMatrix('создана матрица B', B);
  if A.c = B.r then
    begin
      F := MulMatrix(A, B);
      OutMatrix('Получена матрица F = A*B', F);
    end
  else
    WriteLn('Нельзя получить F = A*B');
end.