Срочно нужна помощь - множества! В алфавитном порядке вывести на экран все гласные, которые входят в каждое N-ое слово.

program Project1;
 
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  //Множество гласных букв.
  Db = [
    //Русские.
    'А', 'Е', 'Ё', 'И', 'Й', 'О', 'У', 'Ы', 'Э', 'Ю', 'Я',
    'а', 'е', 'ё', 'и', 'й', 'о', 'у', 'ы', 'э', 'ю', 'я',
    //Латинские.
    'А', 'О', 'Е', 'I', 'У', 'U',
    'а', 'о', 'е', 'i', 'у', 'u'
  ];
var
  S : String;
  i, j, Len, Pos1, CntW, N : Integer;
  DRes, DTmp : set of Char;
  Ch : Char;
  F : Boolean;
begin
  repeat
    Writeln('Задайте строку:');
    Readln(S);
    Writeln('Задайте натуральное число:');
    Readln(N);
 
    Len := Length(S);
    //Флаг первого N-го слова.
    F := True;
    //Результирующее множество.
    DRes := [];
    //Множество гласных букв в очередном N-ом слове.
    DTmp := [];
    //Счётчик слов.
    CntW := 0;
    //Позиция начала слова.
    Pos1 := 0;
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Отслеживаем начало слова.
      if (i = 1) or (S[i - 1] in D) then Pos1 := i;
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        Inc(CntW);
        //Если номер слова не кратен периоду N - пропускаем итерацию.
        if CntW mod N <> 0 then Continue;
        //Составляем множество гласных букв очередного N-го слова.
        for j := Pos1 to i do
          if S[j] in Db then DTmp := DTmp + [ S[j] ];
        //Инициализируем DRes на первом найденном N-ом слове.
        if F then begin
          DRes := DTmp;
          F := False;
        end;
        //Множество гласных букв, которые присутствуют в каждом N-ом слове.
        DRes := DRes * DTmp;
        //Если DRes оказалось пустым - выходим из цикла.
        if DRes = [] then Break;
        //Обнуление множества.
        DTmp := [];
      end;
    end;
 
    if DRes = [] then begin
      Writeln('Нет гласных букв, которые бы присутствовали в каждом ', N, '-м слове.');
    end else begin
      Writeln('Множество гласных букв, которые присутствуют в каждом ', N, '-м слове.');
      for Ch := #0 to #255 do begin
        if Ch in DRes then Writeln(Ch);
      end;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.