Динамические структуры данных: Реализовать функции для работы с двунаправленным списком

program Project1;
 
type
  //Тип основных данных.
  TData = Integer;
  //Указатель на элемент списка.
  TPElem = ^TElem;
  //Элемент списка.
  TElem = record
    Data : TData; //Основные данные.
    PPrev, PNext : TPElem; //Указатели на предыдущий и на следующий элементы.
  end;
  //Тип, описывающий список.
  TDList = record
    Cnt : Integer; //Количество элементов в списке.
    PFirst, PLast : TPElem; //Указатели на первый и на последний элементы списка.
  end;
 
//Процедура инициализации списка. Внимание! Эту процедуру можно применять
//только в отношении пустого списка! Иначе будет утечка памяти.
procedure Init(var aList : TDList);
begin
  aList.Cnt := 0;
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
//Добавление элемента в конец списка.
procedure Add(var aList : TDList; const aData : TData);
var
  PElem : TPElem;
begin
  New(PElem);
  PElem^.Data := aData;
  PElem^.PPrev := nil;
  PElem^.PNext := nil;
  if aList.PFirst = nil then begin
    aList.PFirst := PElem;
    aList.PLast := PElem;
  end else begin
    aList.PLast^.PNext := PElem;
    PElem^.PPrev := aList.PLast;
    aList.PLast := PElem;
  end;
  Inc(aList.Cnt);
end;
 
//Удаление всего списка из памяти и инициализация.
procedure Free(var aList : TDList);
var
  PElem, PDel : TPElem;
begin
  PElem := aList.PFirst;
  while PElem <> nil do begin
    PDel := PElem;
    PElem := PElem^.PNext;
    Dispose(PDel);
  end;
  Init(aList);
end;
 
//Распечатка элементов списка.
procedure Print(const aList : TDList);
var
  PElem : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PElem := aList.PFirst;
  while PElem <> nil do begin
    if PElem <> aList.PFirst then Write(', ');
    Write(PElem^.Data);
    PElem := PElem^.PNext;
  end;
  Writeln;
end;
 
//Удаление элемента из списка.
procedure Del(var aList : TDList; const aPDel : TPElem);
begin
  if (aList.PFirst = nil) or (aPDel = nil) then Exit;
 
  if aPDel^.PPrev <> nil then
    aPDel^.PPrev^.PNext := aPDel^.PNext
  else
    aList.PFirst := aPDel^.PNext;
 
  if aPDel^.PNext <> nil then
    aPDel^.PNext^.PPrev := aPDel^.PPrev
  else
    aList.PLast := aPDel^.PPrev;
 
  Dispose(aPDel);
end;
 
//Удаление из списка всех элементов с заданным значением.
//Функция возвращает количество удалённых элементов.
function DelByVal(var aList : TDList; const aData : TData) : Integer;
var
  PElem, PDel : TPElem;
  Cnt : Integer;
begin
  Cnt := 0;
  PElem := aList.PFirst;
  while PElem <> nil do
    if PElem^.Data = aData then begin
      PDel := PElem;
      PElem := PElem^.PNext;
      Del(aList, PDel);
      Inc(Cnt);
    end else
      PElem := PElem^.PNext;
 
  DelByVal := Cnt;
end;
 
//Диалог добавления элементов в список.
procedure WorkAdd(var aList : TDList);
var
  S : String;
  Data : TData;
  Code : Integer;
begin
  Writeln('Добавьте элементы в список.');
  Writeln('Ввод каждого значения завершайте нажатием Enter.');
  Writeln('Чтобы прекратить ввод оставьте пустую строку и нажмите Enter.');
  repeat
    Write('Элемент №', aList.Cnt + 1, ': ');
    Readln(S);
    if S = '' then begin
      Writeln('Отмена.');
      Code := 0;
    end else begin
      Val(S, Data, Code);
      if Code = 0 then begin
        Add(aList, Data);
        Writeln('Элемент добавлен.');
        Code := 1;
      end else
        Writeln('Неверный ввод. Повторите.');
    end;
  until Code = 0;
  Writeln('Ввод элементов списка завершён.');
end;
 
var
  L : TDList;
  Data : TData;
  Cmd, Code, Cnt : Integer;
  S : String;
begin
  //Начальная инициализация списка.
  Init(L);
 
  repeat
    //Меню
    Writeln('Выберите действие:');
    Writeln('1: Добавление элементов в список.');
    Writeln('2: Распечатка всего списка.');
    Writeln('3: Удаление элементов по условию.');
    Writeln('4: Удаление всего списка (очистка).');
    Writeln('5: Выход.');
    Write('Введите команду: ');
    Readln(Cmd);
    case Cmd of
      1: WorkAdd(L);
      2:
        if L.PFirst = nil then
          Writeln('Список пуст.')
        else begin
          Writeln('Элементы списка:');
          Print(L);
        end;
      3:
      begin
        repeat
          Writeln('Элементы с заданным значением будут удалены из списка.');
          Writeln('Чтобы прервать операцию оставьте пустую строку и нажмите Enter.');
          Write('Значение: ');
          Readln(S);
          if S = '' then begin
            Writeln('Операция отменена.');
            Code := 0;
          end else begin
            Val(S, Data, Code);
            if Code = 0 then begin
              Cnt := DelByVal(L, Data);
              Writeln('Список обработан. Количество удалённых элементов: ', Cnt);
              Code := 1;
            end else
              Writeln('Неверный ввод. Повторите.');
          end;
        until Code = 0;
      end;
      4, 5:
      begin
        Free(L);
        Writeln('Список удалён из памяти (очищен).');
      end;
      else
        Writeln('Незарегистрированная команда. Повторите ввод.');
    end;
  until Cmd = 5;
 
  Writeln('Работа программы завершена. Для выхода нажмите Enter.');
  Readln;
end.