По одной очереди построить две новых из положительных и отрицательных элементов

Type
  Ochered = ^dan;
  dan = Record
          data : Integer;
          next : Ochered;
        end;
Var
  q0,q1,q2 : Ochered;
 
Procedure DisposeItem(Var qq : Ochered);
Var tmp : Ochered;
Begin
  While qq<>nil do
  Begin
    tmp:=qq;
    qq:=qq^.next;
    Dispose(tmp);
  end;
end;
 
Procedure AddNewItem(Var qq : Ochered; NewData : Integer);
Var tmp,tt : Ochered;
Begin
  New(tmp);
  tmp^.data:=NewData;
  tmp^.next:=nil;
  tt:=qq;
  If tt=nil then qq:=tmp
  else
    Begin
      While tt^.next<>nil do tt:=tt^.next;
      tt^.next:=tmp;
    end;
end;
 
Procedure SplitOchered(qqq : Ochered; Var qq1,qq2: Ochered);
Begin
  While qqq<>nil do
  Begin
    If qqq^.data>0 then AddNewItem(qq1,qqq^.data) else AddNewItem(qq2,qqq^.data);
    qqq:=qqq^.next;
  end;
end;
 
Procedure ShowOchered(z : Ochered);
Begin
  While z<>nil do
  Begin
    Write(z^.data,'  ');
    z:=z^.next;
  end;
end;
 
Begin
  q0:=nil; q1:=nil; q2:=nil;
  For var i:integer:=-5 to 5 do AddNewItem(q0,i);
  ShowOchered(q0); Writeln(#13,#10);
  SplitOchered(q0,q1,q2);
  ShowOchered(q1); Writeln(#13,#10);
  ShowOchered(q2); Writeln(#13,#10);
  DisposeItem(q0);
  DisposeItem(q1);
  DisposeItem(q2);  
end.

uses crt;
 
type pitem = ^item;
     item = record
         data : integer;
         next : pitem;
     end;
     queue = record
         first , last : pitem;
     end;
 
var common , positive , negative : queue;
    i : integer;
 
procedure init_queue(var q : queue);
begin
    q.first := nil;
    q.last := nil;
end;
 
procedure add_item(var q : queue ; data : integer);
var t : pitem;
begin
    new(t);
    t^.data := data;
    t^.next := nil;
    if q.first = nil then begin
        q.first := t;
        q.last := t;
    end else begin
        q.last^.next := t;
        q.last := t;
    end;
end;
 
procedure split(var q : queue; var positive , negative : queue);
var t , tt : pitem;
    data : integer;
begin
    t := q.first;
    while t <> nil do begin
        data := t^.data;
        if data >= 0 then
            add_item(positive , data)
        else
            add_item(negative , data);
        tt := t;
        t := t^.next;
        dispose(tt);    
    end;
end;
 
procedure print_queue(q : queue);
var t : pitem;
begin
    t := q.first;
    while t <> nil do begin
        write(t^.data , ' ');
        t := t^.next;
    end;
    writeln;
end;
 
procedure clean_queue(var q : queue);
var t , tt : pitem;
begin
    t := q.first;
    while t <> nil do begin
        tt := t;
        t := t^.next;
        dispose(tt);
    end;
end;
 
begin
    init_queue(common); init_queue(positive); init_queue(negative);
    randomize;
    for i := 1 to 10 do
        add_item(common , -10 + random(21));
    writeln('Initial queue: ');
    print_queue(common);    
    split(common , positive , negative);
    writeln('Positive: ');
    print_queue(positive);
    writeln('Negative: ');
    print_queue(negative);
    clean_queue(positive);
    clean_queue(negative);
    readkey;
end.

uses System.Collections.Generic;
 
procedure Print(myQueue : Queue<integer>);
begin
  foreach v : integer in myQueue do write(v:4);
  writeln;
end;
 
begin
  var q : Queue<integer> := new Queue<integer>;
  for var i := -10 to 20 do
    q.Enqueue(i);
  Print(q);
  
  var queue1 : Queue<integer> := new Queue<integer>;
  var queue2 : Queue<integer> := new Queue<integer>;
  var queues : array[boolean] of Queue<integer> := (queue1, queue2);
  
  while q.Count > 0 do
  begin
    var v := q.Dequeue;
    queues[v > 0].Enqueue(v);
  end;
  Print(queue1);
  Print(queue2);
end.