Оператор case - вычисление даты следующего дня

{ Даны два целых числа: D (день) и M (месяц), определяющие 
правильную дату невисокосного года. Вывести значения D и M 
для даты, следующей за указанной. }
 
var
  D, M, CountDay: byte;
 
begin
 { ВВОДИМ ДЕНЬ И МЕСЯЦ: }
  write(' D = ');
  readln(D); //Вводим значение дня.
  write(' M = ');
  readln(M); //Вводим значение месяца.
  writeln;
 { ПРОВЕРЯЕМ МЕСЯЦЫ ГОДА: }
 { Группируем месяцы по количеству дней: }
  case M of
   { Второй месяц имеет всего 28 дней }
    2: CountDay := 28;
       
   { Следующие месяцы имеют по 30 дней: }    
    4, 6, 9, 11:
       CountDay := 30;
       
   { Следующие месяцы имеют по 31 день: }    
    1, 3, 5, 7, 8, 10, 12:
       CountDay := 31
  end;
 { Если D < CountDay, то увеличиваем день D на единицу;
 если D = CountDay, то следующий день равен 1, а месяц 
 увеличивается на 1 (первый день следующего месяца): }
  if D < CountDay then inc(D)
  else begin
    M := M mod 12 + 1;
    D := 1
  end;
{ ВЫВОДИМ РЕЗУЛЬТАТ: }  
  write('Следующая дата: ');
  if D < 10 then write('0', D, '.')
  else write(D, '.');
  if M < 10 then write('0', M)
  else write(M)
end.

{ По информации о правильной дате, включающей день D, номер 
месяца M и год Y, определяет следующую дату }
 
var
  D, M, CountDay: byte;
  Y: integer;
 
begin
  writeln('Введите правильную дату:');
  write('введите день:  D = ');
  readln(D);
  write('введите месяц: M = ');
  readln(M);
  write('введите год:   Y = ');
  readln(Y);   
 { Группируем месяцы по  количеству дней: }
  case M of
   { Второй месяц имеет 28 дней (для невисокосного года): }
    2: CountDay := 28;
       
   { Следующие месяцы имеют по 30 дней: }    
    4, 6, 9, 11:
       CountDay := 30;
       
   { Следующие месяцы имеют по 31 день: }    
    1, 3, 5, 7, 8, 10, 12:
       CountDay := 31
  end;
 { Если год високосный, месяц второй, а день 28-й, то следующий день 29-й: }
  if ((Y mod 4 = 0) and (Y mod 100 <> 0) or (Y mod 400 = 0)) and
     (M = 2) and (CountDay = 28) then CountDay := 29;
 { Если D < CountDay, то увеличиваем день D на единицу;
  если D = CountDay, то следующий день равен 1, а месяц 
  увеличивается на 1 (первый день следующего месяца): }
  if D < CountDay then inc(D)
  else begin
    M := M mod 12 + 1;
    D := 1
  end;
 { Если имеем дату 01.01.Y, то увеличиваем год на 1: }
  if (D = 1) and (M = 1) then inc(Y);  
  writeln('Следующая дата: ');
 { Выводим предыдущую дату в формате D.M.Y: }
  if D < 10 then write(' 0', D, '.')
  else write(' ', D, '.');
  if M < 10 then write('0', M)
  else write(M);
  writeln('.', Y);
  writeln
end.

function IsLeapYear(Y: Integer): Boolean;
begin
  IsLeapYear:=(Y mod 4 = 0) and (Y mod 100 <> 0) or (Y mod 400 = 0);
end;
...
  case M of
    2: if IsLeapYear(Y) then CountDay:=29 else CountDay := 28;
...
  inc(D);
  if D>CountDay then begin
    D:=1; inc(M);
    if M>12 then begin
      M:=1; inc(Y);
    end;
  end;
  if D<10 then Write('0'); Write(D,'.');
  if M<10 then Write('0'); Write(M,'.');
  WriteLn(Y);

function IsLeapYear(y: Integer): Boolean;
begin
  IsLeapYear:=(Y mod 4 = 0) and (Y mod 100 <> 0) or (Y mod 400 = 0);
end;
function DaysInMonth(m, y: Integer): Integer;
begin
  case m of
  1, 3, 5, 7, 8, 10, 12:
    DaysInMonth:=31;
  4, 6, 9, 11:
    DaysInMonth:=30;
  2:
    DaysInMonth:=28 + Integer(IsLeapYear(y));
  end;
end;
var
  d, m, y: Integer;
begin
  repeat
    Write('Введите день месяц год: '); ReadLn(d, m, y);
    if (y > 1582) and (m in [1..12]) and (d in [1..DaysInMonth(m, y)]) then Break;
    WriteLn('*** Ошибочная дата, повторите ввод');
  until false;
  inc(d);
  if d > DaysInMonth(m, y) then begin
    d:=1; inc(m);
    if m>12 then begin
      m:=1; inc(y);
    end;
  end;
  Write('Следующая дата: ');
  if d<10 then Write(0); Write(d,'.');
  if m<10 then Write(0); Write(m,'.');
  WriteLn(y);
end.