Создание нескольких окон в PascalABC.Net

{$reference System.Windows.Forms.dll}
{$reference System.Drawing.dll}
{$apptype windows}
uses
  System.Windows.Forms, System.Drawing;
 
var
  graphForm, mainForm: Form;
  button: Button;
  draw_circle := false;
 
procedure OnPaint(sender: object; e: PaintEventArgs);
begin
  if draw_circle then
    e.Graphics.DrawEllipse(new Pen(Color.Red), new Rectangle(90, 90, 100, 100));
end;
 
procedure OnClick(sender: object; e: System.EventArgs);
begin
  draw_circle := not draw_circle;
  graphForm.Invalidate();
end;
 
begin
  mainForm := new Form();
  mainForm.Text := 'Main Form';
  mainForm.Size := new System.Drawing.Size(150, 200);
  mainForm.MinimizeBox := false;
  mainForm.MaximizeBox := false;
  mainForm.StartPosition := FormStartPosition.Manual;
  mainForm.Location := new System.Drawing.Point(200, 200);
  
  button := new System.Windows.Forms.Button();
  button.Location := new System.Drawing.Point(30, 10);
  button.Text := 'Draw Circle';
  button.Click += OnClick;
  mainForm.Controls.Add(button);
  
  graphForm := new Form();
  graphForm.Text := 'Graph Form';
  graphForm.Size := new System.Drawing.Size(300, 300);
  graphForm.StartPosition := FormStartPosition.Manual;
  graphForm.Location := new System.Drawing.Point(400, 200);
  graphForm.Paint += OnPaint;
  graphForm.Show();
  
  Application.EnableVisualStyles();
  Application.Run(mainForm);
end.

//Подключаем ссылки на библиотеки .NET, которые нам понадобятся
{$reference System.Windows.Forms.dll}
{$reference System.Drawing.dll}
//Приложение - оконное (не консольное, то бишь)
{$apptype windows}
 
uses
  System.Windows.Forms, System.Drawing;
 
var
  graphForm, mainForm: Form; //Две формы (два окна, грубо говоря)
  button: Button; //Кнопка
  draw_circle := false;
 
//Происходит при пере-/отрисовке графического окна
procedure OnPaint(sender: object; e: PaintEventArgs);
begin
  if draw_circle then
    //Рисуем в нашем графическом окне красной "ручкой" эллипс, который вписан в прямоугольник с координатой левого верхнего угла (90, 90)
    //(считая от ЛВ угла графического окна) и размером 100х100
    e.Graphics.DrawEllipse(new Pen(Color.Red), new Rectangle(90, 90, 100, 100));
end;
 
//Происходит при нажатии на кнопку
procedure OnClick(sender: object; e: System.EventArgs);
begin
  draw_circle := not draw_circle;
  graphForm.Invalidate(); //Перерисовываем граф окно
end;
 
begin
  mainForm := new Form(); //Создаем новый экземпляр класса Form
  mainForm.Text := 'Main Form'; //Текст формы(окна) (аналог Window.Caption в GraphABC)
  mainForm.Size := new System.Drawing.Size(150, 200); //Задаем размер окна
  mainForm.MinimizeBox := false; //Убираем кнопку "скрыть"
  mainForm.MaximizeBox := false; //Убираем кнопку "развернуть"
  mainForm.StartPosition := FormStartPosition.Manual; //Вручную задаем положение окна
  mainForm.Location := new System.Drawing.Point(200, 200); //Координаты ЛВ угла
  
  button := new System.Windows.Forms.Button(); //Создаем новую кнопку
  button.Location := new System.Drawing.Point(30, 10); //Тут понятно: задаем положение, отсчитывая от ЛВ угла формы, в которую мы поместим эту кнопку
  button.Text := 'Draw Circle'; //Текст на кнопке
  button.Click += OnClick; //Прописываем обработчик на событие клика
  mainForm.Controls.Add(button); //Добавляем кнопку на главную форму
  
  //Тут по аналогии с первой формой(окном)
  graphForm := new Form(); 
  graphForm.Text := 'Graph Form';
  graphForm.Size := new System.Drawing.Size(300, 300);
  graphForm.StartPosition := FormStartPosition.Manual;
  graphForm.Location := new System.Drawing.Point(400, 200);
  graphForm.Paint += OnPaint; //Обработчик на событие отрисовки
  graphForm.Show(); //Показываем (запускаем) форму
  
  Application.EnableVisualStyles(); //Это чтобы все было красивенько
  //Запускаем наше приложение, показывая главную форму и делая ее основной, т.е. при закрытии этой формы программа прекращает работу
  Application.Run(mainForm);  
end.