Пожалуйста напишите программу, которая добавляет запись в типизированый файл тип - запись

const
  fName = 'Program1.rec';
  
type
  tRec = record
    N : Integer;
  end;
 
function ReadNewRec : tRec;
begin
  Write(NewLine, 'Введите число для добавления новой записи: '); ReadLn(Result.N);
end;
  
procedure CreateNewFile;
var
  R : tRec;
  F : File of tRec;
begin
  R := ReadNewRec;
  Assign(F, fName);
  Rewrite(F);
  Write(F, R);
  Close(F);
  WriteLn('В новый файл добавлена запись ', R.N);
end;
 
procedure AppendFile;
var
  R : tRec;
  F : File of tRec;
  N : Integer;
begin
  R := ReadNewRec;
  Assign(F, fName);
  Reset(F);
  N := FileSize(F);
  Seek(F, N);
  Write(F, R);
  Close(F);
  WriteLn('В файл добавлена запись ', R.N);
end;
 
procedure ShowFile;
var
  R : tRec;
  F : File of tRec;
  N : Integer;
begin
  WriteLn('Вывод всех записей файла:');
  Assign(F, fName);
  Reset(F);
  N := 0;
  while Not EOF(F) do
    begin
      N += 1;
      Read(F, R);
      Write(' Запись № ', N, ' число = ', R.N, '  ');
    end;
  WriteLn;
  Close(F);
end;
 
procedure Sorted;
var
  K, i, p, l : Integer;
  R : array [1..1000] of tRec;
  F : File of tRec;
begin
  Assign(F, fName);
  Reset(F);
  K := 0;
  while Not EOF(F) do
    begin
      K += 1;
      Read(F, R[K]);
    end;
  Close(F);
  
  l := K - 1;
  repeat
    p := 0;
    for i := 1 to l do
      if R[i].N > R[i + 1].N then
        begin
          p := i;
          Swap(R[i].N, R[i + 1].N);
        end;
    l := p - 1;
  until p = 0;
        
  Rewrite(F);
  for i := 1 to K do
    Write(F, R[i]);
  Close(F);
  
  WriteLn('Файл отсортирован.');
end;
 
var
  S : String;
  DS : Set of Char;
begin
  WriteLn('Выполнение операций с записями и файлами записей.');
  if Not FileExists(fName) then
    begin
      WriteLn('  1. Создание файла записей');
      DS := ['1'];
    end
  else
    begin
      WriteLn('  1. Создание файла записей (приведёт к удалению существующего)');
      WriteLn('  2. Добавление записи в файл');
      WriteLn('  3. Просмотр записей из файла');
      WriteLn('  4. Сортировка записей в порядке неубывания');
      DS := ['1', '2', '3', '4'];
    end;
  WriteLn('Любой другой симовл - выход без действия.');
  Write('Введите номер действия: '); ReadLn(S);
  if (Length(S) > 0) and (S[1] in DS) then
    begin
      case S[1] of
        '1' : CreateNewFile;
        '2' : AppendFile;
        '3' : ShowFile;
        '4' : Sorted;
      end;
    end;
  WriteLn(NewLine, 'Программа завершена.');
end.