Найти определитель матрицы пользуясь, формулой разложения по первой строке

const max=10;
type matrix=array[1..max,1..max] of integer;
     index=array[1..max] of boolean;
var  a:matrix;
     rows,cols:Index;
     n,d:integer;
function FindTrue(var mas:index):integer;
var i:integer;
begin
for i:=1 to n do
if mas[i] then
 begin
  FindTrue:=i;
  exit;
 end;
FindTrue:=0; {признак ошибки: TRUE не найдено}
end;
function minor(var a:matrix; var rows,cols:index;k:integer):integer;
{Вычисление миноров для матрицы A;
rows[i]: истина, если i-ая строка содержится в миноре;
cols[j]: истина, если j-ый столбец содержится в миноре;
k:       порядок минора}
var i,j:integer;       {Номера строки и столбца}
     aa,sum,jo:integer;
begin
i:=FindTrue(rows);
if k=1 then
 begin
  j:=FindTrue(cols);
  minor:=a[i,j];
 end
else
 begin
  rows[i]:=false; {из rows вычеркнуть строку с номером i и...}
  dec(k);  {n уменьшить на 1 для всех миноров следующего порядка}
  sum:=0; {инициализация накопителя суммы}
  jo:=1;  {первое произведение со знаком +}
  for j:=1 to n do
  {Найдя j-й элемент минора }
  if cols[j] then
   begin
   {Вычисление элемента разложения минора }
   {для этого сначала подготовить аргумента функции minor:}
   {из cols вычеркнуть столбец с номером j}
    cols[j]:=false;
    aa:=A[i,j];     {если A[i,j] = 0, то }
    if aa<>0 then   {не надо считать его minor }
    sum:=sum+jo*aa*minor(a,rows,cols,k);
    {восстановить столбец j для следующего минора}
    cols[j]:=true;
    jo:=-jo;   {для следующего произведения}
   end;
  minor:=sum;
  rows[i]:=true; {восстановить состояние массива rows}
 end;
end;
 
function det(var a:matrix):integer;
{Вычисление определителя матрицы A порядка n}
var i:integer;
begin
for i:=1 to n do
 begin
  rows[i]:=true; {Все строки}
  cols[i]:=true; {и столбцы матрицы}
 end;               {входят в ее определитель}
det:=minor(a,rows,cols,n);
end;
var i,j:integer;
begin
repeat
write('Размер матрицы от 2 до ',max,' n=');
readln(n);
until n in [2..max];
for i:=1 to n do
 begin
  for j:=1 to n do
   begin
    a[i,j]:=-5+random(11);
    write(a[i,j]:4);
   end;
  writeln;
 end;
{Вычисление определителя}
d := det(A);
writeLn('Значение определителя=',d);
end.

repeat
write('Размер матрицы от 2 до ',max,' n=');
readln(n);
until n in [2..max];
writeln('Введите элементы матрицы целые числа');
for i:=1 to n do
for j:=1 to n do
 begin
  write('a[',i,',',j,']=');
  readln(a[i,j]);
 end;
writeln('Матрица');
for i:=1 to n do
 begin
  for j:=1 to n do
  write(a[i,j]:4);
  writeln;
 end;