Множество Жюлиа

@valerianka · Регистрация: 07.02.2017

Студворк — интернет-сервис помощи студентам

Что именно нужно исправить в данном коде, чтобы он заработал на PascalABC.NET? (Множество Жюлиа для функции z²+c)

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
program J2; 
uses Graph, Crt; 
type
TComplex = record
X : Real;
Y : Real;
    end;
    
const
    iter = 50;
    max  = 16;
    
var
    z, t, c : TComplex;
    x, y, n : Integer;
    Cancel  : Boolean;
    gd, gm  : Integer;
    mx, my  : Integer;
    
begin
    Cancel := false;
    Randomize;
    gd := Detect;
    InitGraph(gd,gm,'c:\bp\bgi');
    Mx := GetMaxX div 2;
    My := GetMaxY div 2;
    for y := -my to my do
        for x := -mx to mx do 
        begin
            n := 0;
            z.x := x * 0.005;
            z.y := y * 0.005;
            c.x := 0.11;
            c.y := -0.66;
            while (sqr(z.x) + sqr(z.y) < max) and (n < iter) do 
            begin
                t := z;
                {z^2 + c}
                z.x := sqr(t.x) - sqr(t.y) + c.x;
                z.y := 2*t.x*t.y + c.y;
                Inc(n);
                if keypressed then 
                    cancel := true;
            end;
            if n < iter then 
            begin
                PutPixel(mx + x,my + y,16 - (n mod 16));
            end;
            if cancel then 
                exit;
        end;
    Readkey;
    CloseGraph;
end.

@Puporev · 07.02.2017, 15:45

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
uses GraphABC; 
type TComplex = record
                X,Y : Real;
                end;
const iter = 50;
       max  = 16;
var z, t, c : TComplex;
    x, y, n : Integer;
    mx, my  : Integer;
begin
Randomize;
Mx := windowwidth div 2;
My := windowheight div 2;
for y := -my to my do
for x := -mx to mx do 
 begin
  n := 0;
  z.x := x * 0.005;
  z.y := y * 0.005;
  c.x := 0.11;
  c.y := -0.66;
  while (sqr(z.x) + sqr(z.y) < max) and (n < iter) do 
   begin
    t := z;
    z.x := sqr(t.x) - sqr(t.y) + c.x;
    z.y := 2*t.x*t.y + c.y;
    Inc(n);
   end;
   //цвета подбирайте какие нравятся 
   if n < iter then SetPixel(mx + x,my + y,clBlack)
   else SetPixel(mx + x,my + y,RGB(10*(16 - n mod 16),60*(16 - n mod 16),140*(16 - n mod 16)));
  end;
 end.

Добавлено через 41 минуту
Чтобы цветное было, сделать так.

Pascal
1
if n < iter then  SetPixel(mx + x,my + y,RGB(10*(16 - n mod 16),60*(16 - n mod 16),140*(16 - n mod 16)));

Добавлено через 1 минуту
Числа 10, 60, 140 можно менять по вкусу.

@valerianka · 07.02.2017, 16:52 **[ТС]**

А если вместо +с, к примеру, -2 (т.е. z²-2)?

@Puporev · 07.02.2017, 17:03

Точно не знаю, с-комплексное число, в данном примере=0.11-0.66*i, вероятно можно написать c.x=2; c.y=0;

@volvo · 07.02.2017, 19:14

Сообщение от valerianka

А если вместо +с, к примеру, -2 (т.е. z²-2)?

Это не даст картинку, останется линия в центре черного квадрата.

Вот вариант с использованием встроенного в PascalABC.NET типа Complex:

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
uses GraphABC; 
const
  iter = 50;
  max = 16;
 
var
  z: Complex;
  c: Complex := (0.11, -0.66); // (-2, 0) для Z^2 - 2
  n, mx, my: Integer;
 
begin
  Randomize;
  Mx := windowwidth div 2;
  My := windowheight div 2;
  for var y := -my to my do
    for var x := -mx to mx do 
    begin
      n := 0;
      z := (x * 0.005, y * 0.005);
      while (z.Magnitude < max) and (n < iter) do 
      begin
        z := z * z + c;
        Inc(n);
      end;
      if n < iter then SetPixel(mx + x, my + y, clBlack)
      else SetPixel(mx + x, my + y, RGB(10 * (16 - n mod 16), 60 * (16 - n mod 16), 140 * (16 - n mod 16)));
    end;
end.

Новые блоги и статьи Все статьи Все блоги /
SDL3 для Web (WebAssembly): Реализация движения на Box2D v3 - трение и коллизии с повёрнутыми стенами 8Observer8 20.02.2026 Содержание блога Box2D позволяет легко создать главного героя, который не проходит сквозь стены и перемещается с заданным трением о препятствия, которые можно располагать под углом, как верхнее. . .	Конвертировать закладки radiotray-ng в m3u-плейлист damix 19.02.2026 Это можно сделать скриптом для PowerShell. Использование . \СonvertRadiotrayToM3U. ps1 <path_to_bookmarks. json> Рядом с файлом bookmarks. json появится файл bookmarks. m3u с результатом. # Check if. . .	Семь CDC на одном интерфейсе: 5 U[S]ARTов, 1 CAN и 1 SSI Eddy_Em 18.02.2026 Постепенно допиливаю свою "многоинтерфейсную плату". Выглядит вот так: https:/ / www. cyberforum. ru/ blog_attachment. php?attachmentid=11617&stc=1&d=1771445347 Основана на STM32F303RBT6. На борту пять. . .	Камера Toupcam IUA500KMA Eddy_Em 12.02.2026 Т. к. у всяких "хикроботов" слишком уж мелкий пиксель, для подсмотра в ESPriF они вообще плохо годятся: уже 14 величину можно рассмотреть еле-еле лишь на экспозициях под 3 секунды (а то и больше),. . .
И ясному Солнцу zbw 12.02.2026 И ясному Солнцу, и светлой Луне. В мире покоя нет и люди не могут жить в тишине. А жить им немного лет.	«Знание-Сила» zbw 12.02.2026 «Знание-Сила» «Время-Деньги» «Деньги -Пуля»	SDL3 для Web (WebAssembly): Подключение Box2D v3, физика и отрисовка коллайдеров 8Observer8 12.02.2026 Содержание блога Box2D - это библиотека для 2D физики для анимаций и игр. С её помощью можно определять были ли коллизии между конкретными объектами и вызывать обработчики событий столкновения. . . .	SDL3 для Web (WebAssembly): Загрузка PNG с прозрачным фоном с помощью SDL_LoadPNG (без SDL3_image) 8Observer8 11.02.2026 Содержание блога Библиотека SDL3 содержит встроенные инструменты для базовой работы с изображениями - без использования библиотеки SDL3_image. Пошагово создадим проект для загрузки изображения. . .

Множество Жюлиа

Решение

Решение

@valerianka 2 / 2 / 2 Регистрация: 07.02.2017 Сообщений: 7
	07.02.2017, 16:52 [ТС]
	А если вместо +с, к примеру, -2 (т.е. z²-2)? 0

@Puporev Почетный модератор 64315 / 47611 / 32743 Регистрация: 18.05.2008 Сообщений: 115,167
	07.02.2017, 17:03
	Точно не знаю, с-комплексное число, в данном примере=0.11-0.66*i, вероятно можно написать c.x=2; c.y=0; 2