Движение шариков

uses GraphABC;
type tSharik=record {объявим тип запись - шарик, с полями}
             radius: integer;{радиус шара}
             cvet: Color;{цвет}
             dlina: integer;{длина шнура}
             koord_x: integer;{координата х точки подвеса}
             ugol: real;{угол от вертикальной оси}
             naprav: integer;{}
             x,y: integer;{текущие координаты центра шарика}
            end;
const Skorost=5;{константа, регулирующая скорость колебаний, можно поменять,
                 или вообще задавать самому}
var n:integer;{кол. шариков}
    shariki:array of tSharik;{массив шариков}
 
//процедура рисования шарика с нитью,
procedure Narisovat(sharik:tSharik);
var c:Color;
begin
c:=sharik.cvet;
setpencolor(clBlue);//цвет нити
line(sharik.koord_x, 0, sharik.x, sharik.y);//нить - линия
setpencolor(c);//цвет шарика
setbrushcolor(c);
circle(sharik.x, sharik.y,sharik.radius);//закрашенный круг
end;
 
//процедура смещения - колебания шарика
procedure Dvigat(var sharik:tSharik);
var rasst: real;
       j: integer;
begin
with sharik do//пока 1 шарик
 begin
  ugol:= ugol+naprav*skorost/dlina;//вычисляем угол
  //вычисляем текущие координаты центра
  x:= round( koord_x + (dlina+radius) * sin(ugol) );
  y:= round( (dlina+radius) * cos(ugol) );
  //определяем положение шарика по вертикали
  if y<=radius then naprav:=-naprav;//если коснулись верхней границы экрана(она одна для всех
                                     //шариков), меняем направление на обратное
  for j:=0 to n-1 do//перебираем все шарики
   begin
   //определяем расстояние шарика до всех других, переменные типа integer приводим к типу Longint,
   //  иначе квадраты координат выйдут за объявленный тип
    rasst:=sqrt(sqr(longint(shariki[j].x)-longint(x))+sqr(longint(shariki[j].y)-longint(y)) );
    if (rasst<= radius+shariki[j].radius) and (rasst>radius/2) then//если коснулись
     begin
      if x<shariki[j].x then naprav:=-1 else naprav:=+1;//шарик слева, направление -1, справа +1
      shariki[j].naprav:= -naprav;//меняем направление после соприкосновения
     end;
   end;
 end;
end;
 
 
var i:integer;
begin
write('Количество шариков n=');
readln(n);
setlength(shariki,n);
randomize;{генератор случайных чисел}
for i:=0 to n-1 do{по количеству шаров}
 begin
  with shariki[i] do//задаем параметры очередного шарика
   begin
    radius:= 10+random(25);//радиус
    dlina:= 50+random(150);//длина нити
    koord_x:=(windowwidth div (n+1)) * i;//точка крепления нити у верхней шраницы экрана
    cvet:= clrandom;//цвет
    ugol:=0;//начальный угол с вертикальной осью
    naprav:=1;//напрвление вправо
   end;
 end;
lockdrawing; 
repeat//собственно цикл рисования колеблющихся шариков
clearwindow;
for i:=0 to n-1 do//все шарики
Narisovat(shariki[i]);{рисуем цветом фона - стираем}
sleep(100);
for i:=0 to n-1 do
Dvigat(shariki[i]);{меняем положение}
redraw;
until false;{нажатие любой клавиши - выход из программы}
end.