Игра на реакцию

uses GraphABC, Timers;
 
const
  maxCount = 30;
  
var
  clFone := rgb(0,65,100);
 
///---------- Предописание процедур -------------------------------------------- 
 
procedure theEnd := Window.Close;
procedure SelectMain(X, Y, M : Integer); forward;
procedure MainMenu; forward;
procedure Live; forward;
 
///---------- Часть программы, в которой реализована игра ---------------------- 
 
type
  tTroll = record
    x, y, r : Integer;
    enabled : Boolean;
    notKilled : Boolean;
    
    constructor := NewTroll;
    
    procedure NewTroll;
    begin
      x := 10 + Random(Window.Width-20); y := 10 + Random(Window.Height-20);
      r := 5; enabled := True; notKilled := True;
    end;
 
    procedure Show(clr : Color);
    begin
      Pen.Style := psSolid;
      Pen.Color := clFone;
      Brush.Color := clr;
      Circle(x, y, r);
    end;
    
    procedure Kill;
    begin
      notKilled := False;
    end;
  end;
 
type
  tTrolles = class
    T : array of tTroll;
    count, living : Integer;
    
    constructor;
    begin
      count := 0;
      living := 0;
      SetLength(T, 0);
    end;
    
    procedure CreateNew;
    begin
      living += 1;
      for var i := 0 to count-1 do
        if Not T[i].enabled then
          begin
            T[i].NewTroll;
            Exit;
          end;
          
      count += 1;
      SetLength(T, count);
      T[count-1] := New tTroll;
    end;
    
    procedure Live;
    begin
      Window.Clear(rgb(32,64,32));
      for var i := count-1 downto 0 do
        if T[i].enabled then
          if T[i].notKilled then
            begin
              if T[i].r < 100 then T[i].r += 1;
              T[i].Show(rgb(128,128,128));
            end
          else
            begin
              T[i].r -= 5;
              if T[i].r > 0 then
                T[i].Show(rgb(64,32,32))
              else
                begin
                  T[i].enabled := False;
                  living -= 1;
                end;
            end;
    end;
    
    function Click(X, Y : Integer) : Boolean;
    begin
      Result := True;
      for var i := 0 to count-1 do
        if (X-T[i].x)*(X-T[i].x)+(Y-T[i].y)*(Y-T[i].y) < T[i].r*T[i].r then
          begin
            T[i].Kill;
            Exit;
          end;
      Result := False;
    end;
 
  end;
 
var Trolles : tTrolles;
var Timer := New Timer(25, Live);
var Lost := False;
var Swat := 0;
 
procedure Live;
begin
  LockDrawing;
  Window.Caption := 'Троллей: ' + Trolles.living + '   Прихлопнуто: ' + swat;
  Window.Clear(rgb(32,64,32));
  if Trolles.living = 0 then
    Trolles.CreateNew
  else if Trolles.living = maxCount then
    begin
      Timer.Stop;
      Lost := True;
      MainMenu;
    end
  else
    begin
      if Random(10) = 0 then Trolles.CreateNew;
      Trolles.Live;
    end;
  UnlockDrawing;
end;
 
procedure GameSelect(X, Y, M : Integer);
begin
  if Trolles.Click(X, Y) then Swat += 1;
end;
 
procedure Game;
begin
  Swat := 0;
  OnMouseDown := GameSelect;
  Window.Clear(clBlack);
  Trolles := New tTrolles;
  Timer.Start;
end;
 
///---------- Часть программы, в которой реализовано меню ----------------------
 
type
  tMenu = record
    x, y, w, h : Integer;
    inf : String;
    Action : procedure;
  end;
 
const
  aMainMenu : array of tMenu = (
    (x : 250; y : 100; w : 100; h : 30; inf : 'Игра' ; Action : Game  ),
    (x : 250; y : 140; w : 100; h : 30; inf : 'Выход'; Action : theEnd)
  );
 
procedure Show(a : tMenu);
begin
  if Lost then
    begin
      Font.Color := rgb(255,200,145);
      Font.Size := 16;
      DrawTextCentered(Window.Center.X,20,Window.Center.X,20,'Вы проиграли!');
      Font.Size := 15;
      DrawTextCentered(Window.Center.X,40,Window.Center.X,40,'Троллей прихлопнуто ' + Swat);
    end;
  
  Pen.Color   := rgb(0,0,128);
  Brush.Color := rgb(32,32,128);
  Font.Color  := rgb(255,255,0);
  Font.Name   := 'Times New Roman';
  Font.Style  := fsBold;
  Font.Size   := 14;
  Rectangle(a.x, a.y, a.x + a.w, a.y + a.h);
  DrawTextCentered(a.x, a.y, a.x + a.w, a.y + a.h, a.inf);
end;
 
procedure MainMenu;
begin
  OnMouseDown := SelectMain;
  Window.Clear(clFone);
  foreach var item in aMainMenu do Show(item);
end;
 
procedure SelectMain(X, Y, M : Integer);
begin
  foreach var item in aMainMenu do
    if (X > item.x) and (X < item.x + item.w) and (Y > item.y) and (Y < item.y + item.h) then
      item.Action;
end;
 
///---------- Основная программа ----------------------------------------------- 
begin
  Randomize;
  Window.Width := 600;
  Window.Height := 300;
  Window.CenterOnScreen;
  MainMenu;
end.