Кольцевой односвязный список, удаление списка

type
PUzel = ^S;
 
 S = record
 x: real;
 next: PUzel;
 end;
 
 var head: PUzel; n: integer;
 
 {вставка узла p в голову f}
 procedure AddFirst(var f, p: PUzel);
 begin
  p^.next := f;
  f := p;
 end;
 
 {добавление элементов списка}
 procedure AddAfter(var old: PUzel; a: PUzel);
 begin
  a^.next := old^.next;
  old^.next := a;
 end;
 
 {создание списка кольцевого}
 procedure BuildSpisok(var f: PUzel; var n: integer);
  var a, d: PUzel;
  i: integer; y: real;
 begin
  f := nil;
  write('введите n ');
  readln(n);
  for i := 1 to n do 
   begin
   new(a);   
   write('введите число ');
    readln(y);
    a^.x := y;
    if (f = nil) then 
    begin
    AddFirst(f, a); d := f;
    end else
    begin
    AddAfter(d, a); d := a;
    end;
   end;
   d^.next := f;
 end;
 
 {выделение первого эл-та из списка}
 procedure DelFirstElement(var f, a: PUzel);
 begin
  a := f; {получили указатель на выделяемый узел}
  f := f^.next;
  a^.next := nil;
 end;
 
 {удаление списка}
 procedure DelSpisok(var f: PUzel);
  var a: PUzel;
   begin
    while (f^.next <> nil) do
     begin
      DelFirstElement(f, a);
      dispose(a);
     end;
   end;
 
 begin
  BuildSpisok(head, n);
  DelSpisok(head);
 end.

type
  PUzel = ^S;
  S = record
    x: real;
    next: PUzel;
  end;
 
{создание списка кольцевого}
procedure BuildSpisok(var First : PUzel);
var
  n, i : Integer;
  Cur : PUzel;
begin
  Write('Введите n = '); ReadLn(n);
  New(Cur); Write('Введите число: '); ReadLn(Cur^.x); First := Cur; // Первый
  for i := 2 to n do // Остальные начиная со второго
    begin
      New(Cur^.next); Cur := Cur^.next; Write('Введите число: '); ReadLn(Cur^.x);
    end;
  Cur^.next := First; // Закольцевать
end;
 
{удаление списка}
procedure DelSpisok(var cur : PUzel);
var
  tmp : PUzel;
begin
  tmp := cur; cur := cur^.next; tmp^.next := nil; // Разорвём кольцо
  while cur <> nil do // Очистим как однонаправленный список
    begin
      tmp := cur; cur := cur^.next; dispose(tmp);
    end;
end;
 
procedure Show(head : PUzel);
var
  Cur : PUzel;
begin
  if head = nil then
    WriteLn('Список пуст!')
  else
    begin
      Cur := head;
      repeat
        Write(Cur^.x:7:2); Cur := Cur^.next;
      until Cur = head;
      WriteLn;
    end;
end;
 
var
  head: PUzel;
begin
  BuildSpisok(head);
  Show(head);
  DelSpisok(head);
  Show(head);
end.