Как перевести изображение в массив строк

{$reference System.Drawing.dll}
uses System;
uses System.Drawing;
uses System.Drawing.Imaging;
 
type
  Pixel = record
    val: integer;
  end;
 
function PixelAt(ptr: IntPtr): Pixel;
begin
  var p: ^Pixel := pointer(ptr);
  Result := p^;
end;
 
function AddPixel(x,y,w,h: integer; ptr: IntPtr; stride: integer; find: Pixel; skip, checked, add: HashSet<Point>): boolean;
begin
  if x<0 then exit;
  if y<0 then exit;
  if x>=w then exit;
  if y>=h then exit;
  var p := new Point(x,y);
  if skip.Contains(p) then exit;
  if not checked.Add(p) then exit;
  Result := (PixelAt(ptr + y*stride + x*4) = find) and add.Add(p);
end;
 
begin
  var b := new Bitmap('0.bmp');
  var (x,y) := ReadInteger2('x и y через пробел:');
  var (w,h) := (b.Width,b.Height);
  
  var bd := b.LockBits(new Rectangle(0,0,w,h), ImageLockMode.ReadOnly, PixelFormat.Format32bppArgb);
  
  // Координаты пикселей, которые прошли на предыдущей (перед последней) итерации
  // Надо чтоб не идти назад, в сторону проверенных раньше пикселей
  var PrevPts := new HashSet<Point>;
  
  // Координаты пикселей, которые прошли на последней итерации
  // Новые пиксели смотрит только среди прямо прилежащим к этим
  var LastPts := new HashSet<Point>;
  LastPts += new Point(x,y);
  
  var find := PixelAt(bd.Scan0 + y*bd.Stride + x*4);
  var count := 1;
  
  while LastPts.Count<>0 do
  begin
    // Координаты пикселей, проверенных на данной итерации
    // Надо чтоб 1 и тот же пиксель не проверять 2 раза
    var Checked := new HashSet<Point>;
    // Координаты пикселей, которые были добавлены на данной итерации
    var NewPts := new HashSet<Point>;
    
    foreach var p in LastPts do
    begin
      if AddPixel(p.X-1,p.Y, w,h, bd.Scan0,bd.Stride, find, PrevPts,Checked,NewPts) then count += 1;
      if AddPixel(p.X,p.Y-1, w,h, bd.Scan0,bd.Stride, find, PrevPts,Checked,NewPts) then count += 1;
      if AddPixel(p.X+1,p.Y, w,h, bd.Scan0,bd.Stride, find, PrevPts,Checked,NewPts) then count += 1;
      if AddPixel(p.X,p.Y+1, w,h, bd.Scan0,bd.Stride, find, PrevPts,Checked,NewPts) then count += 1;
    end;
    
    PrevPts := LastPts;
    LastPts := NewPts;
  end;
  
  b.UnlockBits(bd);
  count.Println;
end.