Ошибка в сортировке массива по алфавиту

Program books;
type note = record //Набор сведений о книгах
     author, title: string[20];  //фамилия автора, название книги
     year, price: integer; //год издания, цена
end;
const n=5;
var F: file of note;
    note0, note1, note2, note3, note4: note;
    notes: array[0..n] of note;
    i: integer;
    year1:1000..2050;
    min:string;
procedure sort(F:file of note);
var i, j, ind: integer;
    k: string;
begin
  for i:=0 to n-1 do begin // i указывает на 1 позицию
    for j:=i+1 to n do begin // j указывает на 2 позицию
     if notes[j].author<min then  // если j меньше минимума
        begin
        min:=notes[j].author; // присваиваем минимум
        ind:=j;      // запоминаем позицию
        end;
     end;
    if notes[i].author>min then begin // если i больше мин то мы меняем местами
       k:=notes[i].author;
       notes[i].author:=notes[ind].author; // возвращаем на позицию arr ind
       notes[ind].author:=k;
    end;
  end;
end;
begin
//Создание типизированного файла kat.dat
   Assign(F,'kat.dat'); //установка связи между переменной F и файлом kat.dat
   Rewrite(F); //создание и открытие файла F для записи
   //создание переменных
   note0.Author:='Чехов';  //заполнение поля "автор"
   note0.Year:=2018;   //заполнение поля "год"
   note0.Price:=900;   //заполнение поля "цена"
   note0.Title:='Вишнёвый сад'; //заполнение поля "название"
   note1.Author:='Пушкин';
   note1.Year:=2018;
   note1.Price:=850;
   note1.Title:='Борис Годунов';
   note2.Author:='Островский';
   note2.Year:=2016;
   note2.Price:=570;
   note2.Title:='Бесприданница';
   note3.Author:='Тургенев';
   note3.Year:=2016;
   note3.Price:=180;
   note3.Title:='Отцы и дети';
   note4.Author:='Гончаров';
   note4.Year:=2018;
   note4.Price:=800;
   note4.Title:='Обломов';
   //запись созданных переменных в компоненты файла
   Write(F, note0);
   Write(F, note1);
   Write(F, note2);
   Write(F, note3);
   Write(F, note4);
   Close(F); //закрытие файла
//конец создания типизированного файла kat.dat
begin
   assign(F, 'kat.dat'); //установка связи между переменной F и файлом kat.dat
   reset(F); //открытие файла
   writeln('Введите запрашиваемый год издания ');
   readln(year1);
   //вывод исходных данных в виде таблицы
   writeln('Список книг ',year1,' года издания'); //вывод на экран поясняющей надписи
   writeln('---------------------------------------------------');
   writeln('|    АВТОР   |      НАЗВАНИЕ     |   ГОД   |  ЦЕНА |'); //вывод заголовка таблицы
   writeln('---------------------------------------------------');
   for i:=1 to n do begin //начало цикла для вывода файла
    Read(F, notes[i]); //считывание компоненты файла
    //вывод на экран
    begin
      if (notes[i].Year=year1) then begin
        sort(F);
        write('|',notes[i].Author:10,'  | ',notes[i].Title:17,' |  ',notes[i].Year:3,'   |',notes[i].Price:7,'|');
        writeln();
        writeln('---------------------------------------------------');
      end; //конец цикла для вывода файла
      {else begin
        writeln('Книги за ',year1, ' год не найдены');
        readln;
      end;}
    end;
   end;
   Close(F);
end;
end.

const n=5;
type note = record //Набор сведений о книгах
            author, title: string[20];  //фамилия автора, название книги
            year, price: integer; //год издания, цена
            end;
mas=array[1..n] of note;
 
procedure sort(var notes:mas;m:integer);
var x:note;
begin
for var i:=1 to m-1 do
for var j:=i+1 to m do 
if notes[i].author>notes[j].author then  // если j меньше минимума
 begin
  x:=notes[i];
  notes[i]:=notes[j];
  notes[j]:=x;
 end;
end;
var F: file of note;
    x:note;
    notes:mas;
    year:1900..2020;
    m:integer;
begin
//Создание типизированного файла kat.dat
assign(F,'kat.dat'); //установка связи между переменной F и файлом kat.dat
rewrite(F); //создание и открытие файла F для записи
//создание переменных
x.Author:='Чехов';  //заполнение поля "автор"
x.Year:=2018;   //заполнение поля "год"
x.Price:=900;   //заполнение поля "цена"
x.Title:='Вишнёвый сад'; //заполнение поля "название"
write(F,x);
x.Author:='Пушкин';
x.Year:=2018;
x.Price:=850;
x.Title:='Борис Годунов';
write(F,x);
x.Author:='Островский';
x.Year:=2016;
x.Price:=570;
x.Title:='Бесприданница';
write(F,x);
x.Author:='Тургенев';
x.Year:=2016;
x.Price:=180;
x.Title:='Отцы и дети';
write(F,x);
x.Author:='Гончаров';
x.Year:=2018;
x.Price:=800;
x.Title:='Обломов';
write(F,x);
//конец создания типизированного файла kat.dat
reset(F); //открытие файла
repeat
writeln('Введите запрашиваемый год издания от 1000 до 2050');
readln(year);
until(year>=1000)and(year<=2020);
//поиск данных по запросу
m:=0;
while not eof(F)do
 begin
  read(F,x);
  if x.year=year then
   begin
    inc(m);
    notes[m]:=x;
   end;
 end;
close(F);
if m=0 then writeln('Книги за ',year, ' год не найдены')
else
 begin
  if m>1 then sort(notes,m);  
 //вывод найденных книг в виде таблицы
  writeln('Список книг ',year,' года издания'); //вывод на экран поясняющей надписи
  writeln('----------------------------------------------------');
  writeln('|    АВТОР   |      НАЗВАНИЕ     |   ГОД   |  ЦЕНА |'); //вывод заголовка таблицы
  writeln('----------------------------------------------------');
  for var i:=1 to m do  //начало цикла для вывода файла
   begin
    write('|',notes[i].Author:12,'|',notes[i].Title:19,'|',notes[i].Year:9,'|',notes[i].Price:7,'|');
    writeln;
    writeln('---------------------------------------------------');
   end; 
 end; //конец цикла для вывода файла
  
end.

const
  fname = 'kat.dat';
  
type
  note = record //Набор сведений о книгах
    author, title: string[20];  //фамилия автора, название книги
    year, price: integer; //год издания, цена
  end;
 
procedure CreateFile;
begin
   var F : file of note;
   Rewrite(F, fname);
   
   var n : note;
   n.Author := 'Чехов'     ; n.Year := 2018; n.Price := 900; n.Title := 'Вишнёвый сад' ; f.Write(n);
   n.Author := 'Пушкин'    ; n.Year := 2018; n.Price := 850; n.Title := 'Борис Годунов'; f.Write(n);
   n.Author := 'Островский'; n.Year := 2016; n.Price := 570; n.Title := 'Бесприданница'; f.Write(n);
   n.Author := 'Тургенев'  ; n.Year := 2016; n.Price := 180; n.Title := 'Отцы и дети'  ; f.Write(n);
   n.Author := 'Гончаров'  ; n.Year := 2018; n.Price := 800; n.Title := 'Обломов'      ; f.Write(n);
   
   f.Close;
end;
 
function ReadFile : array of note;
begin
  var f : file of note;
  Reset(f, fname);
  SetLength(Result, f.Size);
  for var i := 0 to f.Size-1 do
    Result[i] := f.Read;
  f.close;
end;
  
begin
  CreateFile;
  
  var a := ReadFile;
  
  var year := ReadLnInteger('Введите запрашиваемый год издания:');
  var t := a.where(x->x.year = year);
  if t.count = 0 then
    $'Нет книг издания {year} года.'.Println
  else
    begin
      var u := t.OrderBy(x->string(x.author));
      $'Список книг {year} года издания'.Println;
      ('-'*50).Println;
      '|    АВТОР   |      НАЗВАНИЕ     |  ГОД  |  ЦЕНА |'.Println;
      ('-'*50).Println;
      foreach var x in u do
        $'| {x.author,-10} | {x.title,-17} | {x.year,4}  | {x.price,5} |'.Println;
    end;
end.