Работа с векторами

uses GraphABC;
const 
  Eps: real = 1e-6;
  Scale: real = 10;
  
type
  TPoint2d = record
  private
    x, y: real;
  public
    constructor Create(x, y: real);
    begin self.x := x; self.y := y; end;
    
    function ToString: string; override;
    begin Result := Format('<{0:F2}, {1:F2}>', x, y) end;
    
    static function operator+(a, b: TPoint2d): TPoint2d;
    begin Result := TPoint2d.Create(a.x + b.x, a.y + b.y) end;
    
    static function operator-(a, b: TPoint2d): TPoint2d;
    begin Result := TPoint2d.Create(a.x - b.x, a.y - b.y) end;
    
    static function operator*(a: real; b: TPoint2d): TPoint2d;
    begin Result := TPoint2d.Create(a * b.x, a * b.y) end;
  end;
  
  TPoint = TPoint2d;
  
  TVector = record
  private
    f1, f2: TPoint;
  public
    constructor Create(f1, f2: TPoint);
    begin self.f1 := f1; self.f2 := f2; end;
    
    property PointStart: TPoint read f1;
    property PointEnd: TPoint read f2;
    
    function ToString: string; override;
    begin Result := Format('{0} -> {1}', f1, f2) end;
    
    static function operator+(a, b: TVector): TVector;
    begin Result := TVector.Create(a.f1, a.f2 + b.f2 - b.f1) end;
    
    static function operator-(a, b: TVector): TVector;
    begin Result := TVector.Create(a.f2 + b.f2 - b.f1, a.f1) end;
    
    static function operator*(a: real; b: TVector): TVector;
    begin Result := TVector.Create(b.f1, b.f1 + a * (b.f2 - b.f1)) end;
    
    /// Параллельный перенос
    function Transport(a: TVector): TVector;
    begin Result := TVector.Create(f1 + a.f2 - a.f1, f2 + a.f2 - a.f1) end;
    
  end;
  
  /// Поворот
  function Rotate2f(self: TVector; a: real): TVector; extensionmethod;
  begin 
    var v := self.f2 - self.f1;
    var w := a + System.Math.Atan2(v.y, v.x);
    var r := sqrt(sqr(v.x) + sqr(v.y));
    Result := TVector.Create(self.f1, TPoint2d.Create(
      self.f1.x + r * Cos(w),
      self.f1.y + r * Sin(w)));
  end;
  
  procedure Show(v: TVector; caption: string);
  begin
    var p := v.PointEnd - v.PointStart;
    var w := System.Math.Atan2(p.y, p.x);
    var l := sqrt(sqr(p.x) + sqr(p.y));
    var g := GraphBufferGraphics;
    var s := g.Save();
    var font := System.Drawing.Font.Create('arial', 0.4);
    var brush := System.Drawing.SolidBrush.Create(clRed);
    var pen := System.Drawing.Pen.Create(Pen.Color, 0.4);
    pen.StartCap := System.Drawing.Drawing2D.LineCap.RoundAnchor;
    pen.EndCap := System.Drawing.Drawing2D.LineCap.ArrowAnchor;
    g.TranslateTransform(v.PointStart.x, v.PointStart.y);
    g.RotateTransform(w*180/pi);
    g.DrawLine(pen, 0, 0, l, 0);
    if (w > pi/2) or (w < -pi/2) then begin
      g.RotateTransform(-180);
      g.TranslateTransform(-l, 0);
    end;
    var m := g.MeasureString(caption, font);
    g.TranslateTransform((l-m.Width)/2, -m.Height/2);
    g.DrawString(caption, font, brush, 0, 0);
    g.Restore(s);
  end;
  
begin
  var a := TVector.Create(TPoint.Create(1, 1), TPoint.Create(4, 2));
  var b := TVector.Create(TPoint.Create(10, 10), TPoint.Create(11,9));
  var c := TVector.Create(TPoint.Create(1, 5), TPoint.Create(4,6));
  
  LockDrawing;
  Coordinate.SetOrigin(WindowWidth div 5, WindowHeight div 5);
  Coordinate.SetScale(30);
  Show(a, 'a');
  Show(b, 'b');
  Show(3*c, '3c');
  Show(c, 'c');
  Show(a+b, 'a+b');
  Show(b+a, 'b+a');
  Show(c.Transport(b), 'c ~ b');
  Show(c.Rotate2f(Pi/4), 'c + 45°');
  Redraw;
end.