Графика Паскаль

uses GraphABC;
const
  op = 200;          // степень непрозрачности цветных лепестков, 0..255
  rot = 10 * Pi/180; // поворот цветка: rot>0 по часовой стрелке, rot<0 против часовой
  zoom = 1.2;        // коэфф. растяжения лепестков для их "распускания"
var 
  a, b, h, alpha: real;
  color := |ARGB(op,50,50,133), ARGB(op,0,0,255),    ARGB(op,0,160,227), ARGB(op,0,255,0), 
            ARGB(op,255,255,0), ARGB(op,239,127,26), ARGB(op,255,0,0)|;
 
procedure DrawFlower(rot: real);
begin
  var (Ox, Oy) := (window.Center.X, window.Center.Y);
  var beta := 2*Pi/7-alpha; // угол между соседними лепестками
  var Angles := PartitionPoints(alpha-rot,2*Pi-beta-rot,6);
  foreach var w in Angles index i do
    begin
      var (Ax, Ay) := (Round(Ox+b*cos(w)), Round(Oy-b*sin(w)));
      var (Bx, By) := (Round(Ox+b*cos(w+alpha)), Round(Oy-b*sin(w+alpha)));
      SetBrushColor(color[i]);
      Polygon((Ox,Oy),(Ax, Ay),(Bx, By));
      Sleep(100); // задержка для "анимации" отрисовки лепестков
    end;
end;
 
begin
  window.Caption := 'Геометрический семицветик';
  window.SetSize(800, 750);
  window.CenterOnScreen;
  window.Clear(clSkyBlue);
  window.IsFixedSize := true;
  repeat
    a := ReadlnReal('Введите основание треугольного лепестка, 50 <= a <= 280 pixels:');
    if a.InRange(50, 280) then break else println('*** Не годится! Повторите... ***');
  until false;
  window.Clear(clSkyBlue);
  
  // Чтобы лепестки не соприкасались боковыми сторонами друг с другом,
  // растянем их относительно радиуса окружности, вписанной
  // в правильный 7-угольник (т.е. когда цветок "плотный")
  h := a/(2*tan(Pi/7)) * zoom; // высота лепестков с учетом "зума"
  b := sqrt(a*a/4 + h*h);      // боковая сторона лепестков
  alpha := ArcTan(a/2/h)*2;    // угловой размер каждого лепестка  
  DrawFlower(rot);
end.